Include `%'-escape substitution.

[sw-tools] / configure.in

dnl -*-fundamental-*-
dnl
dnl $Id: configure.in,v 1.7 1999/07/30 18:45:36 mdw Exp $
dnl
dnl Configuration for sw-tools
dnl
dnl (c) 1999 EBI
dnl

dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of sw-tools.
dnl
dnl sw-tools is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl 
dnl sw-tools is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl 
dnl You should have received a copy of the GNU General Public License
dnl along with sw-tools; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl ----- Revision history --------------------------------------------------
dnl
dnl $Log: configure.in,v $
dnl Revision 1.7  1999/07/30 18:45:36  mdw
dnl Configure the Perl bits.
dnl
dnl Revision 1.6  1999/07/28 09:31:49  mdw
dnl Small amounts of tidying.
dnl
dnl Revision 1.5  1999/07/16 12:46:04  mdw
dnl First proper release version.
dnl
dnl Revision 1.4  1999/06/24 15:53:11  mdw
dnl Bump the version number again.
dnl
dnl Revision 1.3  1999/06/18 18:59:39  mdw
dnl Preliminary work for Perl scripts.
dnl
dnl Revision 1.2  1999/06/04 13:56:36  mdw
dnl Bump version.
dnl
dnl Revision 1.1.1.1  1999/06/02 16:53:33  mdw
dnl Initial import.
dnl

dnl --- Boring boilerplate ---

AC_INIT(src/sw.c)
AM_INIT_AUTOMAKE(sw-tools, 1.0.0)
AM_CONFIG_HEADER(config.h)

dnl --- Work out the architecture name ---

AC_MSG_CHECKING([architecture name])
arch=`$srcdir/sw.in --archname`
AC_MSG_RESULT($arch)
AC_DEFINE_UNQUOTED(ARCH, "$arch")
AC_SUBST(arch)

dnl --- Set up the C compiler ---

AC_PROG_CC
mdw_GCC_FLAGS

dnl --- Find a Perl ---

mdw_PROG_PERL(5.003)
mdw_CHECK_PERL(5.003)

dnl --- Find an appropriate remote shell program ---

AC_ARG_WITH(rsh,
[  --with-rsh=PROGRAM      use PROGRAM to start remote shells],
[RSH=$withval])
AC_PATH_PROGS(RSH, $RSH remsh rsh ssh, rsh)
AC_DEFINE_UNQUOTED(RSH, "$RSH")

dnl --- Various simple tests ---

AC_CHECK_HEADERS(unistd.h)
mdw_DECL_ENVIRON
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_TYPE_UID_T
mdw_TYPE_SSIZE_T
AC_CHECK_FUNCS(strsignal _sys_siglist, break)
mdw_CURSES
mdw_CHECK_MANYLIBS(socketpair, socket)

dnl --- Write in some useful paths ---

mdw_prefix=$prefix mdw_exec_prefix=$exec_prefix
transform=`echo "$program_transform_name"|sed 's,\\\\\\\\,\\\\,g; s,\\$\\$,$,g'`
test "$prefix" = "NONE" && prefix=$ac_default_prefix
test "$exec_prefix" = "NONE" && exec_prefix=$prefix
SW=`echo sw|sed "$transform"`
AC_SUBST(SW)
AC_DEFINE_UNQUOTED(PREFIX, "$mdw_prefix")
AC_DEFINE_UNQUOTED(BINDIR, "`eval echo $bindir`")
AC_DEFINE_UNQUOTED(DATADIR, "`eval echo $datadir`")
AC_DEFINE_UNQUOTED(SW, "$SW")
pkgdatadir="`eval echo $datadir/sw`"
AC_SUBST(pkgdatadir)
prefix=$mdw_prefix exec_prefix=$mdw_exec_prefix

dnl --- Output the configuration ---

AC_CONFIG_SUBDIRS(mLib)
AC_OUTPUT(dnl
  Makefile src/Makefile perl/Makefile dnl
  perl/SWConfig.pm perl/sw perl/sw-tidy dnl
  sw sw-share dnl
)

dnl ----- That's all, folks -------------------------------------------------