| 1 | /* -*-c-*- |
| 2 | * |
| 3 | * Replacement tensioner for the Sparrows disc-detainer picking tool |
| 4 | * |
| 5 | * (c) 2023 Mark Wooding |
| 6 | */ |
| 7 | |
| 8 | /*----- Licensing notice --------------------------------------------------* |
| 9 | * |
| 10 | * This program is free software: you can redistribute it and/or modify |
| 11 | * it under the terms of the GNU General Public License as published by |
| 12 | * the Free Software Foundation; either version 3 of the License, or (at |
| 13 | * your option) any later version. |
| 14 | * |
| 15 | * This program is distributed in the hope that it will be useful, but |
| 16 | * WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| 18 | * General Public License for more details. |
| 19 | * |
| 20 | * You should have received a copy of the GNU General Public License |
| 21 | * along with this program. If not, see <https://www.gnu.org/licenses/>. |
| 22 | */ |
| 23 | |
| 24 | /*----- Configuration -----------------------------------------------------*/ |
| 25 | |
| 26 | /* Overall scaling. */ |
| 27 | MM = 1; |
| 28 | |
| 29 | /* Curvature quality. */ |
| 30 | $fa = 0.1; |
| 31 | $fs = 0.2*MM; |
| 32 | |
| 33 | /* A `large enough' length; effectively infinite. */ |
| 34 | BIG = 50*MM; |
| 35 | |
| 36 | /* Dimensions. */ |
| 37 | STOCK_DIAM = 5.5*MM; /* stock diemeter */ |
| 38 | STOCK_LENGTH = 35*MM; /* total stock length */ |
| 39 | SQUARE_SIDE = 4.5*MM; /* square section side */ |
| 40 | SQUARE_LENGTH = 26*MM; /* length of square section */ |
| 41 | DRILL_DIAM = 1.6*MM; /* hole diameter for picking tip */ |
| 42 | PRONG_DIAM = 3.3*MM; /* hole diameter to form prongs */ |
| 43 | PRONG_DEPTH = 6*MM; /* depth of prong hole */ |
| 44 | PRONG_LENGTH = 4.5*MM; /* prong length */ |
| 45 | PRONG_HEIGHT = 2.5*MM; /* prong height */ |
| 46 | |
| 47 | /*----- The main object ---------------------------------------------------*/ |
| 48 | |
| 49 | difference() { |
| 50 | |
| 51 | /* Start with a cylinder. */ |
| 52 | rotate([0, 90, 0]) |
| 53 | cylinder(h = STOCK_LENGTH, r = STOCK_DIAM/2); |
| 54 | |
| 55 | /* And now we cut things away. */ |
| 56 | union() { |
| 57 | |
| 58 | /* First, put the flat sides so that the tensioning arms can grip it. */ |
| 59 | for (theta = [0 : 90 : 270]) |
| 60 | rotate([theta, 0, 0]) |
| 61 | translate([0, -BIG/2, SQUARE_SIDE/2]) |
| 62 | cube([SQUARE_LENGTH, BIG, BIG]); |
| 63 | |
| 64 | /* Drill a hole all the way through for the picking tip. */ |
| 65 | rotate([0, 90, 0]) |
| 66 | cylinder(h = BIG, r = DRILL_DIAM/2); |
| 67 | |
| 68 | /* Drill a hole in the end to form the gap between the prongs. */ |
| 69 | translate([STOCK_LENGTH - PRONG_DEPTH, 0, 0]) |
| 70 | rotate([0, 90, 0]) |
| 71 | cylinder(h = BIG, r = PRONG_DIAM/2); |
| 72 | |
| 73 | /* Finally, shave off top and bottom to form the prongs themselves. */ |
| 74 | for (theta = [0 : 180 : 180]) |
| 75 | rotate([theta, 0, 0]) |
| 76 | translate([STOCK_LENGTH - PRONG_LENGTH, |
| 77 | -BIG/2, |
| 78 | (STOCK_DIAM - PRONG_HEIGHT)/2]) |
| 79 | cube(BIG); |
| 80 | } |
| 81 | } |