| 1 | dnl -*-fundamental-*- |
| 2 | dnl |
| 3 | dnl $Id: configure.in,v 1.1 1999/06/02 16:53:33 mdw Exp $ |
| 4 | dnl |
| 5 | dnl Configuration for sw-tools |
| 6 | dnl |
| 7 | dnl (c) 1999 EBI |
| 8 | dnl |
| 9 | |
| 10 | dnl ----- Licensing notice -------------------------------------------------- |
| 11 | dnl |
| 12 | dnl This file is part of sw-tools. |
| 13 | dnl |
| 14 | dnl sw-tools is free software; you can redistribute it and/or modify |
| 15 | dnl it under the terms of the GNU General Public License as published by |
| 16 | dnl the Free Software Foundation; either version 2 of the License, or |
| 17 | dnl (at your option) any later version. |
| 18 | dnl |
| 19 | dnl sw-tools is distributed in the hope that it will be useful, |
| 20 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | dnl GNU General Public License for more details. |
| 23 | dnl |
| 24 | dnl You should have received a copy of the GNU General Public License |
| 25 | dnl along with sw-tools; if not, write to the Free Software Foundation, |
| 26 | dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 27 | |
| 28 | dnl ----- Revision history -------------------------------------------------- |
| 29 | dnl |
| 30 | dnl $Log: configure.in,v $ |
| 31 | dnl Revision 1.1 1999/06/02 16:53:33 mdw |
| 32 | dnl Initial revision |
| 33 | dnl |
| 34 | |
| 35 | dnl --- Boring boilerplate --- |
| 36 | |
| 37 | AC_INIT(src/sw.c) |
| 38 | AM_INIT_AUTOMAKE(sw-tools, 1.0.0pre3) |
| 39 | AM_CONFIG_HEADER(config.h) |
| 40 | |
| 41 | dnl --- Work out the architecture name --- |
| 42 | |
| 43 | AC_MSG_CHECKING([architecture name]) |
| 44 | arch=`$srcdir/sw.in --archname` |
| 45 | AC_MSG_RESULT($arch) |
| 46 | AC_DEFINE_UNQUOTED(ARCH, "$arch") |
| 47 | AC_SUBST(arch) |
| 48 | |
| 49 | dnl --- Set up the C compiler --- |
| 50 | |
| 51 | AC_PROG_CC |
| 52 | mdw_GCC_FLAGS |
| 53 | |
| 54 | dnl --- Check for <unistd.h> --- |
| 55 | |
| 56 | AC_CHECK_HEADERS(unistd.h) |
| 57 | |
| 58 | dnl --- Find an appropriate remote shell program --- |
| 59 | |
| 60 | AC_ARG_WITH(rsh, |
| 61 | [ --with-rsh=PROGRAM use PROGRAM to start remote shells], |
| 62 | [RSH=$withval]) |
| 63 | AC_PATH_PROGS(RSH, $RSH remsh rsh ssh, rsh) |
| 64 | AC_DEFINE_UNQUOTED(RSH, "$RSH") |
| 65 | |
| 66 | dnl --- Find out whether I have `strsignal' or `sys_siglist' --- |
| 67 | |
| 68 | AC_CHECK_FUNCS(strsignal _sys_siglist, break) |
| 69 | |
| 70 | dnl --- Decide whether to declare `environ' --- |
| 71 | |
| 72 | AC_CACHE_CHECK([for declaration of \`environ'], sw_cv_environ, |
| 73 | [AC_EGREP_CPP(environ, |
| 74 | [#include <sys/types.h> |
| 75 | #if HAVE_UNISTD_H |
| 76 | #include <unistd.h> |
| 77 | #endif |
| 78 | #if STDC_HEADERS |
| 79 | #include <stdlib.h> |
| 80 | #include <stddef.h> |
| 81 | #endif], [sw_cv_environ=yes], [sw_cv_environ=no])]) |
| 82 | if test $sw_cv_environ = yes; then |
| 83 | AC_DEFINE(DECL_ENVIRON) |
| 84 | fi |
| 85 | |
| 86 | dnl --- Find a curses library --- |
| 87 | dnl |
| 88 | dnl Try to find one which knows how to resize a terminal. |
| 89 | |
| 90 | mdw_CHECK_MANYLIBS(newwin, ncurses curses, AC_DEFINE(HAVE_CURSES)) |
| 91 | |
| 92 | if test $mdw_cv_lib_newwin != no; then |
| 93 | AC_CHECK_HEADERS([ncurses.h ncurses/ncurses.h curses.h], [break]) |
| 94 | |
| 95 | if test "$ac_cv_header_ncurses_h" = "no" && |
| 96 | test "$ac_cv_header_ncurses_ncurses_h" = "no" && |
| 97 | test "$ac_cv_header_curses_h" = "no"; then |
| 98 | AC_MSG_WARN([couldn't find a \`curses' header. Assuming \`curses.h'.]) |
| 99 | AC_DEFINE(HAVE_CURSES_H) |
| 100 | fi |
| 101 | |
| 102 | AC_CHECK_FUNCS(wresize) |
| 103 | fi |
| 104 | |
| 105 | |
| 106 | dnl --- Other handy libraries --- |
| 107 | |
| 108 | mdw_CHECK_MANYLIBS(socketpair, socket) |
| 109 | |
| 110 | dnl --- Various standard types --- |
| 111 | |
| 112 | AC_TYPE_PID_T |
| 113 | AC_TYPE_SIZE_T |
| 114 | AC_TYPE_UID_T |
| 115 | |
| 116 | AC_CACHE_CHECK(for ssize_t, sw_cv_ssize_t, |
| 117 | [AC_EGREP_CPP(ssize_t, |
| 118 | [#include <sys/types.h> |
| 119 | #if HAVE_UNISTD_H |
| 120 | #include <unistd.h> |
| 121 | #endif |
| 122 | #if STDC_HEADERS |
| 123 | #include <stdlib.h> |
| 124 | #include <stddef.h> |
| 125 | #endif], |
| 126 | [sw_cv_ssize_t=yes], [sw_cv_ssize_t=no])]) |
| 127 | |
| 128 | if test $sw_cv_ssize_t = no; then |
| 129 | AC_DEFINE(ssize_t, int) |
| 130 | fi |
| 131 | |
| 132 | dnl --- Write in some useful paths --- |
| 133 | |
| 134 | mdw_prefix=$prefix mdw_exec_prefix=$exec_prefix |
| 135 | transform=`echo "$program_transform_name"|sed 's,\\\\\\\\,\\\\,g; s,\\$\\$,$,g'` |
| 136 | test "$prefix" = "NONE" && prefix=$ac_default_prefix |
| 137 | test "$exec_prefix" = "NONE" && exec_prefix=$prefix |
| 138 | SW=`echo sw|sed "$transform"` |
| 139 | AC_SUBST(SW) |
| 140 | AC_DEFINE_UNQUOTED(PREFIX, "$mdw_prefix") |
| 141 | AC_DEFINE_UNQUOTED(BINDIR, "`eval echo $bindir`") |
| 142 | AC_DEFINE_UNQUOTED(DATADIR, "`eval echo $datadir`") |
| 143 | AC_DEFINE_UNQUOTED(SW, "$SW") |
| 144 | prefix=$mdw_prefix exec_prefix=$mdw_exec_prefix |
| 145 | |
| 146 | dnl --- Output the configuration --- |
| 147 | |
| 148 | AC_CONFIG_SUBDIRS(mLib) |
| 149 | AC_OUTPUT(Makefile src/Makefile sw) |
| 150 | |
| 151 | dnl ----- That's all, folks ------------------------------------------------- |