;;; -*-lisp-*-
;;;
;;; Basic system-specific stuff
;;;
;;; (c) 2005 Mark Wooding
;;;

;;;----- Licensing notice ---------------------------------------------------
;;;
;;; This program is free software; you can redistribute it and/or modify
;;; it under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 2 of the License, or
;;; (at your option) any later version.
;;;
;;; This program is distributed in the hope that it will be useful,
;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with this program; if not, write to the Free Software Foundation,
;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

(defpackage #:runlisp
  (:use #:common-lisp)
  (:export #:*command-line* #:exit)
  #+clisp (:import-from #:ext #:exit))

(defpackage #:mdw.sys-base
  (:use #:common-lisp #:runlisp)
  (:export #:exit #:hard-exit #:*program-name* #:*command-line*
	   #:set-command-line-arguments)
  (:import-from #:runlisp #:*command-line* #:exit))
(in-package #:mdw.sys-base)

(defvar *command-line*)
(defvar *program-name*)

(defun set-command-line-arguments ()
  (setf *command-line*
	(let ((uiop-package (find-package :uiop))
	      (cll-package (find-package :cl-launch)))
	  (cons (or (and uiop-package
			 (funcall (intern "ARGV0" uiop-package)))
		    (and cll-package
			 (some (intern "GETENV" cll-package)
			       (list "__CL_ARGV0" "CL_LAUNCH_FILE")))
		    #+sbcl (car sb-ext:*posix-argv*)
		    #+cmu (car ext:*command-line-strings*)
		    #+clisp (aref (ext:argv) 0)
		    #+ecl (ext:argv 0)
		    "<unknown-script>")
		(cond (uiop-package
		       (funcall (intern "COMMAND-LINE-ARGUMENTS"
					uiop-package)))
		      (cll-package
		       (symbol-value (intern "*ARGUMENTS*" cll-package)))
		      (t #.(or (car '(#+sbcl (cdr sb-ext:*posix-argv*)
				      #+cmu (cdr ext:*command-line-strings*)
				      #+clisp (coerce (subseq (ext:argv) 8)
					       'list)
				      #+ecl (loop for i from 1
						  below (ext:argc)
						  collect (ext:argv i))))
			       (error "Unsupported Lisp."))))))

	*program-name* (pathname-name (car *command-line*))))

(set-command-line-arguments)

#-clisp
(unless (fboundp 'exit)
  (defun exit (&optional (code 0))
    "Polite way to end a program."
    #+(or cmu ecl) (ext:quit code)
    #+sbcl (sb-ext:exit :code code)
    #-(or cmu ecl sbcl)
    (progn
      (unless (zerop code)
	(format t "~&Exiting unsuccessfully with code ~D.~%" code))
      (abort))))

(defun hard-exit (&optional (code 0))
  "Stops the program immediately in its tracks.  Does nothing else.  Use
   after fork, for example, to avoid flushing buffers."
  (declare (type (unsigned-byte 32) code))
  #+cmu (unix::void-syscall ("_exit" c-call:int) code)
  #+sbcl (sb-ext:exit :code code :abort t)
  #+(or clisp ecl) (ext:quit code))

;;;----- That's all, folks --------------------------------------------------