| 1 | ;;; -*-lisp-*- |
| 2 | ;;; |
| 3 | ;;; Output for classes |
| 4 | ;;; |
| 5 | ;;; (c) 2009 Straylight/Edgeware |
| 6 | ;;; |
| 7 | |
| 8 | ;;;----- Licensing notice --------------------------------------------------- |
| 9 | ;;; |
| 10 | ;;; This file is part of the Sensble Object Design, an object system for C. |
| 11 | ;;; |
| 12 | ;;; SOD is free software; you can redistribute it and/or modify |
| 13 | ;;; it under the terms of the GNU General Public License as published by |
| 14 | ;;; the Free Software Foundation; either version 2 of the License, or |
| 15 | ;;; (at your option) any later version. |
| 16 | ;;; |
| 17 | ;;; SOD is distributed in the hope that it will be useful, |
| 18 | ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;;; GNU General Public License for more details. |
| 21 | ;;; |
| 22 | ;;; You should have received a copy of the GNU General Public License |
| 23 | ;;; along with SOD; if not, write to the Free Software Foundation, |
| 24 | ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 25 | |
| 26 | (cl:in-package #:sod) |
| 27 | |
| 28 | ;;;-------------------------------------------------------------------------- |
| 29 | ;;; Classes. |
| 30 | |
| 31 | (defmethod hook-output progn ((class sod-class) (reason (eql :h)) sequencer) |
| 32 | |
| 33 | ;; Main output sequencing. |
| 34 | (sequence-output (stream sequencer) |
| 35 | |
| 36 | :constraint |
| 37 | ((:classes :start) |
| 38 | (class :banner) |
| 39 | (class :islots :start) (class :islots :slots) (class :islots :end) |
| 40 | (class :vtmsgs :start) (class :vtmsgs :end) |
| 41 | (class :vtables :start) (class :vtables :end) |
| 42 | (class :vtable-externs) (class :vtable-externs-after) |
| 43 | (class :methods :start) (class :methods) (class :methods :end) |
| 44 | (class :ichains :start) (class :ichains :end) |
| 45 | (class :ilayout :start) (class :ilayout :slots) (class :ilayout :end) |
| 46 | (class :conversions) |
| 47 | (class :message-macros) |
| 48 | (class :object) |
| 49 | (:classes :end)) |
| 50 | |
| 51 | (:typedefs |
| 52 | (format stream "typedef struct ~A ~A;~%" |
| 53 | (ichain-struct-tag class (sod-class-chain-head class)) class)) |
| 54 | |
| 55 | ((class :banner) |
| 56 | (banner (format nil "Class ~A" class) stream)) |
| 57 | ((class :vtable-externs-after) |
| 58 | (terpri stream)) |
| 59 | |
| 60 | ((class :vtable-externs) |
| 61 | (format stream "/* Vtable structures. */~%")) |
| 62 | |
| 63 | ((class :object) |
| 64 | (let ((metaclass (sod-class-metaclass class)) |
| 65 | (metaroot (find-root-metaclass class))) |
| 66 | (format stream "/* The class object. */~@ |
| 67 | extern const struct ~A ~A__classobj;~@ |
| 68 | #define ~:*~A__class (&~:*~A__classobj.~A.~A)~2%" |
| 69 | (ilayout-struct-tag metaclass) class |
| 70 | (sod-class-nickname (sod-class-chain-head metaroot)) |
| 71 | (sod-class-nickname metaroot))))) |
| 72 | |
| 73 | ;; Maybe generate an islots structure. |
| 74 | (when (sod-class-slots class) |
| 75 | (dolist (slot (sod-class-slots class)) |
| 76 | (hook-output slot 'islots sequencer)) |
| 77 | (sequence-output (stream sequencer) |
| 78 | ((class :islots :start) |
| 79 | (format stream "/* Instance slots. */~@ |
| 80 | struct ~A {~%" |
| 81 | (islots-struct-tag class))) |
| 82 | ((class :islots :end) |
| 83 | (format stream "};~2%")))) |
| 84 | |
| 85 | ;; Declare the direct methods. |
| 86 | (when (sod-class-methods class) |
| 87 | (sequence-output (stream sequencer) |
| 88 | ((class :methods :start) |
| 89 | (format stream "/* Direct methods. */~%")) |
| 90 | ((class :methods :end) |
| 91 | (terpri stream)))) |
| 92 | |
| 93 | ;; Provide upcast macros which do the right thing. |
| 94 | (when (sod-class-direct-superclasses class) |
| 95 | (sequence-output (stream sequencer) |
| 96 | ((class :conversions) |
| 97 | (let ((chain-head (sod-class-chain-head class))) |
| 98 | (format stream "/* Conversion macros. */~%") |
| 99 | (dolist (super (cdr (sod-class-precedence-list class))) |
| 100 | (let ((super-head (sod-class-chain-head super))) |
| 101 | (format stream "#define ~:@(~A__CONV_~A~)(p) ((~A *)~ |
| 102 | ~:[SOD_XCHAIN(~A, (p))~;(p)~])~%" |
| 103 | class (sod-class-nickname super) super |
| 104 | (eq chain-head super-head) |
| 105 | (sod-class-nickname super-head)))) |
| 106 | (terpri stream))))) |
| 107 | |
| 108 | ;; Provide convenience macros for sending the newly defined messages. (The |
| 109 | ;; macros work on all subclasses too.) |
| 110 | ;; |
| 111 | ;; We need each message's method entry type for this, so we need to dig it |
| 112 | ;; out of the vtmsgs structure. Indeed, the vtmsgs for this class contains |
| 113 | ;; entries for precisely the messages we want to make macros for. |
| 114 | (when (sod-class-messages class) |
| 115 | (sequence-output (stream sequencer) |
| 116 | ((class :message-macros) |
| 117 | (let* ((vtable (find (sod-class-chain-head class) |
| 118 | (sod-class-vtables class) |
| 119 | :key #'vtable-chain-head)) |
| 120 | (vtmsgs (find-if (lambda (item) |
| 121 | (and (typep item 'vtmsgs) |
| 122 | (eql (vtmsgs-class item) class))) |
| 123 | (vtable-body vtable)))) |
| 124 | (format stream "/* Message invocation macros. */~%") |
| 125 | (dolist (entry (vtmsgs-entries vtmsgs)) |
| 126 | (let* ((type (method-entry-function-type entry)) |
| 127 | (args (c-function-arguments type)) |
| 128 | (method (method-entry-effective-method entry)) |
| 129 | (message (effective-method-message method)) |
| 130 | (in-names nil) (out-names nil) (varargsp nil) (me "me")) |
| 131 | (do ((args args (cdr args))) |
| 132 | ((endp args)) |
| 133 | (let* ((raw-name (argument-name (car args))) |
| 134 | (name (if (find raw-name |
| 135 | (list "_vt" |
| 136 | (sod-class-nickname class) |
| 137 | (sod-message-name message)) |
| 138 | :test #'string=) |
| 139 | (format nil "sod__a_~A" raw-name) |
| 140 | raw-name))) |
| 141 | (cond ((and (cdr args) (eq (cadr args) :ellipsis)) |
| 142 | (setf varargsp t) |
| 143 | (unless in-names (setf me "SOD__CAR(__VA_ARGS__)")) |
| 144 | (push (format nil "/*~A*/ ..." name) in-names) |
| 145 | (push "__VA_ARGS__" out-names) |
| 146 | (return)) |
| 147 | (t |
| 148 | (push name in-names) |
| 149 | (push name out-names))))) |
| 150 | (when varargsp |
| 151 | (format stream "#if __STDC_VERSION__ >= 199901~%")) |
| 152 | (format stream "#define ~A(~{~A~^, ~}) ~ |
| 153 | ~A->_vt->~A.~A(~{~A~^, ~})~%" |
| 154 | (message-macro-name class message) |
| 155 | (nreverse in-names) |
| 156 | me |
| 157 | (sod-class-nickname class) |
| 158 | (sod-message-name message) |
| 159 | (nreverse out-names)) |
| 160 | (when varargsp |
| 161 | (format stream "#endif~%")))) |
| 162 | (terpri stream))))) |
| 163 | |
| 164 | ;; Generate vtmsgs structure for all superclasses. |
| 165 | (hook-output (car (sod-class-vtables class)) |
| 166 | 'vtmsgs |
| 167 | sequencer)) |
| 168 | |
| 169 | (defmethod hook-output progn ((class sod-class) reason sequencer) |
| 170 | (with-slots (ilayout vtables methods effective-methods) class |
| 171 | (hook-output ilayout reason sequencer) |
| 172 | (dolist (method methods) (hook-output method reason sequencer)) |
| 173 | (dolist (method effective-methods) (hook-output method reason sequencer)) |
| 174 | (dolist (vtable vtables) (hook-output vtable reason sequencer)))) |
| 175 | |
| 176 | ;;;-------------------------------------------------------------------------- |
| 177 | ;;; Instance structure. |
| 178 | |
| 179 | (defmethod hook-output progn ((slot sod-slot) |
| 180 | (reason (eql 'islots)) |
| 181 | sequencer) |
| 182 | (sequence-output (stream sequencer) |
| 183 | (((sod-slot-class slot) :islots :slots) |
| 184 | (pprint-logical-block (stream nil :prefix " " :suffix ";") |
| 185 | (pprint-c-type (sod-slot-type slot) stream (sod-slot-name slot))) |
| 186 | (terpri stream)))) |
| 187 | |
| 188 | (defmethod hook-output progn ((ilayout ilayout) reason sequencer) |
| 189 | (with-slots (ichains) ilayout |
| 190 | (dolist (ichain ichains) (hook-output ichain reason sequencer)))) |
| 191 | |
| 192 | (defmethod hook-output progn ((ichain ichain) reason sequencer) |
| 193 | (dolist (item (ichain-body ichain)) |
| 194 | (hook-output item reason sequencer))) |
| 195 | |
| 196 | (defmethod hook-output progn ((ilayout ilayout) (reason (eql :h)) sequencer) |
| 197 | (with-slots (class ichains) ilayout |
| 198 | (sequence-output (stream sequencer) |
| 199 | ((class :ilayout :start) |
| 200 | (format stream "/* Instance layout. */~@ |
| 201 | struct ~A {~%" |
| 202 | (ilayout-struct-tag class))) |
| 203 | ((class :ilayout :end) |
| 204 | (format stream "};~2%"))) |
| 205 | (dolist (ichain ichains) |
| 206 | (hook-output ichain 'ilayout sequencer)))) |
| 207 | |
| 208 | (defmethod hook-output progn ((ichain ichain) (reason (eql :h)) sequencer) |
| 209 | (with-slots (class chain-head chain-tail) ichain |
| 210 | (when (eq class chain-tail) |
| 211 | (sequence-output (stream sequencer) |
| 212 | :constraint ((class :ichains :start) |
| 213 | (class :ichain chain-head :start) |
| 214 | (class :ichain chain-head :slots) |
| 215 | (class :ichain chain-head :end) |
| 216 | (class :ichains :end)) |
| 217 | ((class :ichain chain-head :start) |
| 218 | (format stream "/* Instance chain structure. */~@ |
| 219 | struct ~A {~%" |
| 220 | (ichain-struct-tag chain-tail chain-head))) |
| 221 | ((class :ichain chain-head :end) |
| 222 | (format stream "};~2%") |
| 223 | (format stream "/* Union of equivalent superclass chains. */~@ |
| 224 | union ~A {~@ |
| 225 | ~:{ struct ~A ~A;~%~}~ |
| 226 | };~2%" |
| 227 | (ichain-union-tag chain-tail chain-head) |
| 228 | |
| 229 | ;; Make sure the most specific class is first: only the |
| 230 | ;; first element of a union can be statically initialized in |
| 231 | ;; C90. |
| 232 | (mapcar (lambda (super) |
| 233 | (list (ichain-struct-tag super chain-head) |
| 234 | (sod-class-nickname super))) |
| 235 | (sod-class-chain chain-tail)))))))) |
| 236 | |
| 237 | (defmethod hook-output progn ((ichain ichain) |
| 238 | (reason (eql 'ilayout)) |
| 239 | sequencer) |
| 240 | (with-slots (class chain-head chain-tail) ichain |
| 241 | (sequence-output (stream sequencer) |
| 242 | ((class :ilayout :slots) |
| 243 | (format stream " union ~A ~A;~%" |
| 244 | (ichain-union-tag chain-tail chain-head) |
| 245 | (sod-class-nickname chain-head)))))) |
| 246 | |
| 247 | (defmethod hook-output progn ((vtptr vtable-pointer) |
| 248 | (reason (eql :h)) |
| 249 | sequencer) |
| 250 | (with-slots (class chain-head chain-tail) vtptr |
| 251 | (sequence-output (stream sequencer) |
| 252 | ((class :ichain chain-head :slots) |
| 253 | (format stream " const struct ~A *_vt;~%" |
| 254 | (vtable-struct-tag chain-tail chain-head)))))) |
| 255 | |
| 256 | (defmethod hook-output progn ((islots islots) reason sequencer) |
| 257 | (dolist (slot (islots-slots islots)) |
| 258 | (hook-output slot reason sequencer))) |
| 259 | |
| 260 | (defmethod hook-output progn ((islots islots) (reason (eql :h)) sequencer) |
| 261 | (with-slots (class subclass slots) islots |
| 262 | (sequence-output (stream sequencer) |
| 263 | ((subclass :ichain (sod-class-chain-head class) :slots) |
| 264 | (format stream " struct ~A ~A;~%" |
| 265 | (islots-struct-tag class) |
| 266 | (sod-class-nickname class)))))) |
| 267 | |
| 268 | ;;;-------------------------------------------------------------------------- |
| 269 | ;;; Vtable structure. |
| 270 | |
| 271 | (defmethod hook-output progn ((vtable vtable) reason sequencer) |
| 272 | (with-slots (body) vtable |
| 273 | (dolist (item body) (hook-output item reason sequencer)))) |
| 274 | |
| 275 | (defmethod hook-output progn ((method sod-method) |
| 276 | (reason (eql :h)) |
| 277 | sequencer) |
| 278 | (with-slots (class) method |
| 279 | (sequence-output (stream sequencer) |
| 280 | ((class :methods) |
| 281 | (let ((type (sod-method-function-type method))) |
| 282 | (princ "extern " stream) |
| 283 | (pprint-c-type (commentify-function-type type) stream |
| 284 | (sod-method-function-name method)) |
| 285 | (format stream ";~%")))))) |
| 286 | |
| 287 | (defmethod hook-output progn ((vtable vtable) (reason (eql :h)) sequencer) |
| 288 | (with-slots (class chain-head chain-tail) vtable |
| 289 | (when (eq class chain-tail) |
| 290 | (sequence-output (stream sequencer) |
| 291 | :constraint ((class :vtables :start) |
| 292 | (class :vtable chain-head :start) |
| 293 | (class :vtable chain-head :slots) |
| 294 | (class :vtable chain-head :end) |
| 295 | (class :vtables :end)) |
| 296 | ((class :vtable chain-head :start) |
| 297 | (format stream "/* Vtable structure. */~@ |
| 298 | struct ~A {~%" |
| 299 | (vtable-struct-tag chain-tail chain-head))) |
| 300 | ((class :vtable chain-head :end) |
| 301 | (format stream "};~2%")))) |
| 302 | (sequence-output (stream sequencer) |
| 303 | ((class :vtable-externs) |
| 304 | (format stream "~@<extern const struct ~A ~2I~_~A__vtable_~A;~:>~%" |
| 305 | (vtable-struct-tag chain-tail chain-head) |
| 306 | class (sod-class-nickname chain-head)))))) |
| 307 | |
| 308 | (defmethod hook-output progn ((vtmsgs vtmsgs) (reason (eql :h)) sequencer) |
| 309 | (with-slots (class subclass chain-head chain-tail) vtmsgs |
| 310 | (sequence-output (stream sequencer) |
| 311 | ((subclass :vtable chain-head :slots) |
| 312 | (format stream " struct ~A ~A;~%" |
| 313 | (vtmsgs-struct-tag subclass class) |
| 314 | (sod-class-nickname class)))))) |
| 315 | |
| 316 | (defmethod hook-output progn ((vtmsgs vtmsgs) |
| 317 | (reason (eql 'vtmsgs)) |
| 318 | sequencer) |
| 319 | (when (vtmsgs-entries vtmsgs) |
| 320 | (with-slots (class subclass) vtmsgs |
| 321 | (sequence-output (stream sequencer) |
| 322 | :constraint ((subclass :vtmsgs :start) |
| 323 | (subclass :vtmsgs class :start) |
| 324 | (subclass :vtmsgs class :slots) |
| 325 | (subclass :vtmsgs class :end) |
| 326 | (subclass :vtmsgs :end)) |
| 327 | ((subclass :vtmsgs class :start) |
| 328 | (format stream "/* Messages protocol from class ~A */~@ |
| 329 | struct ~A {~%" |
| 330 | class |
| 331 | (vtmsgs-struct-tag subclass class))) |
| 332 | ((subclass :vtmsgs class :end) |
| 333 | (format stream "};~2%")))))) |
| 334 | |
| 335 | (defmethod hook-output progn ((vtmsgs vtmsgs) reason sequencer) |
| 336 | (with-slots (entries) vtmsgs |
| 337 | (dolist (entry entries) (hook-output entry reason sequencer)))) |
| 338 | |
| 339 | (defmethod hook-output progn ((entry method-entry) |
| 340 | (reason (eql 'vtmsgs)) |
| 341 | sequencer) |
| 342 | (let* ((method (method-entry-effective-method entry)) |
| 343 | (message (effective-method-message method)) |
| 344 | (class (effective-method-class method)) |
| 345 | (function-type (method-entry-function-type entry)) |
| 346 | (commented-type (commentify-function-type function-type)) |
| 347 | (pointer-type (make-pointer-type commented-type))) |
| 348 | (sequence-output (stream sequencer) |
| 349 | ((class :vtmsgs (sod-message-class message) :slots) |
| 350 | (pprint-logical-block (stream nil :prefix " " :suffix ";") |
| 351 | (pprint-c-type pointer-type stream (sod-message-name message))) |
| 352 | (terpri stream))))) |
| 353 | |
| 354 | (defmethod hook-output progn ((cptr class-pointer) |
| 355 | (reason (eql :h)) |
| 356 | sequencer) |
| 357 | (with-slots (class chain-head metaclass meta-chain-head) cptr |
| 358 | (sequence-output (stream sequencer) |
| 359 | ((class :vtable chain-head :slots) |
| 360 | (format stream " const ~A *~:[_class~;~:*_cls_~A~];~%" |
| 361 | metaclass |
| 362 | (and (sod-class-direct-superclasses meta-chain-head) |
| 363 | (sod-class-nickname meta-chain-head))))))) |
| 364 | |
| 365 | (defmethod hook-output progn ((boff base-offset) (reason (eql :h)) sequencer) |
| 366 | (with-slots (class chain-head) boff |
| 367 | (sequence-output (stream sequencer) |
| 368 | ((class :vtable chain-head :slots) |
| 369 | (write-line " size_t _base;" stream))))) |
| 370 | |
| 371 | (defmethod hook-output progn ((choff chain-offset) |
| 372 | (reason (eql :h)) |
| 373 | sequencer) |
| 374 | (with-slots (class chain-head target-head) choff |
| 375 | (sequence-output (stream sequencer) |
| 376 | ((class :vtable chain-head :slots) |
| 377 | (format stream " ptrdiff_t _off_~A;~%" |
| 378 | (sod-class-nickname target-head)))))) |
| 379 | |
| 380 | ;;;-------------------------------------------------------------------------- |
| 381 | ;;; Implementation output. |
| 382 | |
| 383 | (defvar *instance-class*) |
| 384 | |
| 385 | (defmethod hook-output progn ((class sod-class) (reason (eql :c)) sequencer) |
| 386 | (sequence-output (stream sequencer) |
| 387 | |
| 388 | :constraint |
| 389 | ((:classes :start) |
| 390 | (class :banner) |
| 391 | (class :direct-methods :start) (class :direct-methods :end) |
| 392 | (class :effective-methods) |
| 393 | (class :vtables :start) (class :vtables :end) |
| 394 | (class :object :prepare) (class :object :start) (class :object :end) |
| 395 | (:classes :end)) |
| 396 | |
| 397 | ((class :banner) |
| 398 | (banner (format nil "Class ~A" class) stream)) |
| 399 | |
| 400 | ((class :object :start) |
| 401 | (format stream "~ |
| 402 | /* The class object. */ |
| 403 | const struct ~A ~A__classobj = {~%" |
| 404 | (ilayout-struct-tag (sod-class-metaclass class)) |
| 405 | class)) |
| 406 | ((class :object :end) |
| 407 | (format stream "};~2%"))) |
| 408 | |
| 409 | (let ((*instance-class* class)) |
| 410 | (hook-output (sod-class-ilayout (sod-class-metaclass class)) |
| 411 | 'class |
| 412 | sequencer))) |
| 413 | |
| 414 | ;;;-------------------------------------------------------------------------- |
| 415 | ;;; Direct and effective methods. |
| 416 | |
| 417 | (defmethod hook-output progn ((method delegating-direct-method) |
| 418 | (reason (eql :c)) |
| 419 | sequencer) |
| 420 | (with-slots (class body) method |
| 421 | (unless body |
| 422 | (return-from hook-output)) |
| 423 | (sequence-output (stream sequencer) |
| 424 | ((class :direct-method method :start) |
| 425 | (format stream "#define CALL_NEXT_METHOD (next_method(~{~A~^, ~}))~%" |
| 426 | (mapcar #'argument-name |
| 427 | (c-function-arguments (sod-method-next-method-type |
| 428 | method))))) |
| 429 | ((class :direct-method method :end) |
| 430 | (format stream "#undef CALL_NEXT_METHOD~%"))))) |
| 431 | |
| 432 | (defmethod hook-output progn ((method sod-method) |
| 433 | (reason (eql :c)) |
| 434 | sequencer) |
| 435 | (with-slots (class body) method |
| 436 | (unless body |
| 437 | (return-from hook-output)) |
| 438 | (sequence-output (stream sequencer) |
| 439 | :constraint ((class :direct-methods :start) |
| 440 | (class :direct-method method :start) |
| 441 | (class :direct-method method :body) |
| 442 | (class :direct-method method :end) |
| 443 | (class :direct-methods :end)) |
| 444 | ((class :direct-method method :body) |
| 445 | (pprint-c-type (sod-method-function-type method) |
| 446 | stream |
| 447 | (sod-method-function-name method)) |
| 448 | (format stream "~&{~%") |
| 449 | (write body :stream stream :pretty nil :escape nil) |
| 450 | (format stream "~&}~%")) |
| 451 | ((class :direct-method method :end) |
| 452 | (terpri stream))))) |
| 453 | |
| 454 | (defmethod hook-output progn ((method basic-effective-method) |
| 455 | (reason (eql :c)) |
| 456 | sequencer) |
| 457 | (with-slots (class functions) method |
| 458 | (sequence-output (stream sequencer) |
| 459 | ((class :effective-methods) |
| 460 | (dolist (func functions) |
| 461 | (write func :stream stream :escape nil :circle nil)))))) |
| 462 | |
| 463 | ;;;-------------------------------------------------------------------------- |
| 464 | ;;; Vtables. |
| 465 | |
| 466 | (defmethod hook-output progn ((vtable vtable) (reason (eql :c)) sequencer) |
| 467 | (with-slots (class chain-head chain-tail) vtable |
| 468 | (sequence-output (stream sequencer) |
| 469 | :constraint ((class :vtables :start) |
| 470 | (class :vtable chain-head :start) |
| 471 | (class :vtable chain-head :end) |
| 472 | (class :vtables :end)) |
| 473 | ((class :vtable chain-head :start) |
| 474 | (format stream "/* Vtable for ~A chain. */~@ |
| 475 | const struct ~A ~A = {~%" |
| 476 | chain-head |
| 477 | (vtable-struct-tag chain-tail chain-head) |
| 478 | (vtable-name class chain-head))) |
| 479 | ((class :vtable chain-head :end) |
| 480 | (format stream "};~2%"))))) |
| 481 | |
| 482 | (defmethod hook-output progn ((cptr class-pointer) |
| 483 | (reason (eql :c)) |
| 484 | sequencer) |
| 485 | (with-slots (class chain-head metaclass meta-chain-head) cptr |
| 486 | (sequence-output (stream sequencer) |
| 487 | :constraint ((class :vtable chain-head :start) |
| 488 | (class :vtable chain-head :class-pointer metaclass) |
| 489 | (class :vtable chain-head :end)) |
| 490 | ((class :vtable chain-head :class-pointer metaclass) |
| 491 | (format stream " /* ~21@A = */ &~A__classobj.~A.~A,~%" |
| 492 | (if (sod-class-direct-superclasses meta-chain-head) |
| 493 | (format nil "_cls_~A" |
| 494 | (sod-class-nickname meta-chain-head)) |
| 495 | "_class") |
| 496 | class |
| 497 | (sod-class-nickname meta-chain-head) |
| 498 | (sod-class-nickname metaclass)))))) |
| 499 | |
| 500 | (defmethod hook-output progn ((boff base-offset) (reason (eql :c)) sequencer) |
| 501 | (with-slots (class chain-head) boff |
| 502 | (sequence-output (stream sequencer) |
| 503 | :constraint ((class :vtable chain-head :start) |
| 504 | (class :vtable chain-head :base-offset) |
| 505 | (class :vtable chain-head :end)) |
| 506 | ((class :vtable chain-head :base-offset) |
| 507 | (format stream " /* ~21@A = */ offsetof(struct ~A, ~A),~%" |
| 508 | "_base" |
| 509 | (ilayout-struct-tag class) |
| 510 | (sod-class-nickname chain-head)))))) |
| 511 | |
| 512 | (defmethod hook-output progn ((choff chain-offset) |
| 513 | (reason (eql :c)) |
| 514 | sequencer) |
| 515 | (with-slots (class chain-head target-head) choff |
| 516 | (sequence-output (stream sequencer) |
| 517 | :constraint ((class :vtable chain-head :start) |
| 518 | (class :vtable chain-head :chain-offset target-head) |
| 519 | (class :vtable chain-head :end)) |
| 520 | ((class :vtable chain-head :chain-offset target-head) |
| 521 | (format stream " /* ~21@A = */ SOD_OFFSETDIFF(struct ~A, ~A, ~A),~%" |
| 522 | (format nil "_off_~A" (sod-class-nickname target-head)) |
| 523 | (ilayout-struct-tag class) |
| 524 | (sod-class-nickname chain-head) |
| 525 | (sod-class-nickname target-head)))))) |
| 526 | |
| 527 | (defmethod hook-output progn ((vtmsgs vtmsgs) (reason (eql :c)) sequencer) |
| 528 | (with-slots (class subclass chain-head) vtmsgs |
| 529 | (sequence-output (stream sequencer) |
| 530 | :constraint ((subclass :vtable chain-head :start) |
| 531 | (subclass :vtable chain-head :vtmsgs class :start) |
| 532 | (subclass :vtable chain-head :vtmsgs class :slots) |
| 533 | (subclass :vtable chain-head :vtmsgs class :end) |
| 534 | (subclass :vtable chain-head :end)) |
| 535 | ((subclass :vtable chain-head :vtmsgs class :start) |
| 536 | (format stream " { /* Method entries for ~A messages. */~%" |
| 537 | class)) |
| 538 | ((subclass :vtable chain-head :vtmsgs class :end) |
| 539 | (format stream " },~%"))))) |
| 540 | |
| 541 | (defmethod hook-output progn ((entry method-entry) |
| 542 | (reason (eql :c)) |
| 543 | sequencer) |
| 544 | (with-slots (method chain-head chain-tail) entry |
| 545 | (let* ((message (effective-method-message method)) |
| 546 | (class (effective-method-class method)) |
| 547 | (super (sod-message-class message))) |
| 548 | (sequence-output (stream sequencer) |
| 549 | ((class :vtable chain-head :vtmsgs super :slots) |
| 550 | (format stream " /* ~19@A = */ ~A,~%" |
| 551 | (sod-message-name message) |
| 552 | (method-entry-function-name method chain-head))))))) |
| 553 | |
| 554 | ;;;-------------------------------------------------------------------------- |
| 555 | ;;; Filling in the class object. |
| 556 | |
| 557 | (defmethod hook-output progn ((ichain ichain) |
| 558 | (reason (eql 'class)) |
| 559 | sequencer) |
| 560 | (with-slots (class chain-head) ichain |
| 561 | (sequence-output (stream sequencer) |
| 562 | :constraint ((*instance-class* :object :start) |
| 563 | (*instance-class* :object chain-head :ichain :start) |
| 564 | (*instance-class* :object chain-head :ichain :end) |
| 565 | (*instance-class* :object :end)) |
| 566 | ((*instance-class* :object chain-head :ichain :start) |
| 567 | (format stream " { { /* ~A ichain */~%" |
| 568 | (sod-class-nickname chain-head))) |
| 569 | ((*instance-class* :object chain-head :ichain :end) |
| 570 | (format stream " } },~%"))))) |
| 571 | |
| 572 | (defmethod hook-output progn ((islots islots) |
| 573 | (reason (eql 'class)) |
| 574 | sequencer) |
| 575 | (with-slots (class) islots |
| 576 | (let ((chain-head (sod-class-chain-head class))) |
| 577 | (sequence-output (stream sequencer) |
| 578 | :constraint ((*instance-class* :object chain-head :ichain :start) |
| 579 | (*instance-class* :object class :slots :start) |
| 580 | (*instance-class* :object class :slots) |
| 581 | (*instance-class* :object class :slots :end) |
| 582 | (*instance-class* :object chain-head :ichain :end)) |
| 583 | ((*instance-class* :object class :slots :start) |
| 584 | (format stream " { /* Class ~A */~%" class)) |
| 585 | ((*instance-class* :object class :slots :end) |
| 586 | (format stream " },~%")))))) |
| 587 | |
| 588 | (defmethod hook-output progn ((vtptr vtable-pointer) |
| 589 | (reason (eql 'class)) |
| 590 | sequencer) |
| 591 | (with-slots (class chain-head chain-tail) vtptr |
| 592 | (sequence-output (stream sequencer) |
| 593 | :constraint ((*instance-class* :object chain-head :ichain :start) |
| 594 | (*instance-class* :object chain-head :vtable) |
| 595 | (*instance-class* :object chain-head :ichain :end)) |
| 596 | ((*instance-class* :object chain-head :vtable) |
| 597 | (format stream " &~A__vtable_~A,~%" |
| 598 | class (sod-class-nickname chain-head)))))) |
| 599 | |
| 600 | (defgeneric find-class-initializer (slot class) |
| 601 | (:method ((slot effective-slot) (class sod-class)) |
| 602 | (let ((dslot (effective-slot-direct-slot slot))) |
| 603 | (or (some (lambda (super) |
| 604 | (find dslot (sod-class-class-initializers super) |
| 605 | :test #'sod-initializer-slot)) |
| 606 | (sod-class-precedence-list class)) |
| 607 | (effective-slot-initializer slot))))) |
| 608 | |
| 609 | (defgeneric output-class-initializer (slot instance stream) |
| 610 | (:method ((slot sod-class-effective-slot) (instance sod-class) stream) |
| 611 | (let ((func (effective-slot-initializer-function slot)) |
| 612 | (direct-slot (effective-slot-direct-slot slot))) |
| 613 | (if func |
| 614 | (format stream " /* ~15@A = */ ~A,~%" |
| 615 | (sod-slot-name direct-slot) |
| 616 | (funcall func instance)) |
| 617 | (call-next-method)))) |
| 618 | (:method ((slot effective-slot) (instance sod-class) stream) |
| 619 | (let ((init (find-class-initializer slot instance)) |
| 620 | (direct-slot (effective-slot-direct-slot slot))) |
| 621 | (ecase (sod-initializer-value-kind init) |
| 622 | (:simple (format stream " /* ~15@A = */ ~A,~%" |
| 623 | (sod-slot-name direct-slot) |
| 624 | (sod-initializer-value-form init))) |
| 625 | (:compound (format stream " /* ~15@A = */ ~@<{ ~;~A~; },~:>~%" |
| 626 | (sod-slot-name direct-slot) |
| 627 | (sod-initializer-value-form init))))))) |
| 628 | |
| 629 | (defmethod hook-output progn ((slot sod-class-effective-slot) |
| 630 | (reason (eql 'class)) |
| 631 | sequencer) |
| 632 | (let ((instance *instance-class*) |
| 633 | (func (effective-slot-prepare-function slot))) |
| 634 | (when func |
| 635 | (sequence-output (stream sequencer) |
| 636 | ((instance :object :prepare) |
| 637 | (funcall func instance stream)))))) |
| 638 | |
| 639 | (defmethod hook-output progn ((slot effective-slot) |
| 640 | (reason (eql 'class)) |
| 641 | sequencer) |
| 642 | (with-slots (class (dslot slot)) slot |
| 643 | (let ((instance *instance-class*) |
| 644 | (super (sod-slot-class dslot))) |
| 645 | (sequence-output (stream sequencer) |
| 646 | ((instance :object super :slots) |
| 647 | (output-class-initializer slot instance stream)))))) |
| 648 | |
| 649 | ;;;----- That's all, folks -------------------------------------------------- |