### -*-pyrex-*-
###
### Universal hashing interface
###
### (c) 2005 Straylight/Edgeware
###

###----- Licensing notice ---------------------------------------------------
###
### This file is part of the Python interface to mLib.
###
### mLib/Python is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### mLib/Python is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with mLib/Python; if not, write to the Free Software Foundation,
### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

def setglobalkey(uint32 k):
  """setglobalkey(K): set global hash key"""
  unihash_setkey(&unihash_global, k)

cdef class UnihashKey:
  """Key(K): universal hashing key"""
  cdef unihash_info _i
  cdef readonly uint32 k
  def __cinit__(me, uint32 k):
    unihash_setkey(&me._i, k)
    me.k = k
  def hash(me, object data):
    return _unihash_hash(me, data)

## DEPRECATED: compatibility hack
Key = UnihashKey

cdef const unihash_info *_unihash_keydata(UnihashKey key):
  if key is None:
    return &unihash_global
  else:
    return &key._i

cdef uint32 _unihash_hash(UnihashKey key, object data):
  cdef const void *p
  cdef Py_ssize_t n
  cdef const unihash_info *i = _unihash_keydata(key)
  PyObject_AsReadBuffer(data, &p, &n)
  return unihash_hash(i, UNIHASH_INIT(i), p, n)

cdef class Unihash:
  """Unihash([key = None]): universal hashing context"""
  cdef uint32 _a
  cdef readonly UnihashKey key
  cdef const unihash_info *_i
  def __init__(me, UnihashKey key = None):
    me.key = key
    me._i = _unihash_keydata(key)
    me._a = UNIHASH_INIT(me._i)
  def chunk(me, data):
    """U.chunk(BYTES): hash the STR"""
    cdef const void *p
    cdef Py_ssize_t n
    PyObject_AsReadBuffer(data, &p, &n)
    me._a = unihash_hash(me._i, me._a, p, n)
    return me
  def done(me):
    """U.done() -> INT: the hash of the data"""
    return me._a
  @classmethod
  def hash(cls, data, UnihashKey key = None):
    """Unihash.hash(BYTES, [key = None]) -> INT: the hash of the data"""
    return _unihash_hash(key, data)

###----- That's all, folks --------------------------------------------------