@@@ all the mess ever

[mLib] / configure.ac

dnl -*-autoconf-*-
dnl
dnl Configuration script for mLib
dnl
dnl (c) 2008 Straylight/Edgeware
dnl

dnl----- Licensing notice ---------------------------------------------------
dnl
dnl This file is part of the mLib utilities library.
dnl
dnl mLib is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU Library General Public License as
dnl published by the Free Software Foundation; either version 2 of the
dnl License, or (at your option) any later version.
dnl
dnl mLib is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU Library General Public License for more details.
dnl
dnl You should have received a copy of the GNU Library General Public
dnl License along with mLib; if not, write to the Free
dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
dnl MA 02111-1307, USA.

dnl--------------------------------------------------------------------------
dnl Initialization.

mdw_AUTO_VERSION
AC_INIT([mLib], AUTO_VERSION, [mdw@distorted.org.uk], [mLib])
AC_CONFIG_SRCDIR([mLib.pc.in])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([foreign subdir-objects])
mdw_SILENT_RULES

AC_PROG_CC
AM_PROG_CC_C_O
AM_PROG_LIBTOOL
AX_CFLAGS_WARN_ALL
mdw_LIBTOOL_VERSION_INFO

AC_CHECK_PROGS([AUTOM4TE], [autom4te])

mdw_MANEXT([mLib])

AC_DEFINE_UNQUOTED([SRCDIR], ["$(cd $srcdir && pwd)"],
		   [absolute pathname for the source directory.])

dnl--------------------------------------------------------------------------
dnl C programming environment.

MLIB_LIBS=

dnl Headers.
AC_CHECK_HEADERS([float.h])
AC_CHECK_HEADERS([stdint.h])

dnl Libraries.
mdw_ORIG_LIBS=$LIBS LIBS=$MLIB_LIBS
AC_SEARCH_LIBS([sqrt], [m])
AC_SEARCH_LIBS([socket], [socket])
AC_SEARCH_LIBS([gethostbyname], [nsl resolv])
MLIB_LIBS=$LIBS LIBS=$mdw_ORIG_LIBS

dnl Functions.
AC_CHECK_FUNCS([snprintf])

dnl Types.
AC_CHECK_TYPE([socklen_t], [],
  [AC_DEFINE([socklen_t], [int],
     [Define to `int' if <sys/socket.h> does not define])],
  [AC_INCLUDES_DEFAULT
#include <sys/socket.h>
])

dnl Which version of struct msghdr do we have?
AC_CHECK_MEMBERS([struct msgdr.msg_control],,, [
#include <sys/types.h>
#include <sys/socket.h>
])

dnl Find out whether we're cross-compiling.
AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])

dnl Set the master library list.
AC_SUBST([MLIB_LIBS])

dnl--------------------------------------------------------------------------
dnl Name resolution.

AC_ARG_WITH([adns],
  AS_HELP_STRING([--with-adns],
		 [use ADNS library for background name resolution]),
  [want_adns=$withval],
  [want_adns=auto])

mdw_ORIG_LIBS=$LIBS LIBS=$MLIB_LIBS
case $want_adns in
  no) ;;
  *) AC_SEARCH_LIBS([adns_init], [adns], [have_adns=yes], [have_adns=no]) ;;
esac
MLIB_LIBS=$LIBS LIBS=$mdw_ORIG_LIBS
case $want_adns,$have_adns in
  yes,no)
    AC_MSG_ERROR([ADNS library not found but explicitly requested])
    ;;
  yes,yes | auto,yes)
    use_adns=yes
    AC_DEFINE([HAVE_ADNS], [1],
	      [define if you have (and want to use) the ADNS library.])
    ;;
  no,* | auto,no)
    use_adns=no
    mdw_DEFINE_PATHS([
      AC_DEFINE_UNQUOTED([BRES_SERVER],
			 ["mdw_PATH($libexecdir)/$PACKAGE/mdw_PROG(bres)"],
			 [pathname to the standalone `bres' binary.'])
    ])
    ;;
esac
AM_CONDITIONAL([WITH_ADNS], [test "$use_adns" = yes])

dnl--------------------------------------------------------------------------
dnl Timers.

AC_CHECK_HEADERS([linux/perf_event.h])

mdw_ORIG_LIBS=$LIBS LIBS=$MLIB_LIBS
AC_SEARCH_LIBS([clock_gettime], [rt])
MLIB_LIBS=$LIBS LIBS=$mdw_ORIG_LIBS
if test "$ac_cv_search_clock_gettime" != no; then
  AC_DEFINE([HAVE_CLOCK_GETTIME], [1],
	    [Define if you have the \`clock_gettime' function.])
fi

dnl--------------------------------------------------------------------------
dnl Python (used for testing).

AM_PATH_PYTHON([2.4],, [:])

dnl--------------------------------------------------------------------------
dnl Output.

AC_CONFIG_HEADER([config/config.h])
AC_CONFIG_TESTDIR([t])

AC_CONFIG_FILES(
  [Makefile]
  [buf/Makefile]
  [codec/Makefile]
  [hash/Makefile]
  [mem/Makefile]
  [sel/Makefile]
  [struct/Makefile]
  [sys/Makefile]
  [test/Makefile]
  [trace/Makefile]
  [ui/Makefile]
  [utils/Makefile]
  [t/Makefile t/atlocal])
AC_OUTPUT

dnl------ That's all, folks -------------------------------------------------