@@@ cython and python3

[mLib-python] / assoc.pyx

### -*-pyrex-*-
###
### Association tables
###
### (c) 2005 Straylight/Edgeware
###

###----- Licensing notice ---------------------------------------------------
###
### This file is part of the Python interface to mLib.
###
### mLib/Python is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### mLib/Python is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with mLib/Python; if not, write to the Free Software Foundation,
### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

cdef struct _assoc_entry:
  sym_base _b
  PyObject *v

cdef class AssocTable (_Mapping):
  cdef assoc_table _t
  def __cinit__(me):
    assoc_create(&me._t)
  cdef int _init(me) except -1:
    return 0
  cdef void *_find(me, object key, unsigned *f) except NULL:
    cdef _assoc_entry *e = NULL
    cdef object a = atom_pyintern(key)
    if not f:
      e = <_assoc_entry *>assoc_find(&me._t, ATOM_A(a), 0, NULL)
      if not e:
        raise KeyError(a)
    else:
      e = <_assoc_entry *>assoc_find(&me._t, ATOM_A(a), PSIZEOF(e), f)
      if not f[0]:
        e.v = NULL
    return <void *>e
  cdef object _key(me, void *e):
    return atom_pywrap(ASSOC_ATOM(e))
  cdef object _value(me, void *e):
    cdef _assoc_entry *ee = <_assoc_entry *>e
    Py_INCREF(ee.v)
    return <object>ee.v
  cdef void _setval(me, void *e, object val):
    cdef _assoc_entry *ee = <_assoc_entry *>e
    if ee.v:
      Py_DECREF(ee.v)
    ee.v = <PyObject *>val
    Py_INCREF(ee.v)
  cdef void _del(me, void *e):
    cdef _assoc_entry *ee = <_assoc_entry *>e
    if ee.v:
      Py_DECREF(ee.v)
    assoc_remove(&me._t, <void *>ee)
  cdef _MapIterator _iter(me):
    return _AssocIter(me)

cdef class _AssocIter (_MapIterator):
  cdef AssocTable t
  cdef assoc_iter i
  def __cinit__(me, AssocTable t not None):
    me.t = t
    assoc_mkiter(&me.i, &me.t._t)
  cdef void *_next(me):
    return assoc_next(&me.i)

###----- That's all, folks --------------------------------------------------