mdw@git.distorted.org.uk Git - sod/blob - src/class-output.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Output for classes
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensble Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Classes.
  30
  31 (defmethod hook-output progn ((class sod-class) (reason (eql :h)) sequencer)
  32
  33   ;; Main output sequencing.
  34   (sequence-output (stream sequencer)
  35
  36     :constraint
  37     ((:classes :start)
  38      (class :banner)
  39      (class :islots :start) (class :islots :slots) (class :islots :end)
  40      (class :vtmsgs :start) (class :vtmsgs :end)
  41      (class :vtables :start) (class :vtables :end)
  42      (class :vtable-externs) (class :vtable-externs-after)
  43      (class :methods :start) (class :methods) (class :methods :end)
  44      (class :ichains :start) (class :ichains :end)
  45      (class :ilayout :start) (class :ilayout :slots) (class :ilayout :end)
  46      (class :conversions)
  47      (class :message-macros)
  48      (class :object)
  49      (:classes :end))
  50
  51     (:typedefs
  52      (format stream "typedef struct ~A ~A;~%"
  53              (ichain-struct-tag class (sod-class-chain-head class)) class))
  54
  55     ((class :banner)
  56      (banner (format nil "Class ~A" class) stream))
  57     ((class :vtable-externs-after)
  58      (terpri stream))
  59
  60     ((class :vtable-externs)
  61      (format stream "/* Vtable structures. */~%"))
  62
  63     ((class :object)
  64      (let ((metaclass (sod-class-metaclass class))
  65            (metaroot (find-root-metaclass class)))
  66        (format stream "/* The class object. */~@
  67                        extern const struct ~A ~A__classobj;~@
  68                        #define ~:*~A__class (&~:*~A__classobj.~A.~A)~2%"
  69                (ilayout-struct-tag metaclass) class
  70                (sod-class-nickname (sod-class-chain-head metaroot))
  71                (sod-class-nickname metaroot)))))
  72
  73   ;; Maybe generate an islots structure.
  74   (when (sod-class-slots class)
  75     (dolist (slot (sod-class-slots class))
  76       (hook-output slot 'islots sequencer))
  77     (sequence-output (stream sequencer)
  78       ((class :islots :start)
  79        (format stream "/* Instance slots. */~@
  80                        struct ~A {~%"
  81                (islots-struct-tag class)))
  82       ((class :islots :end)
  83        (format stream "};~2%"))))
  84
  85   ;; Declare the direct methods.
  86   (when (sod-class-methods class)
  87     (sequence-output (stream sequencer)
  88       ((class :methods :start)
  89        (format stream "/* Direct methods. */~%"))
  90       ((class :methods :end)
  91        (terpri stream))))
  92
  93   ;; Provide upcast macros which do the right thing.
  94   (when (sod-class-direct-superclasses class)
  95     (sequence-output (stream sequencer)
  96       ((class :conversions)
  97        (let ((chain-head (sod-class-chain-head class)))
  98          (format stream "/* Conversion macros. */~%")
  99          (dolist (super (cdr (sod-class-precedence-list class)))
 100            (let ((super-head (sod-class-chain-head super)))
 101              (format stream "#define ~:@(~A__CONV_~A~)(p) ((~A *)~
 102                                      ~:[SOD_XCHAIN(~A, (p))~;(p)~])~%"
 103                      class (sod-class-nickname super) super
 104                      (eq chain-head super-head)
 105                      (sod-class-nickname super-head))))
 106          (terpri stream)))))
 107
 108   ;; Provide convenience macros for sending the newly defined messages.  (The
 109   ;; macros work on all subclasses too.)
 110   ;;
 111   ;; We need each message's method entry type for this, so we need to dig it
 112   ;; out of the vtmsgs structure.  Indeed, the vtmsgs for this class contains
 113   ;; entries for precisely the messages we want to make macros for.
 114   (when (sod-class-messages class)
 115     (sequence-output (stream sequencer)
 116       ((class :message-macros)
 117        (let* ((vtable (find (sod-class-chain-head class)
 118                             (sod-class-vtables class)
 119                             :key #'vtable-chain-head))
 120               (vtmsgs (find-if (lambda (item)
 121                                  (and (typep item 'vtmsgs)
 122                                       (eql (vtmsgs-class item) class)))
 123                                (vtable-body vtable))))
 124          (format stream "/* Message invocation macros. */~%")
 125          (dolist (entry (vtmsgs-entries vtmsgs))
 126            (let* ((type (method-entry-function-type entry))
 127                   (args (c-function-arguments type))
 128                   (in-names nil) (out-names nil) (varargsp nil) (me "me"))
 129              (do ((args args (cdr args)))
 130                  ((endp args))
 131                (let* ((raw-name (princ-to-string (argument-name (car args))))
 132                       (name (if (find raw-name
 133                                       (list "_vt"
 134                                             (sod-class-nickname class)
 135                                             (method-entry-slot-name entry))
 136                                       :test #'string=)
 137                                 (format nil "sod__a_~A" raw-name)
 138                                 raw-name)))
 139                  (cond ((and (cdr args) (eq (cadr args) :ellipsis))
 140                         (setf varargsp t)
 141                         (unless in-names (setf me "SOD__CAR(__VA_ARGS__)"))
 142                         (push (format nil "/*~A*/ ..." name) in-names)
 143                         (push "__VA_ARGS__" out-names)
 144                         (return))
 145                        (t
 146                         (push name in-names)
 147                         (push name out-names)))))
 148              (when varargsp
 149                (format stream "#if __STDC_VERSION__ >= 199901~%"))
 150              (format stream "#define ~A(~{~A~^, ~}) ~
 151                                    ~A->_vt->~A.~A(~{~A~^, ~})~%"
 152                      (message-macro-name class entry)
 153                      (nreverse in-names)
 154                      me
 155                      (sod-class-nickname class)
 156                      (method-entry-slot-name entry)
 157                      (nreverse out-names))
 158              (when varargsp
 159                (format stream "#endif~%"))))
 160          (terpri stream)))))
 161
 162   ;; Generate vtmsgs structure for all superclasses.
 163   (hook-output (car (sod-class-vtables class))
 164                     'vtmsgs
 165                     sequencer))
 166
 167 (defmethod hook-output progn ((class sod-class) reason sequencer)
 168   (with-slots (ilayout vtables methods effective-methods) class
 169     (hook-output ilayout reason sequencer)
 170     (dolist (method methods) (hook-output method reason sequencer))
 171     (dolist (method effective-methods) (hook-output method reason sequencer))
 172     (dolist (vtable vtables) (hook-output vtable reason sequencer))))
 173
 174 ;;;--------------------------------------------------------------------------
 175 ;;; Instance structure.
 176
 177 (defmethod hook-output progn ((slot sod-slot)
 178                               (reason (eql 'islots))
 179                               sequencer)
 180   (sequence-output (stream sequencer)
 181     (((sod-slot-class slot) :islots :slots)
 182      (pprint-logical-block (stream nil :prefix "  " :suffix ";")
 183        (pprint-c-type (sod-slot-type slot) stream (sod-slot-name slot)))
 184      (terpri stream))))
 185
 186 (defmethod hook-output progn ((ilayout ilayout) reason sequencer)
 187   (with-slots (ichains) ilayout
 188     (dolist (ichain ichains) (hook-output ichain reason sequencer))))
 189
 190 (defmethod hook-output progn ((ichain ichain) reason sequencer)
 191   (dolist (item (ichain-body ichain))
 192     (hook-output item reason sequencer)))
 193
 194 (defmethod hook-output progn ((ilayout ilayout) (reason (eql :h)) sequencer)
 195   (with-slots (class ichains) ilayout
 196     (sequence-output (stream sequencer)
 197       ((class :ilayout :start)
 198        (format stream "/* Instance layout. */~@
 199                        struct ~A {~%"
 200                (ilayout-struct-tag class)))
 201       ((class :ilayout :end)
 202        (format stream "};~2%")))
 203     (dolist (ichain ichains)
 204       (hook-output ichain 'ilayout sequencer))))
 205
 206 (defmethod hook-output progn ((ichain ichain) (reason (eql :h)) sequencer)
 207   (with-slots (class chain-head chain-tail) ichain
 208     (when (eq class chain-tail)
 209       (sequence-output (stream sequencer)
 210         :constraint ((class :ichains :start)
 211                      (class :ichain chain-head :start)
 212                      (class :ichain chain-head :slots)
 213                      (class :ichain chain-head :end)
 214                      (class :ichains :end))
 215         ((class :ichain chain-head :start)
 216          (format stream "/* Instance chain structure. */~@
 217                          struct ~A {~%"
 218                  (ichain-struct-tag chain-tail chain-head)))
 219         ((class :ichain chain-head :end)
 220          (format stream "};~2%")
 221          (format stream "/* Union of equivalent superclass chains. */~@
 222                          union ~A {~@
 223                          ~:{  struct ~A ~A;~%~}~
 224                          };~2%"
 225                  (ichain-union-tag chain-tail chain-head)
 226
 227                  ;; Make sure the most specific class is first: only the
 228                  ;; first element of a union can be statically initialized in
 229                  ;; C90.
 230                  (mapcar (lambda (super)
 231                            (list (ichain-struct-tag super chain-head)
 232                                  (sod-class-nickname super)))
 233                          (sod-class-chain chain-tail))))))))
 234
 235 (defmethod hook-output progn ((ichain ichain)
 236                               (reason (eql 'ilayout))
 237                               sequencer)
 238   (with-slots (class chain-head chain-tail) ichain
 239     (sequence-output (stream sequencer)
 240       ((class :ilayout :slots)
 241        (format stream "  union ~A ~A;~%"
 242                (ichain-union-tag chain-tail chain-head)
 243                (sod-class-nickname chain-head))))))
 244
 245 (defmethod hook-output progn ((vtptr vtable-pointer)
 246                               (reason (eql :h))
 247                               sequencer)
 248   (with-slots (class chain-head chain-tail) vtptr
 249     (sequence-output (stream sequencer)
 250       ((class :ichain chain-head :slots)
 251        (format stream "  const struct ~A *_vt;~%"
 252                (vtable-struct-tag chain-tail chain-head))))))
 253
 254 (defmethod hook-output progn ((islots islots) reason sequencer)
 255   (dolist (slot (islots-slots islots))
 256     (hook-output slot reason sequencer)))
 257
 258 (defmethod hook-output progn ((islots islots) (reason (eql :h)) sequencer)
 259   (with-slots (class subclass slots) islots
 260     (sequence-output (stream sequencer)
 261       ((subclass :ichain (sod-class-chain-head class) :slots)
 262        (format stream "  struct ~A ~A;~%"
 263                (islots-struct-tag class)
 264                (sod-class-nickname class))))))
 265
 266 ;;;--------------------------------------------------------------------------
 267 ;;; Vtable structure.
 268
 269 (defmethod hook-output progn ((vtable vtable) reason sequencer)
 270   (with-slots (body) vtable
 271     (dolist (item body) (hook-output item reason sequencer))))
 272
 273 (defmethod hook-output progn ((method sod-method)
 274                               (reason (eql :h))
 275                               sequencer)
 276   (with-slots (class) method
 277     (sequence-output (stream sequencer)
 278       ((class :methods)
 279        (let ((type (sod-method-function-type method)))
 280          (princ "extern " stream)
 281          (pprint-c-type (commentify-function-type type) stream
 282                         (sod-method-function-name method))
 283          (format stream ";~%"))))))
 284
 285 (defmethod hook-output progn ((vtable vtable) (reason (eql :h)) sequencer)
 286   (with-slots (class chain-head chain-tail) vtable
 287     (when (eq class chain-tail)
 288       (sequence-output (stream sequencer)
 289         :constraint ((class :vtables :start)
 290                      (class :vtable chain-head :start)
 291                      (class :vtable chain-head :slots)
 292                      (class :vtable chain-head :end)
 293                      (class :vtables :end))
 294         ((class :vtable chain-head :start)
 295          (format stream "/* Vtable structure. */~@
 296                          struct ~A {~%"
 297                  (vtable-struct-tag chain-tail chain-head)))
 298         ((class :vtable chain-head :end)
 299          (format stream "};~2%"))))
 300     (sequence-output (stream sequencer)
 301       ((class :vtable-externs)
 302        (format stream "~@<extern const struct ~A ~2I~_~A__vtable_~A;~:>~%"
 303                (vtable-struct-tag chain-tail chain-head)
 304                class (sod-class-nickname chain-head))))))
 305
 306 (defmethod hook-output progn ((vtmsgs vtmsgs) (reason (eql :h)) sequencer)
 307   (with-slots (class subclass chain-head chain-tail) vtmsgs
 308     (sequence-output (stream sequencer)
 309       ((subclass :vtable chain-head :slots)
 310        (format stream "  struct ~A ~A;~%"
 311                (vtmsgs-struct-tag subclass class)
 312                (sod-class-nickname class))))))
 313
 314 (defmethod hook-output progn ((vtmsgs vtmsgs)
 315                               (reason (eql 'vtmsgs))
 316                               sequencer)
 317   (when (vtmsgs-entries vtmsgs)
 318     (with-slots (class subclass) vtmsgs
 319       (sequence-output (stream sequencer)
 320         :constraint ((subclass :vtmsgs :start)
 321                      (subclass :vtmsgs class :start)
 322                      (subclass :vtmsgs class :slots)
 323                      (subclass :vtmsgs class :end)
 324                      (subclass :vtmsgs :end))
 325         ((subclass :vtmsgs class :start)
 326          (format stream "/* Messages protocol from class ~A */~@
 327                          struct ~A {~%"
 328                  class
 329                  (vtmsgs-struct-tag subclass class)))
 330         ((subclass :vtmsgs class :end)
 331          (format stream "};~2%"))))))
 332
 333 (defmethod hook-output progn ((vtmsgs vtmsgs) reason sequencer)
 334   (with-slots (entries) vtmsgs
 335     (dolist (entry entries) (hook-output entry reason sequencer))))
 336
 337 (defmethod hook-output progn ((entry method-entry)
 338                               (reason (eql 'vtmsgs))
 339                               sequencer)
 340   (let* ((method (method-entry-effective-method entry))
 341          (message (effective-method-message method))
 342          (class (effective-method-class method))
 343          (function-type (method-entry-function-type entry))
 344          (commented-type (commentify-function-type function-type))
 345          (pointer-type (make-pointer-type commented-type)))
 346     (sequence-output (stream sequencer)
 347       ((class :vtmsgs (sod-message-class message) :slots)
 348        (pprint-logical-block (stream nil :prefix "  " :suffix ";")
 349          (pprint-c-type pointer-type stream (method-entry-slot-name entry)))
 350        (terpri stream)))))
 351
 352 (defmethod hook-output progn ((cptr class-pointer)
 353                               (reason (eql :h))
 354                               sequencer)
 355   (with-slots (class chain-head metaclass meta-chain-head) cptr
 356     (sequence-output (stream sequencer)
 357       ((class :vtable chain-head :slots)
 358        (format stream "  const ~A *~:[_class~;~:*_cls_~A~];~%"
 359                metaclass
 360                (and (sod-class-direct-superclasses meta-chain-head)
 361                     (sod-class-nickname meta-chain-head)))))))
 362
 363 (defmethod hook-output progn ((boff base-offset) (reason (eql :h)) sequencer)
 364   (with-slots (class chain-head) boff
 365     (sequence-output (stream sequencer)
 366       ((class :vtable chain-head :slots)
 367        (write-line "  size_t _base;" stream)))))
 368
 369 (defmethod hook-output progn ((choff chain-offset)
 370                               (reason (eql :h))
 371                               sequencer)
 372   (with-slots (class chain-head target-head) choff
 373     (sequence-output (stream sequencer)
 374       ((class :vtable chain-head :slots)
 375        (format stream "  ptrdiff_t _off_~A;~%"
 376                (sod-class-nickname target-head))))))
 377
 378 ;;;--------------------------------------------------------------------------
 379 ;;; Implementation output.
 380
 381 (defvar *instance-class*)
 382
 383 (defmethod hook-output progn ((class sod-class) (reason (eql :c)) sequencer)
 384   (sequence-output (stream sequencer)
 385
 386     :constraint
 387     ((:classes :start)
 388      (class :banner)
 389      (class :direct-methods :start) (class :direct-methods :end)
 390      (class :effective-methods)
 391      (class :vtables :start) (class :vtables :end)
 392      (class :object :prepare) (class :object :start) (class :object :end)
 393      (:classes :end))
 394
 395     ((class :banner)
 396      (banner (format nil "Class ~A" class) stream))
 397
 398     ((class :object :start)
 399      (format stream "~
 400 /* The class object. */
 401 const struct ~A ~A__classobj = {~%"
 402              (ilayout-struct-tag (sod-class-metaclass class))
 403              class))
 404     ((class :object :end)
 405      (format stream "};~2%")))
 406
 407   (let ((*instance-class* class))
 408     (hook-output (sod-class-ilayout (sod-class-metaclass class))
 409                       'class
 410                       sequencer)))
 411
 412 ;;;--------------------------------------------------------------------------
 413 ;;; Direct and effective methods.
 414
 415 (defmethod hook-output progn ((method delegating-direct-method)
 416                               (reason (eql :c))
 417                               sequencer)
 418   (with-slots (class body) method
 419     (unless body
 420       (return-from hook-output))
 421     (sequence-output (stream sequencer)
 422       ((class :direct-method method :start)
 423        (format stream "#define CALL_NEXT_METHOD (next_method(~{~A~^, ~}))~%"
 424                (mapcar #'argument-name
 425                        (c-function-arguments (sod-method-next-method-type
 426                                               method)))))
 427       ((class :direct-method method :end)
 428        (format stream "#undef CALL_NEXT_METHOD~%")))))
 429
 430 (defmethod hook-output progn ((method sod-method)
 431                               (reason (eql :c))
 432                               sequencer)
 433   (with-slots (class body) method
 434     (unless body
 435       (return-from hook-output))
 436     (sequence-output (stream sequencer)
 437       :constraint ((class :direct-methods :start)
 438                    (class :direct-method method :start)
 439                    (class :direct-method method :body)
 440                    (class :direct-method method :end)
 441                    (class :direct-methods :end))
 442       ((class :direct-method method :body)
 443        (pprint-c-type (sod-method-function-type method)
 444                       stream
 445                       (sod-method-function-name method))
 446        (format stream "~&{~%")
 447        (write body :stream stream :pretty nil :escape nil)
 448        (format stream "~&}~%"))
 449       ((class :direct-method method :end)
 450        (terpri stream)))))
 451
 452 (defmethod hook-output progn ((method basic-effective-method)
 453                               (reason (eql :c))
 454                               sequencer)
 455   (with-slots (class functions) method
 456     (sequence-output (stream sequencer)
 457       ((class :effective-methods)
 458        (dolist (func functions)
 459          (write func :stream stream :escape nil :circle nil))))))
 460
 461 ;;;--------------------------------------------------------------------------
 462 ;;; Vtables.
 463
 464 (defmethod hook-output progn ((vtable vtable) (reason (eql :c)) sequencer)
 465   (with-slots (class chain-head chain-tail) vtable
 466     (sequence-output (stream sequencer)
 467       :constraint ((class :vtables :start)
 468                    (class :vtable chain-head :start)
 469                    (class :vtable chain-head :end)
 470                    (class :vtables :end))
 471       ((class :vtable chain-head :start)
 472        (format stream "/* Vtable for ~A chain. */~@
 473                        const struct ~A ~A = {~%"
 474                chain-head
 475                (vtable-struct-tag chain-tail chain-head)
 476                (vtable-name class chain-head)))
 477       ((class :vtable chain-head :end)
 478        (format stream "};~2%")))))
 479
 480 (defmethod hook-output progn ((cptr class-pointer)
 481                               (reason (eql :c))
 482                               sequencer)
 483   (with-slots (class chain-head metaclass meta-chain-head) cptr
 484     (sequence-output (stream sequencer)
 485       :constraint ((class :vtable chain-head :start)
 486                    (class :vtable chain-head :class-pointer metaclass)
 487                    (class :vtable chain-head :end))
 488       ((class :vtable chain-head :class-pointer metaclass)
 489        (format stream "  /* ~21@A = */ &~A__classobj.~A.~A,~%"
 490                (if (sod-class-direct-superclasses meta-chain-head)
 491                    (format nil "_cls_~A"
 492                            (sod-class-nickname meta-chain-head))
 493                    "_class")
 494                class
 495                (sod-class-nickname meta-chain-head)
 496                (sod-class-nickname metaclass))))))
 497
 498 (defmethod hook-output progn ((boff base-offset) (reason (eql :c)) sequencer)
 499   (with-slots (class chain-head) boff
 500     (sequence-output (stream sequencer)
 501       :constraint ((class :vtable chain-head :start)
 502                    (class :vtable chain-head :base-offset)
 503                    (class :vtable chain-head :end))
 504       ((class :vtable chain-head :base-offset)
 505        (format stream "  /* ~21@A = */ offsetof(struct ~A, ~A),~%"
 506                "_base"
 507                (ilayout-struct-tag class)
 508                (sod-class-nickname chain-head))))))
 509
 510 (defmethod hook-output progn ((choff chain-offset)
 511                               (reason (eql :c))
 512                               sequencer)
 513   (with-slots (class chain-head target-head) choff
 514     (sequence-output (stream sequencer)
 515       :constraint ((class :vtable chain-head :start)
 516                    (class :vtable chain-head :chain-offset target-head)
 517                    (class :vtable chain-head :end))
 518       ((class :vtable chain-head :chain-offset target-head)
 519        (format stream "  /* ~21@A = */ SOD_OFFSETDIFF(struct ~A, ~A, ~A),~%"
 520                (format nil "_off_~A" (sod-class-nickname target-head))
 521                (ilayout-struct-tag class)
 522                (sod-class-nickname chain-head)
 523                (sod-class-nickname target-head))))))
 524
 525 (defmethod hook-output progn ((vtmsgs vtmsgs) (reason (eql :c)) sequencer)
 526   (with-slots (class subclass chain-head) vtmsgs
 527     (sequence-output (stream sequencer)
 528       :constraint ((subclass :vtable chain-head :start)
 529                    (subclass :vtable chain-head :vtmsgs class :start)
 530                    (subclass :vtable chain-head :vtmsgs class :slots)
 531                    (subclass :vtable chain-head :vtmsgs class :end)
 532                    (subclass :vtable chain-head :end))
 533       ((subclass :vtable chain-head :vtmsgs class :start)
 534        (format stream "  { /* Method entries for ~A messages. */~%"
 535                class))
 536       ((subclass :vtable chain-head :vtmsgs class :end)
 537        (format stream "  },~%")))))
 538
 539 (defmethod hook-output progn ((entry method-entry)
 540                               (reason (eql :c))
 541                               sequencer)
 542   (with-slots (method chain-head chain-tail role) entry
 543     (let* ((message (effective-method-message method))
 544            (class (effective-method-class method))
 545            (super (sod-message-class message)))
 546       (sequence-output (stream sequencer)
 547         ((class :vtable chain-head :vtmsgs super :slots)
 548          (format stream "    /* ~19@A = */ ~A,~%"
 549                  (method-entry-slot-name entry)
 550                  (method-entry-function-name method chain-head role)))))))
 551
 552 ;;;--------------------------------------------------------------------------
 553 ;;; Filling in the class object.
 554
 555 (defmethod hook-output progn ((ichain ichain)
 556                               (reason (eql 'class))
 557                               sequencer)
 558   (with-slots (class chain-head) ichain
 559     (sequence-output (stream sequencer)
 560       :constraint ((*instance-class* :object :start)
 561                    (*instance-class* :object chain-head :ichain :start)
 562                    (*instance-class* :object chain-head :ichain :end)
 563                    (*instance-class* :object :end))
 564       ((*instance-class* :object chain-head :ichain :start)
 565        (format stream "  { { /* ~A ichain */~%"
 566                (sod-class-nickname chain-head)))
 567       ((*instance-class* :object chain-head :ichain :end)
 568        (format stream "  } },~%")))))
 569
 570 (defmethod hook-output progn ((islots islots)
 571                               (reason (eql 'class))
 572                               sequencer)
 573   (with-slots (class) islots
 574     (let ((chain-head (sod-class-chain-head class)))
 575       (sequence-output (stream sequencer)
 576         :constraint ((*instance-class* :object chain-head :ichain :start)
 577                      (*instance-class* :object class :slots :start)
 578                      (*instance-class* :object class :slots)
 579                      (*instance-class* :object class :slots :end)
 580                      (*instance-class* :object chain-head :ichain :end))
 581         ((*instance-class* :object class :slots :start)
 582          (format stream "      { /* Class ~A */~%" class))
 583         ((*instance-class* :object class :slots :end)
 584          (format stream "      },~%"))))))
 585
 586 (defmethod hook-output progn ((vtptr vtable-pointer)
 587                               (reason (eql 'class))
 588                               sequencer)
 589   (with-slots (class chain-head chain-tail) vtptr
 590     (sequence-output (stream sequencer)
 591       :constraint ((*instance-class* :object chain-head :ichain :start)
 592                    (*instance-class* :object chain-head :vtable)
 593                    (*instance-class* :object chain-head :ichain :end))
 594       ((*instance-class* :object chain-head :vtable)
 595        (format stream "      &~A__vtable_~A,~%"
 596                class (sod-class-nickname chain-head))))))
 597
 598 (defgeneric find-class-initializer (slot class)
 599   (:method ((slot effective-slot) (class sod-class))
 600     (let ((dslot (effective-slot-direct-slot slot)))
 601       (or (some (lambda (super)
 602                   (find dslot (sod-class-class-initializers super)
 603                         :test #'sod-initializer-slot))
 604                 (sod-class-precedence-list class))
 605           (effective-slot-initializer slot)))))
 606
 607 (defgeneric output-class-initializer (slot instance stream)
 608   (:method ((slot sod-class-effective-slot) (instance sod-class) stream)
 609     (let ((func (effective-slot-initializer-function slot))
 610           (direct-slot (effective-slot-direct-slot slot)))
 611       (if func
 612           (format stream "        /* ~15@A = */ ~A,~%"
 613                   (sod-slot-name direct-slot)
 614                   (funcall func instance))
 615           (call-next-method))))
 616   (:method ((slot effective-slot) (instance sod-class) stream)
 617     (let ((init (find-class-initializer slot instance))
 618           (direct-slot (effective-slot-direct-slot slot)))
 619       (ecase (sod-initializer-value-kind init)
 620         (:simple (format stream "        /* ~15@A = */ ~A,~%"
 621                          (sod-slot-name direct-slot)
 622                          (sod-initializer-value-form init)))
 623         (:compound (format stream "        /* ~15@A = */ ~@<{ ~;~A~; },~:>~%"
 624                            (sod-slot-name direct-slot)
 625                            (sod-initializer-value-form init)))))))
 626
 627 (defmethod hook-output progn ((slot sod-class-effective-slot)
 628                               (reason (eql 'class))
 629                               sequencer)
 630   (let ((instance *instance-class*)
 631         (func (effective-slot-prepare-function slot)))
 632     (when func
 633       (sequence-output (stream sequencer)
 634         ((instance :object :prepare)
 635          (funcall func instance stream))))))
 636
 637 (defmethod hook-output progn ((slot effective-slot)
 638                               (reason (eql 'class))
 639                               sequencer)
 640   (with-slots (class (dslot slot)) slot
 641     (let ((instance *instance-class*)
 642           (super (sod-slot-class dslot)))
 643       (sequence-output (stream sequencer)
 644         ((instance :object super :slots)
 645          (output-class-initializer slot instance stream))))))
 646
 647 ;;;----- That's all, folks --------------------------------------------------