dnl -*-fundamental-*-
dnl
dnl $Id: configure.in,v 1.2 2002/02/02 19:20:36 mdw Exp $
dnl
dnl Configuration script for jog
dnl
dnl (c) 2001 Mark Wooding
dnl

dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of Jog: Programming for a jogging machine.
dnl
dnl Jog is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl 
dnl Jog is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl 
dnl You should have received a copy of the GNU General Public License
dnl along with Jog; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

AC_INIT(rxglue.c)
AC_CANONICAL_TARGET
AM_INIT_AUTOMAKE(jog, 1.0.0)
AM_CONFIG_HEADER(config.h)

AC_PROG_CC
AC_PROG_CPP
mdw_GCC_FLAGS
mdw_OPT_TRACE

AC_CACHE_CHECK([where to find <rexxsaa.h>], [mdw_cv_rexxsaa_path], [
  bad=true
  tmp_CPPFLAGS=$CPPFLAGS
  for i in present /usr/include/regina /usr/local/include/regina; do
    case $i in
      present) ;;
      /*) CPPFLAGS="-I$i $tmp_CPPFLAGS" ;;
      *) AC_MSG_ERROR([Buggered!]) ;;
    esac
    ac_cpp='$CPP $CPPFLAGS'
    AC_TRY_CPP([#include <rexxsaa.h>], [bad=false; break;])
  done
  if $bad; then
    AC_MSG_ERROR([header file <rexxsaa.h> not found])
  fi
  CPPFLAGS=$tmp_CPPFLAGS
  mdw_cv_rexxsaa_path=$i
])
case $mdw_cv_rexxsaa_path in
  present) ;;
  /*) CPPFLAGS="-I$mdw_cv_rexxsaa_path $tmp_CPPFLAGS" ;;
  *) AC_MSG_ERROR([Buggered!]) ;;
esac

have_sdl=no
AM_PATH_SDL(1.1.0, have_sdl=yes)
AC_MSG_CHECKING([which audio subsystem to select])
AC_ARG_WITH([ausys],
[  --with-ausys=[VARIANT]  use VARIANT of the audio subsystem],
[AUSYS=$withval],
[case $host_os in
  cygwin*) AUSYS=win32 ;;
  *) AUSYS=sdl ;;
esac])
AC_SUBST(AUSYS)
AC_MSG_RESULT($AUSYS)
test -f $srcdir/ausys-$AUSYS.c ||
  AC_MSG_ERROR([no support for audio subsystem \`$AUSYS'])
case $AUSYS in
  sdl)
    if test $have_sdl = yes; then
      LIBS="$LIBS $SDL_LIBS"
      CFLAGS="$CFLAGS $SDL_CFLAGS"
    else
      AC_MSG_ERROR([SDL library not found, or too old])
    fi
    ;;
esac

mdw_DEFINE_PATHS([
  mdw_DEFINE_PATH([JOGSOCKET], [$localstatedir/$PACKAGE/socket],
                  [Pathname to default socket for socket transport.])
  audiodir='${datadir}/${PACKAGE}/audio' AC_SUBST(audiodir)
  mdw_DEFINE_PATH([AUDIODIR], [$audiodir], [Pathname to audio data.])
])

mdw_CHECK_MANYLIBS(crypt, crypt)
mdw_CHECK_MANYLIBS(dlopen, dl)
mdw_CHECK_MANYLIBS(RexxStart, regina rexx)
mdw_CHECK_MANYLIBS(pthread_create, pthread)
mdw_CHECK_MANYLIBS(socket, socket)
mdw_MLIB(2.0.0pre4)

mdw_TYPE_SSIZE_T

AC_OUTPUT(Makefile sounds/Makefile)

dnl ----- That's all, folks -------------------------------------------------