+proc tell_event {nl event} {
+ # For `act' we *haven't* yet done the 750ms delay; we implement
+ # that here. Also, here we turn `talk' into `talk' now and `act'
+ # later. We also support the psuedo-event `none'. The del msg
+ # and new msg events are handled by the command procedures, not here.
+ global calling_nick
+ if {[info exists calling_nick]} { set save $calling_nick }
+ switch -exact $event {
+ none { }
+ talk {
+ tell_event_core $nl talk
+ tell_event $nl act
+ }
+ act {
+ after 750 [list tell_event_core $nl $event]
+ }
+ ident - msgsarrive {
+ tell_event_core $nl $event
+ }
+ default {
+ error "tell_event $nl $event"
+ }
+ }
+ if {[info exists save]} { set calling_nick $save }
+}
+
+proc tell_getcstate {} {
+ # uses nl from caller's context
+ # imports telling (as the nick_telling) and u
+ # sets stt, telling_when
+ uplevel 1 {
+ upvar #0 nick_telling($nl) telling
+ upvar #0 nick_unique($nl) u
+
+ if {[info exists telling]} {
+ manyset $telling u_last stt telling_when
+ if {![info exists u] || "$u_last" != "$u"} {
+ unset telling; unset stt; unset telling_when
+ }
+ }
+
+ if {![info exists stt]} {
+ set stt norecord
+ set telling_when $now
+ }
+ }
+}
+
+proc tell_event_core {nl event} {
+ catch_logged { tell_event_core1 $nl $event }
+}
+
+proc tell_event_core1 {nl event} {
+ # event is `talk', `act', `ident' or `msgsarrive'
+ # When user talks we actually get talk now and act later
+ global calling_nick
+ set calling_nick $nl
+ set iml [msgsdb_get $nl inbound]
+ if {![llength $iml]} return
+
+ set now [clock seconds]
+ tell_getcstate
+ set ago [expr {$now - $telling_when}]
+
+ # Now we have the components of a telling state
+ # u - nick_unique (unset if not visible)
+ # stt - state: norecord, mentioned, passede
+ # ago - how long ago since we did anything
+
+ # We compute an evstate to dispatch on as follows:
+
+ # evstate is string of letters
+ # current state
+ # n NORECORD (MESSAGES)
+ # m MENTIONED
+ # p PASSED
+ # event
+ # t talk
+ # a act
+ # i ident
+ # m msgsarrive
+ # security level and timing
+ # ii Insecure
+ # ss Secure and soon (before interval)
+ # sl Secure and late (after interval)
+ # current identification
+ # i Identified
+ # u Unidentified
+ # reliability and timing
+ # uu Unreliable
+ # rv Remind, very soon (before within-interval)
+ # rs Remind, soon (between)
+ # rl Remind, late (after every-interval)
+ # ps Pester, soon (before interval)
+ # pl Pester, late (after interval)
+
+ set evstate {}
+
+ append evstate [string range $stt 0 0]
+ append evstate [string range $event 0 0]
+
+ manyset [nickdb_get_sec_effective $nl] sec secwhen
+ switch -exact $sec {
+ insecure { append evstate ii }
+ secure { append evstate [expr {$ago<$secwhen ? "sl" : "ss"}] }
+ default { append evstate "#$sec#" }
+ }
+
+ upvar #0 nick_username($nl) nu
+ if {[info exists nu] && "$nu" == "[nickdb_get_username $nl]"} {
+ append evstate i
+ } else {
+ append evstate u
+ }
+
+ manyset [nickdb_get $nl tellrel] rel relint relwithin
+ switch -exact $rel {
+ unreliable { append evstate uu }
+ remind { append evstate [expr {
+ $ago<$relwithin ? "rv" : $ago<$relint ? "rs" : "rl"
+ }]}
+ pester { append evstate [expr {$ago<$relint ? "ps" : "pl"}] }
+ default { append evstate "#$rel#" }
+ }
+
+ log "tell_event_core1 core evstate=$evstate (ago=$ago)"
+ switch -glob $evstate {
+ pt???rv {
+ # consider delivered:
+ # (very recently passed, and the user talks)
+ tell_delete_msgs {} $nl
+ return
+ }
+ pm????? {
+ # oops, messages passed are now out of date
+ catch_restoreei { unset telling }
+ return
+ }
+ ?m????? {
+ # ignore new msgs if we haven't passed yet
+ return
+ }
+ nt????? - mt????? -
+ pt???uu - pt???rs - pt???rl - pt???p? {
+ # ignore (any other `talk's) - act handles these
+ return
+ }
+ ni????? - naii??? - nas?i?? - mi????? - pa????l {
+ # pass and then stuff
+ if {[llength $iml] == 3} {
+ manyset $iml sender sentwhen msg
+ sendprivmsg $nl \
+ "$sender asked me [showinterval [expr {$now-$sentwhen}]]\
+ to tell you: $msg"
+ } else {
+ sendprivmsg $nl \
+ "Here are the [expr {[llength $iml]/3}] messages there are for you:"
+ while {[llength $iml] >= 3} {
+ manyset [lrange $iml 0 2] sender sentwhen msg
+ set iml [lrange $iml 3 end]
+ sendprivmsg $nl \
+ " [showintervalsecs [expr {$now-$sentwhen}] 1] <$sender> $msg"
+ }
+ }
+ if {"$rel" == "unreliable"} {
+ tell_delete_msgs {} $nl
+ return
+ }
+ set stt passed
+ }
+ nas?u?? {
+ sendprivmsg $nl {You have messages (so identify yourself please).}
+ set stt mentioned
+ }
+ masl??? {
+ sendprivmsg $nl {Don't forget about your messages.}
+ }
+ pi????? {
+ return
+ }
+ mass??? - pa????v - pa????s {
+ # too soon
+ return
+ }
+ * {
+ error "tell_event_core nl=$nl evstate=$evstate ?"
+ }
+ }
+ if {![info exists u]} {
+ catch_restoreei { unset telling }
+ } else {
+ set telling [list $u $stt $now]
+ }
+}
+