dnl -*-autoconf-*-
dnl
dnl Build-time configuration for rsync-backup
dnl
dnl (c) 2012 Mark Wooding
dnl

dnl----- Licensing notice ---------------------------------------------------
dnl
dnl This file is part of the `rsync-backup' program.
dnl
dnl rsync-backup is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl
dnl rsync-backup is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with rsync-backup; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl--------------------------------------------------------------------------
dnl Initialization.

mdw_AUTO_VERSION
AC_INIT([rsync-backup], AUTO_VERSION, [mdw@distorted.org.uk])
AC_CONFIG_SRCDIR([rsync-backup.in])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([foreign])
mdw_SILENT_RULES

dnl--------------------------------------------------------------------------
dnl Paths.

AC_ARG_WITH([mntbkpdir],
  AS_HELP_STRING([--with-mntbkpdir], [location of the backup mount tree]),
  [mntbkpdir=$withval],
  [mntbkpdir=/mnt/bkp])
AC_SUBST([mntbkpdir])

AC_ARG_WITH([fshashdir],
  AS_HELP_STRING([--with-fshashdir], [location for fshash cache files]),
  [fshashdir=$withval],
  [fshashdir=$localstatedir/cache/fshash])
AC_SUBST([fshashdir])

AC_ARG_WITH([logdir],
  AS_HELP_STRING([--with-logdir], [location for logfiles]),
  [logdir=$withval],
  [logdir=$localstatedir/log/bkp])
AC_SUBST([logdir])

dnl--------------------------------------------------------------------------
dnl Programming environments.

dnl C compilers and libraries.
AC_PROG_CC
AX_CFLAGS_WARN_ALL
PKG_CHECK_MODULES([mLib], [mLib >= 2.2.1], [have_mlib=t], [have_mlib=nil])
AM_CONDITIONAL([HAVE_MLIB], [test $have_mlib = t])

dnl Bourne-Again Shell.
AC_PATH_PROG([BASH], [bash])

dnl Python.
AC_PATH_PROG([PYTHON], [python])
AX_PROG_PYTHON_VERSION([2.5],,
	[AC_MSG_ERROR([Failed to find suitable Python.])])

dnl--------------------------------------------------------------------------
dnl Output.

AC_CONFIG_FILES([Makefile])
AC_OUTPUT

dnl----- That's all, folks --------------------------------------------------