3 ;;; Code generation protocol
5 ;;; (c) 2009 Straylight/Edgeware
8 ;;;----- Licensing notice ---------------------------------------------------
10 ;;; This file is part of the Sensble Object Design, an object system for C.
12 ;;; SOD is free software; you can redistribute it and/or modify
13 ;;; it under the terms of the GNU General Public License as published by
14 ;;; the Free Software Foundation; either version 2 of the License, or
15 ;;; (at your option) any later version.
17 ;;; SOD is distributed in the hope that it will be useful,
18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20 ;;; GNU General Public License for more details.
22 ;;; You should have received a copy of the GNU General Public License
23 ;;; along with SOD; if not, write to the Free Software Foundation,
24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
28 ;;;--------------------------------------------------------------------------
33 (export 'format-temporary-name)
34 (defgeneric format-temporary-name (var stream)
36 "Write the name of a temporary variable VAR to STREAM."))
38 (export 'var-in-use-p)
39 (defgeneric var-in-use-p (var)
41 "Answer whether VAR is currently being used. See `with-temporary-var'.")
43 "Non-temporary variables are always in use."
44 (declare (ignore var))
46 (defgeneric (setf var-in-use-p) (value var)
48 "Record whether VAR is currently being used. See `with-temporary-var'."))
52 (export '(temporary-name temp-tag))
53 (defclass temporary-name ()
54 ((tag :initarg :tag :reader temp-tag))
56 "Base class for temporary variable and argument names."))
58 ;; Important temporary names.
60 (export '(*sod-ap* *sod-master-ap*))
61 (defparameter *sod-ap*
62 (make-instance 'temporary-name :tag "sod__ap"))
63 (defparameter *sod-master-ap*
64 (make-instance 'temporary-name :tag "sod__master_ap"))
65 (defparameter *sod-tmp-ap*
66 (make-instance 'temporary-name :tag "sod__tmp_ap"))
68 ;;;--------------------------------------------------------------------------
76 "A base class for instructions.
78 An `instruction' is anything which might be useful to string into a code
79 generator. Both statements and expressions can be represented by trees of
80 instructions. The `definst' macro is a convenient way of defining new
83 The only important protocol for instructions is output, which is achieved
84 by calling `print-object' with `*print-escape*' nil.
86 This doesn't really do very much, but it acts as a handy marker for
87 instruction subclasses."))
90 (defgeneric inst-metric (inst)
92 "Returns a `metric' describing how complicated INST is.
94 The default metric of an inst node is simply 1; `inst' subclasses
95 generated by `definst' (q.v.) have an automatically generated method which
96 returns one plus the sum of the metrics of the node's children.
98 This isn't intended to be a particularly rigorous definition. Its purpose
99 is to allow code generators to make decisions about inlining or calling
100 code fairly simply.")
102 (declare (ignore inst))
104 (:method ((inst null))
105 (declare (ignore inst))
107 (:method ((inst list))
108 (reduce #'+ inst :key #'inst-metric)))
110 ;; Instruction definition.
113 (defmacro definst (code (streamvar &key export) args &body body)
114 "Define an instruction type and describe how to output it.
116 An `inst' can represent any structured piece of output syntax: a
117 statement, expression or declaration, for example. This macro defines the
120 * A class `CODE-inst' to represent the instruction.
122 * Instance slots named after the ARGS, with matching keyword initargs,
123 and `inst-ARG' readers.
125 * A constructor `make-CODE-inst' which accepts the ARGS (in order, not
126 with keywords) as arguments and returns a fresh instance.
128 * A print method, which prints a diagnostic dump if `*print-escape*' is
129 set, or invokes the BODY (with STREAMVAR bound to the output stream)
130 otherwise. The BODY is expected to produce target code at this
133 If EXPORT is non-nil, then export the `CODE-inst' and `make-CODE-inst'
136 (let ((inst-var (gensym "INST"))
137 (class-name (symbolicate code '-inst))
138 (constructor-name (symbolicate 'make- code '-inst))
139 (keys (mapcar (lambda (arg) (intern (symbol-name arg) :keyword))
142 (defclass ,class-name (inst)
143 ,(mapcar (lambda (arg key)
144 `(,arg :initarg ,key :reader ,(symbolicate 'inst- arg)))
146 (defun ,constructor-name (,@args)
147 (make-instance ',class-name ,@(mappend #'list keys args)))
148 (defmethod inst-metric ((,inst-var ,class-name))
149 (with-slots (,@args) ,inst-var
150 (+ 1 ,@(mapcar (lambda (arg) `(inst-metric ,arg)) args))))
151 (defmethod print-object ((,inst-var ,class-name) ,streamvar)
152 (with-slots (,@args) ,inst-var
154 (print-unreadable-object (,inst-var ,streamvar :type t)
155 (format stream "~@<~@{~S ~@_~S~^ ~_~}~:>"
156 ,@(mappend #'list keys args)))
158 ,@(and export `((export '(,class-name ,constructor-name
159 ,@(mapcar (lambda (arg)
160 (symbolicate 'inst- arg))
164 ;; Important instruction classes.
166 ;; HACK: use a gensym for the `expr' and `type' slots to avoid leaking the
167 ;; slot names, since the symbol `expr' is exported from our package and
168 ;; `type' belongs to the `common-lisp' package.
170 (definst var (stream :export t) (name #1=#:type init)
171 (pprint-c-type #1# stream name)
173 (format stream " = ~A" init))
174 (write-char #\; stream))
175 (definst set (stream :export t) (var #1=#:expr)
176 (format stream "~@<~A = ~@_~2I~A;~:>" var #1#))
177 (definst update (stream :export t) (var op #1=#:expr)
178 (format stream "~@<~A ~A= ~@_~2I~A;~:>" var op #1#))
179 (definst return (stream :export t) (#1=#:expr)
180 (format stream "return~@[ (~A)~];" #1#))
181 (definst break (stream :export t) ()
182 (format stream "break;"))
183 (definst continue (stream :export t) ()
184 (format stream "continue;"))
185 (definst expr (stream :export t) (#1=#:expr)
186 (format stream "~A;" #1#))
187 (definst block (stream :export t) (decls body)
188 (format stream "{~:@_~@< ~2I~@[~{~A~:@_~}~:@_~]~{~A~^~:@_~}~:>~:@_}"
190 (definst function (stream :export t) (name #1=#:type body)
191 (pprint-logical-block (stream nil)
192 (princ "static " stream)
193 (pprint-c-type #1# stream name)
194 (format stream "~:@_~A~:@_~:@_" body)))
196 ;; Formatting utilities.
198 (defun format-compound-statement* (stream child morep thunk)
199 "Underlying function for `format-compound-statement'."
200 (cond ((typep child 'block-inst)
201 (funcall thunk stream)
202 (write-char #\space stream)
204 (when morep (write-char #\space stream)))
206 (pprint-logical-block (stream nil)
207 (funcall thunk stream)
208 (write-char #\space stream)
209 (pprint-indent :block 2 stream)
210 (pprint-newline :linear stream)
212 (pprint-indent :block 0 stream)
215 (write-char #\space stream)
216 (pprint-newline :linear stream))
218 (pprint-newline :mandatory stream)))))))
220 (export 'format-compound-statement)
221 (defmacro format-compound-statement
222 ((stream child &optional morep) &body body)
223 "Format a compound statement to STREAM.
225 The introductory material is printed by BODY. The CHILD is formatted
226 properly according to whether it's a `block-inst'. If MOREP is true, then
227 allow for more stuff following the child."
228 `(format-compound-statement* ,stream ,child ,morep
229 (lambda (,stream) ,@body)))
231 ;;;--------------------------------------------------------------------------
236 (export 'codegen-functions)
237 (defgeneric codegen-functions (codegen)
239 "Return the list of `function-inst's of completed functions."))
242 (defgeneric ensure-var (codegen name type &optional init)
244 "Add a variable to CODEGEN's list.
246 The variable is called NAME (which should be comparable using `equal' and
247 print to an identifier) and has the given TYPE. If INIT is present and
248 non-nil it is an expression `inst' used to provide the variable with an
251 (export '(emit-inst emit-insts))
252 (defgeneric emit-inst (codegen inst)
254 "Add INST to the end of CODEGEN's list of instructions."))
255 (defgeneric emit-insts (codegen insts)
257 "Add a list of INSTS to the end of CODEGEN's list of instructions.")
258 (:method (codegen insts)
259 (dolist (inst insts) (emit-inst codegen inst))))
261 (export '(emit-decl emit-decls))
262 (defgeneric emit-decl (codegen inst)
264 "Add INST to the end of CODEGEN's list of declarations."))
265 (defgeneric emit-decls (codegen insts)
267 "Add a list of INSTS to the end of CODEGEN's list of declarations."))
269 (export 'codegen-push)
270 (defgeneric codegen-push (codegen)
272 "Pushes the current code generation state onto a stack.
274 The state consists of the accumulated variables and instructions."))
276 (export 'codegen-pop)
277 (defgeneric codegen-pop (codegen)
279 "Pops a saved state off of the CODEGEN's stack.
281 Returns the newly accumulated variables and instructions as lists, as
284 (export 'codegen-add-function)
285 (defgeneric codegen-add-function (codegen function)
287 "Adds a function to CODEGEN's list.
289 Actually, we're not picky: FUNCTION can be any kind of object that you're
290 willing to find in the list returned by `codegen-functions'."))
292 (export 'temporary-var)
293 (defgeneric temporary-var (codegen type)
295 "Return the name of a temporary variable.
297 The temporary variable will have the given TYPE, and will be marked
298 in-use. You should clear the in-use flag explicitly when you've finished
299 with the variable -- or, better, use `with-temporary-var' to do the
300 cleanup automatically."))
302 (export 'codegen-build-function)
303 (defun codegen-build-function (codegen name type vars insts)
304 "Build a function and add it to CODEGEN's list.
306 Returns the function's name."
307 (codegen-add-function codegen
308 (make-function-inst name type
309 (make-block-inst vars insts)))
312 (export 'codegen-pop-block)
313 (defgeneric codegen-pop-block (codegen)
315 "Makes a block (`block-inst') out of the completed code in CODEGEN.")
317 (multiple-value-bind (vars insts) (codegen-pop codegen)
318 (make-block-inst vars insts))))
320 (export 'codegen-pop-function)
321 (defgeneric codegen-pop-function (codegen name type)
323 "Makes a function out of the completed code in CODEGEN.
325 The NAME can be any object you like. The TYPE should be a function type
326 object which includes argument names. The return value is the NAME.")
327 (:method (codegen name type)
328 (multiple-value-bind (vars insts) (codegen-pop codegen)
329 (codegen-build-function codegen name type vars insts))))
331 (export 'with-temporary-var)
332 (defmacro with-temporary-var ((codegen var type) &body body)
333 "Evaluate BODY with VAR bound to a temporary variable name.
335 During BODY, VAR will be marked in-use; when BODY ends, VAR will be marked
336 available for re-use."
337 `(let ((,var (temporary-var ,codegen ,type)))
340 (setf (var-in-use-p ,var) nil))))
342 ;;;--------------------------------------------------------------------------
343 ;;; Code generation idioms.
345 (export 'deliver-expr)
346 (defun deliver-expr (codegen target expr)
347 "Emit code to deliver the value of EXPR to the TARGET.
349 The TARGET may be one of the following.
351 * `:void', indicating that the value is to be discarded. The expression
352 will still be evaluated.
354 * `:void-return', indicating that the value is to be discarded (as for
355 `:void') and furthermore a `return' from the current function should
356 be forced after computing the value.
358 * `:return', indicating that the value is to be returned from the
361 * A variable name, indicating that the value is to be stored in the
364 In the cases of `:return', `:void' and `:void-return' targets, it is valid
365 for EXPR to be nil; this signifies that no computation needs to be
366 performed. Variable-name targets require an expression."
369 (:return (emit-inst codegen (make-return-inst expr)))
370 (:void (when expr (emit-inst codegen (make-expr-inst expr))))
371 (:void-return (when expr (emit-inst codegen (make-expr-inst expr)))
372 (emit-inst codegen (make-return-inst nil)))
373 (t (emit-inst codegen (make-set-inst target expr)))))
375 (export 'convert-stmts)
376 (defun convert-stmts (codegen target type func)
377 "Invoke FUNC to deliver a value to a non-`:return' target.
379 FUNC is a function which accepts a single argument, a non-`:return'
380 target, and generates statements which deliver a value (see
381 `deliver-expr') of the specified TYPE to this target. In general, the
382 generated code will have the form
384 setup instructions...
385 (deliver-expr CODEGEN TARGET (compute value...))
386 cleanup instructions...
388 where the cleanup instructions are essential to the proper working of the
391 The `convert-stmts' function will call FUNC to generate code, and arrange
392 that its value is correctly delivered to TARGET, regardless of what the
393 TARGET is -- i.e., it lifts the restriction to non-`:return' targets. It
394 does this by inventing a new temporary variable."
397 (:return (with-temporary-var (codegen var type)
399 (deliver-expr codegen target var)))
400 (:void-return (funcall func :void)
401 (emit-inst codegen (make-return-inst nil)))
402 (t (funcall func target))))
404 ;;;----- That's all, folks --------------------------------------------------