dnl -*-autoconf-*-

### SYNOPSIS
###
###   mdw_DIR_TEXMF
###
### DESCRIPTION
###
###   Define the substitution `@texmfdir@' to name a sensible TeX
###   installation root directory.
###
###   A `--with-texmfdir' command-line option is defined, which allows the
###   end user to select a specific installation root.  The default is chosen
###   according to a heuristic, which is currently to use the first of
###
###     * `DATADIR/texmf',
###     * `PREFIX/lib/texmf',
###     * `PREFIX/texmf',
###     * `LIBDIR/lib/texmf'.
###
### LICENSE
###
###   Copyright (c) 2002 Mark Wooding <mdw@distorted.org.uk>
###
###   This program is free software: you can redistribute it and/or modify it
###   under the terms of the GNU General Public License as published by the
###   Free Software Foundation, either version 2 of the License, or (at your
###   option) any later version.
###
###   This program is distributed in the hope that it will be useful, but
###   WITHOUT ANY WARRANTY; without even the implied warranty of
###   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
###   General Public License for more details.
###
###   You should have received a copy of the GNU General Public License along
###   with this program. If not, see <http://www.gnu.org/licenses/>.
###
###   As a special exception, the respective Autoconf Macro's copyright owner
###   gives unlimited permission to copy, distribute and modify the configure
###   scripts that are the output of Autoconf when processing the Macro. You
###   need not follow the terms of the GNU General Public License when using
###   or distributing such scripts, even though portions of the text of the
###   Macro appear in them. The GNU General Public License (GPL) does govern
###   all other use of the material that constitutes the Autoconf Macro.
###
###   This special exception to the GPL applies to versions of the Autoconf
###   Macro released by the Autoconf Archive. When you make and distribute a
###   modified version of the Autoconf Macro, you may extend this special
###   exception to the GPL to apply to your modified version as well.

# serial 1
AC_DEFUN([mdw_DIR_TEXMF],
[AC_ARG_WITH([texmfdir],
	     [AS_HELP_STRING([--with-texmfdir=DIR],
			     [set the TeX install directory to DIR])],
	     [texmfdir=$withval],
	     [texmfdir=guess])
case $texmfdir in
  guess)
    AC_MSG_CHECKING([where to put installed TeX files])
    mdw_DEFINE_PATHS([
      texmfdir='${datadir}/texmf'
      for d in \
	'${datadir}/texmf' '${prefix}/lib/texmf' \
	'${prefix}/texmf' '${libdir}/lib/texmf'
      do
	if test -d "mdw_PATH([$d])"; then texmfdir=$d; break; fi
      done])
    AC_MSG_RESULT([$texmfdir])
    ;;
esac
AC_SUBST(texmfdir)])