dot/lisp-init.lisp: Use actual variable names rather than gensyms.

[profile] / dot / lisp-init.lisp

(cl:defpackage #:mdw-hacks
  (:use #:cl)
  (:export #:crank-swank))
(cl:defparameter mdw-hacks::*previous-package* cl:*package*)
(cl:in-package #:mdw-hacks)

;; Obtain ASDF from somewhere.
#+sbcl (require :asdf)
#+clisp (let ((*compile-verbose* nil)
	      (*load-verbose* nil))
	  (handler-bind ((warning (lambda (cond)
				    (declare (ignore cond))
				    (muffle-warning))))
	    (load "/usr/share/common-lisp/source/cl-asdf/asdf.lisp"
		  :verbose nil)
	    (funcall (find-symbol "LOAD-SYSTEM" :asdf) :asdf
		     :verbose nil)))

;; Shut up.
(setf *load-verbose* nil)
(setf *compile-verbose* nil)
#+cmu (setf *gc-verbose* nil)

;; Tell SBCL where to find its source source.
#+sbcl
(sb-ext:set-sbcl-source-location #p"/usr/share/sbcl-source/")

;; Tell some Lisps about my home directory.
#+(and unix (or sbcl clisp))
(let* ((homestring (or #+sbcl (sb-ext:posix-getenv "HOME")
		       #+clisp (ext:getenv "HOME")
		       #+cmu (unix:unix-getenv "HOME")
		       "/home/mdw"))
       (home (pathname (concatenate 'string homestring "/"))))
  (setf (logical-pathname-translations "HOME")
	`(("HOME:**;*.*.*" ,(merge-pathnames "**/*.*" home nil)))
	(logical-pathname-translations "CL")
	'(("CL:SOURCE;**;*.*.*" #p"/usr/share/common-lisp/source/**/*.*")
	  ("CL:SYSTEMS;**;*.*.*" #p"/usr/share/common-lisp/systems/**/*.*"))))

;; Various fixings.
#+clisp (setf custom:*parse-namestring-ansi* t)

;; Shebang.
(set-dispatch-macro-character
 #\# #\!
 (lambda (stream char arg)
   (declare (ignore char arg))
   (values (read-line stream))))

;; Start up swank.
(defun crank-swank (&rest args)
  (let ((swank (find-package "SWANK")))
    (unless swank
      (load "/usr/share/common-lisp/source/slime/swank-loader.lisp")
      (setf swank (find-package "SWANK")))
    (set (find-symbol "*GLOBAL-DEBUGGER*" swank) nil)
    (apply (find-symbol "CREATE-SERVER" swank) args)))

#+asdf (setf asdf:*compile-file-failure-behaviour* :warn)

;; Done.
(pushnew :mdw *features*)
;;#+(and cmu mp) (mp::startup-idle-and-top-level-loops)
(setf *package* *previous-package*)