| 1 | ;;; -*-lisp-*- |
| 2 | ;;; |
| 3 | ;;; Finishing touches for Sod |
| 4 | ;;; |
| 5 | ;;; (c) 2015 Straylight/Edgeware |
| 6 | ;;; |
| 7 | |
| 8 | ;;;----- Licensing notice --------------------------------------------------- |
| 9 | ;;; |
| 10 | ;;; This file is part of the Sensible Object Design, an object system for C. |
| 11 | ;;; |
| 12 | ;;; SOD is free software; you can redistribute it and/or modify |
| 13 | ;;; it under the terms of the GNU General Public License as published by |
| 14 | ;;; the Free Software Foundation; either version 2 of the License, or |
| 15 | ;;; (at your option) any later version. |
| 16 | ;;; |
| 17 | ;;; SOD is distributed in the hope that it will be useful, |
| 18 | ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;;; GNU General Public License for more details. |
| 21 | ;;; |
| 22 | ;;; You should have received a copy of the GNU General Public License |
| 23 | ;;; along with SOD; if not, write to the Free Software Foundation, |
| 24 | ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 25 | |
| 26 | (cl:in-package #:sod) |
| 27 | |
| 28 | ;;;-------------------------------------------------------------------------- |
| 29 | ;;; Miscellaneous details. |
| 30 | |
| 31 | (export '*sod-version*) |
| 32 | (defparameter *sod-version* sod-sysdef:*version* |
| 33 | "The version of the SOD translator system, as a string.") |
| 34 | |
| 35 | ;;;-------------------------------------------------------------------------- |
| 36 | ;;; Debugging utilities. |
| 37 | |
| 38 | (export '*debugout-pathname*) |
| 39 | (defvar *debugout-pathname* #p"debugout.c") |
| 40 | |
| 41 | (export 'test-module) |
| 42 | (defun test-module (path reason) |
| 43 | "Reset the translator's state, read a module from PATH and output it with |
| 44 | REASON, returning the result as a string." |
| 45 | (setf *module-map* (make-hash-table :test #'equal)) |
| 46 | (with-open-file (out *debugout-pathname* |
| 47 | :direction :output |
| 48 | :if-exists :supersede |
| 49 | :if-does-not-exist :create) |
| 50 | (output-module (read-module path) reason out))) |
| 51 | |
| 52 | (export 'test-parse-c-type) |
| 53 | (defun test-parse-c-type (string) |
| 54 | "Parse STRING as a C type, with optional kernel, and show the results." |
| 55 | (with-input-from-string (in string) |
| 56 | (let* ((*module-type-map* (make-hash-table)) |
| 57 | (charscan (make-instance 'charbuf-scanner |
| 58 | :stream in |
| 59 | :filename "<string>")) |
| 60 | (tokscan (make-instance 'sod-token-scanner |
| 61 | :char-scanner charscan |
| 62 | :filename "<string>"))) |
| 63 | (with-parser-context (token-scanner-context :scanner tokscan) |
| 64 | (multiple-value-bind (value winp consumedp) |
| 65 | (parse (seq ((decls (parse-c-type tokscan)) |
| 66 | (type (parse-declarator tokscan decls :abstractp t)) |
| 67 | :eof) |
| 68 | type)) |
| 69 | (declare (ignore consumedp)) |
| 70 | (if winp |
| 71 | (values t (car value) (cdr value) |
| 72 | (princ-to-string (car value))) |
| 73 | (values nil value))))))) |
| 74 | |
| 75 | (export 'test-parser) |
| 76 | (defmacro test-parser ((scanner &key backtrace) parser input) |
| 77 | "Convenient macro for testing parsers at the REPL. |
| 78 | |
| 79 | This is a macro so that the parser can use the fancy syntax. The name |
| 80 | SCANNER is bound to a `sod-token-scanner' reading tokens from the INPUT |
| 81 | string. Then the PARSER is invoked and three values are returned: the |
| 82 | result of the parse, or `nil' if the main parse failed; a list containing |
| 83 | the number of errors and warnings (respectively) reported during the |
| 84 | parse; and a list consisting of the lookahead token type and value, and a |
| 85 | string containing the untokenized remaining input. |
| 86 | |
| 87 | If BACKTRACE is nil (the default) then leave errors to the calling |
| 88 | environment to sort out (e.g., by entering the Lisp debugger); otherwise, |
| 89 | catch and report them as they happen so that you can test error recovery |
| 90 | strategies." |
| 91 | (once-only (input) |
| 92 | (with-gensyms (char-scanner value winp body consumedp where nerror nwarn) |
| 93 | `(let ((,char-scanner nil) (,scanner nil)) |
| 94 | (with-parser-context (token-scanner-context :scanner ,scanner) |
| 95 | (multiple-value-bind (,value ,nerror ,nwarn) |
| 96 | (flet ((,body () |
| 97 | (setf ,char-scanner (make-string-scanner ,input) |
| 98 | ,scanner (make-instance |
| 99 | 'sod-token-scanner |
| 100 | :char-scanner ,char-scanner)) |
| 101 | (multiple-value-bind (,value ,winp ,consumedp) |
| 102 | (parse ,parser) |
| 103 | (declare (ignore ,consumedp)) |
| 104 | (cond (,winp ,value) |
| 105 | (t (syntax-error ,scanner ,value) |
| 106 | nil))))) |
| 107 | (if ,backtrace (,body) |
| 108 | (count-and-report-errors () |
| 109 | (with-default-error-location (,scanner) |
| 110 | (,body))))) |
| 111 | (let ((,where (scanner-capture-place ,char-scanner))) |
| 112 | (values ,value |
| 113 | (list ,nerror ,nwarn) |
| 114 | (and ,scanner (list (token-type ,scanner) |
| 115 | (token-value ,scanner) |
| 116 | (subseq ,input ,where))))))))))) |
| 117 | |
| 118 | ;;;-------------------------------------------------------------------------- |
| 119 | ;;; Calisthenics. |
| 120 | |
| 121 | (export 'exercise) |
| 122 | (defun exercise () |
| 123 | "Exercise the pieces of the metaobject protocol. |
| 124 | |
| 125 | In some Lisps, the compiler is run the first time methods are called, to |
| 126 | do fancy just-in-time optimization things. This is great, only the |
| 127 | program doesn't actually run for very long and a lot of that work is |
| 128 | wasted because we're going to have to do it again next time the program |
| 129 | starts. Only, if we exercise the various methods, or at least a large |
| 130 | fraction of them, before we dump an image, then everything will be fast. |
| 131 | |
| 132 | That's the theory anyway. Call this function before you dump an image and |
| 133 | see what happens." |
| 134 | |
| 135 | (dolist (reason '(:h :c)) |
| 136 | (with-output-to-string (bitbucket) |
| 137 | (output-module *builtin-module* reason bitbucket))) |
| 138 | |
| 139 | (clear-the-decks)) |
| 140 | |
| 141 | ;;;-------------------------------------------------------------------------- |
| 142 | ;;; Make sure things work after loading the system. |
| 143 | |
| 144 | (clear-the-decks) |
| 145 | |
| 146 | ;;;----- That's all, folks -------------------------------------------------- |