Alain Guibert points out that palette changes weren't causing the space

[sgt/putty] / windows / putty.iss

; -*- no -*-\r
; putty.iss\r
;\r
; -- Inno Setup installer script for PuTTY and its related tools.\r
;\r
; TODO for future releases:\r
;\r
;  - It might be nice to have an option to add PSCP, Plink and PSFTP to\r
;    the PATH. This is probably only practical on NT-class systems; I\r
;    believe doing this on 9x would require mucking around with\r
;    AUTOEXEC.BAT.\r
;\r
;  - Maybe a "custom" installation might be useful? Hassle with icons,\r
;    though.\r
\r
[Setup]\r
AppName=PuTTY\r
AppVerName=PuTTY version 0.58\r
VersionInfoTextVersion=Release 0.58\r
AppVersion=0.58\r
;FIXME -- enable this when we've got it going for individual EXEs too\r
;         and are committed to the version numbering scheme.\r
;VersionInfoVersion=0.58.0.0\r
AppPublisher=Simon Tatham\r
AppPublisherURL=http://www.chiark.greenend.org.uk/~sgtatham/putty/\r
AppReadmeFile={app}\README.txt\r
DefaultDirName={pf}\PuTTY\r
DefaultGroupName=PuTTY\r
UninstallDisplayIcon={app}\putty.exe\r
ChangesAssociations=yes\r
;ChangesEnvironment=yes -- when PATH munging is sorted (probably)\r
Compression=zip/9\r
AllowNoIcons=yes\r
\r
[Files]\r
Source: "putty.exe"; DestDir: "{app}"\r
Source: "pageant.exe"; DestDir: "{app}"\r
Source: "puttygen.exe"; DestDir: "{app}"\r
Source: "pscp.exe"; DestDir: "{app}"\r
Source: "psftp.exe"; DestDir: "{app}"\r
Source: "plink.exe"; DestDir: "{app}"\r
Source: "website.url"; DestDir: "{app}"\r
Source: "..\doc\putty.hlp"; DestDir: "{app}"\r
Source: "..\doc\putty.cnt"; DestDir: "{app}"\r
Source: "..\LICENCE"; DestDir: "{app}"\r
Source: "..\README.txt"; DestDir: "{app}"; Flags: isreadme\r
\r
[Icons]\r
Name: "{group}\PuTTY"; Filename: "{app}\putty.exe"; Comment: "SSH, Telnet and Rlogin client";\r
Name: "{group}\PuTTY Manual"; Filename: "{app}\putty.hlp"\r
Name: "{group}\PuTTY Web Site"; Filename: "{app}\website.url"\r
Name: "{group}\PSFTP"; Filename: "{app}\psftp.exe"; Comment: "Command-line interactive SFTP client"\r
Name: "{group}\PuTTYgen"; Filename: "{app}\puttygen.exe"; Comment: "PuTTY SSH key generation utility"\r
Name: "{group}\Pageant"; Filename: "{app}\pageant.exe"; Comment: "PuTTY SSH authentication agent"\r
Name: "{commondesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\common\r
Name: "{userdesktop}\PuTTY"; Filename: "{app}\putty.exe"; Tasks: desktopicon\user\r
; Putting this in {commonappdata} doesn't seem to work, on 98SE at least.\r
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\PuTTY"; Filename: "{app}\putty.exe"; Tasks: quicklaunchicon\r
\r
[Tasks]\r
Name: desktopicon; Description: "Create a &desktop icon for PuTTY"; GroupDescription: "Additional icons:"; Flags: unchecked\r
Name: desktopicon\common; Description: "For all users"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked\r
Name: desktopicon\user; Description: "For the current user only"; GroupDescription: "Additional icons:"; Flags: exclusive unchecked\r
Name: quicklaunchicon; Description: "Create a &Quick Launch icon for PuTTY (current user only)"; GroupDescription: "Additional icons:"; Flags: unchecked\r
Name: associate; Description: "&Associate .PPK files (PuTTY Private Key) with Pageant and PuTTYgen"; GroupDescription: "Other tasks:"\r
\r
[Registry]\r
Root: HKCR; Subkey: ".ppk"; ValueType: string; ValueName: ""; ValueData: "PuTTYPrivateKey"; Flags: uninsdeletevalue; Tasks: associate\r
Root: HKCR; Subkey: "PuTTYPrivateKey"; ValueType: string; ValueName: ""; ValueData: "PuTTY Private Key File"; Flags: uninsdeletekey; Tasks: associate\r
Root: HKCR; Subkey: "PuTTYPrivateKey\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\pageant.exe,0"; Tasks: associate\r
Root: HKCR; Subkey: "PuTTYPrivateKey\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\pageant.exe"" ""%1"""; Tasks: associate\r
Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit"; ValueType: string; ValueName: ""; ValueData: "&Edit"; Tasks: associate\r
Root: HKCR; Subkey: "PuTTYPrivateKey\shell\edit\command"; ValueType: string; ValueName: ""; ValueData: """{app}\puttygen.exe"" ""%1"""; Tasks: associate\r
; Add to PATH on NT-class OS?\r
\r
[UninstallRun]\r
; -cleanup-during-uninstall is an undocumented option that tailors the\r
; message displayed.\r
Filename: "{app}\putty.exe"; Parameters: "-cleanup-during-uninstall"; RunOnceId: "PuTTYCleanup"; StatusMsg: "Cleaning up saved sessions etc (optional)..."\r