@@@ cython and python 3 wip

[mLib-python] / str.pyx

### -*-pyrex-*-
###
### String utilities
###
### (c) 2006 Straylight/Edgeware
###

###----- Licensing notice ---------------------------------------------------
###
### This file is part of the Python interface to mLib.
###
### mLib/Python is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### mLib/Python is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with mLib/Python; if not, write to the Free Software Foundation,
### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

def word(object p, object quotep = False):
  """word(STR, [quotep = False]) -> WORD, REST"""
  cdef unsigned f = 0
  cdef char *op = xstrdup(TEXT_PTR(p))
  cdef char *pp = op
  cdef char *q
  cdef object w
  cdef object r

  if quotep:
    f |= STRF_QUOTE
  q = str_qword(&pp, f)
  if q is NULL:
    w = None
  else:
    w = <str>q
  if pp is NULL:
    r = ''
  else:
    r = <str>pp
  xfree(op)
  return w, r

def split(object p, int n = -1, quotep = False):
  """split(STR, [n = -1], [quotep = False]) -> WORDS, REST"""
  cdef unsigned f = 0
  cdef char *op = xstrdup(TEXT_PTR(p))
  cdef char *pp = op
  cdef char *q
  cdef object l = []
  cdef object r

  if quotep:
    f |= STRF_QUOTE
  while n != 0:
    q = str_qword(&pp, f)
    if q is NULL:
      break
    l.append(<str>q)
    if n > 0:
      n -= 1
  if pp is NULL:
    r = ''
  else:
    r = <str>pp
  xfree(op)
  return l, r

def match(object p, object s, prefixp = False):
  """match(PAT, STR, [prefixp = False]) -> BOOL"""
  cdef unsigned f = 0

  if prefixp:
    f |= STRF_PREFIX
  return str_matchx(TEXT_PTR(p), TEXT_PTR(s), f)

def sanitize(object s, int n = -1):
  """sanitize(STR, [n = -1]) -> STR"""
  cdef Py_ssize_t nn
  cdef const char *ss = _text_strlen(s, &nn)
  cdef char *buf
  cdef object d

  if n < 0:
    n = nn
  buf = <char *>xmalloc(n + 1)
  str_sanitize(buf, ss, n + 1)
  d = <str>buf
  xfree(buf)
  return d

def versioncmp(object va, object vb):
  """versioncmp(V0, V1) -> -1 | 0 | +1"""
  return _versioncmp(TEXT_PTR(va), TEXT_PTR(vb))

###----- That's all, folks --------------------------------------------------