| 1 | # Actual IRC bot code |
| 2 | |
| 3 | set helpfile helpinfos |
| 4 | |
| 5 | source irccore.tcl |
| 6 | source parsecmd.tcl |
| 7 | source stdhelp.tcl |
| 8 | |
| 9 | proc privmsg_unlogged {prefix ischan params} { |
| 10 | if {!$ischan || |
| 11 | [regexp {^![a-z][-a-z]*[a-z]( .*)?$} [lindex $params 1]]} { |
| 12 | return 0 |
| 13 | } |
| 14 | # on-channel message, ignore |
| 15 | set chan [lindex $params 0] |
| 16 | upvar #0 chan_lastactivity([irctolower $chan]) la |
| 17 | set la [clock seconds] |
| 18 | catch { recordlastseen_p $prefix "talking on $chan" 1 } |
| 19 | return 1 |
| 20 | } |
| 21 | |
| 22 | proc showintervalsecs {howlong abbrev} { |
| 23 | return [showintervalsecs/[opt timeformat] $howlong $abbrev] |
| 24 | } |
| 25 | |
| 26 | proc showintervalsecs/ks {howlong abbrev} { |
| 27 | if {$howlong < 1000} { |
| 28 | return "${howlong}s" |
| 29 | } else { |
| 30 | if {$howlong < 1000000} { |
| 31 | set pfx k |
| 32 | set scale 1000 |
| 33 | } else { |
| 34 | set pfx M |
| 35 | set scale 1000000 |
| 36 | } |
| 37 | set value [expr "$howlong.0 / $scale"] |
| 38 | foreach {min format} {100 %.0f 10 %.1f 1 %.2f} { |
| 39 | if {$value < $min} continue |
| 40 | return [format "$format${pfx}s" $value] |
| 41 | } |
| 42 | } |
| 43 | } |
| 44 | |
| 45 | proc format_qty {qty unit abbrev} { |
| 46 | set o $qty |
| 47 | if {$abbrev} { |
| 48 | append o [string range $unit 0 0] |
| 49 | } else { |
| 50 | append o " " |
| 51 | append o $unit |
| 52 | if {$qty != 1} { append o s } |
| 53 | } |
| 54 | return $o |
| 55 | } |
| 56 | |
| 57 | proc showintervalsecs/hms {qty abbrev} { |
| 58 | set ul {second 60 minute 60 hour 24 day 7 week} |
| 59 | set remainv 0 |
| 60 | while {[llength $ul] > 1 && $qty >= [set uv [lindex $ul 1]]} { |
| 61 | set remainu [lindex $ul 0] |
| 62 | set remainv [expr {$qty % $uv}] |
| 63 | set qty [expr {($qty-$remainv)/$uv}] |
| 64 | set ul [lreplace $ul 0 1] |
| 65 | } |
| 66 | set o [format_qty $qty [lindex $ul 0] $abbrev] |
| 67 | if {$remainv} { |
| 68 | if {!$abbrev} { append o " " } |
| 69 | append o [format_qty $remainv $remainu $abbrev] |
| 70 | } |
| 71 | return $o |
| 72 | } |
| 73 | |
| 74 | proc showinterval {howlong} { |
| 75 | if {$howlong <= 0} { |
| 76 | return {just now} |
| 77 | } else { |
| 78 | return "[showintervalsecs $howlong 0] ago" |
| 79 | } |
| 80 | } |
| 81 | |
| 82 | proc showtime {when} { |
| 83 | return [showinterval [expr {[clock seconds] - $when}]] |
| 84 | } |
| 85 | |
| 86 | proc def_msgproc {name argl body} { |
| 87 | proc msg_$name "varbase $argl" "\ |
| 88 | upvar #0 msg/\$varbase/dest d\n\ |
| 89 | upvar #0 msg/\$varbase/str s\n\ |
| 90 | upvar #0 msg/\$varbase/accum a\n\ |
| 91 | $body" |
| 92 | } |
| 93 | |
| 94 | def_msgproc begin {dest str} { |
| 95 | set d $dest |
| 96 | set s $str |
| 97 | set a {} |
| 98 | } |
| 99 | |
| 100 | def_msgproc append {str} { |
| 101 | set ns "$s$str" |
| 102 | if {[string length $s] && [string length $ns] > 65} { |
| 103 | msg__sendout $varbase |
| 104 | set s " [string trimleft $str]" |
| 105 | } else { |
| 106 | set s $ns |
| 107 | } |
| 108 | } |
| 109 | |
| 110 | def_msgproc finish {} { |
| 111 | msg__sendout $varbase |
| 112 | unset s |
| 113 | unset d |
| 114 | return $a |
| 115 | } |
| 116 | |
| 117 | def_msgproc _sendout {} { |
| 118 | lappend a [string trimright $s] |
| 119 | set s {} |
| 120 | } |
| 121 | |
| 122 | proc looking_whenwhere {when where} { |
| 123 | set str [showtime [expr {$when-1}]] |
| 124 | if {[string length $where]} { append str " on $where" } |
| 125 | return $str |
| 126 | } |
| 127 | |
| 128 | proc recordlastseen_n {n how here} { |
| 129 | global lastseen lookedfor |
| 130 | set lastseen([irctolower $n]) [list $n [clock seconds] $how] |
| 131 | if {!$here} return |
| 132 | upvar #0 lookedfor([irctolower $n]) lf |
| 133 | if {[info exists lf]} { |
| 134 | switch -exact [llength $lf] { |
| 135 | 0 { |
| 136 | set ml {} |
| 137 | } |
| 138 | 1 { |
| 139 | manyset [lindex $lf 0] when who where |
| 140 | set ml [list \ |
| 141 | "FYI, $who was looking for you [looking_whenwhere $when $where]."] |
| 142 | } |
| 143 | default { |
| 144 | msg_begin tosend $n "FYI, people have been looking for you:" |
| 145 | set i 0 |
| 146 | set fin "" |
| 147 | foreach e $lf { |
| 148 | incr i |
| 149 | if {$i == 1} { |
| 150 | msg_append tosend " " |
| 151 | } elseif {$i == [llength $lf]} { |
| 152 | msg_append tosend " and " |
| 153 | set fin . |
| 154 | } else { |
| 155 | msg_append tosend ", " |
| 156 | } |
| 157 | manyset $e when who where |
| 158 | msg_append tosend \ |
| 159 | "$who ([looking_whenwhere $when $where])$fin" |
| 160 | } |
| 161 | set ml [msg_finish tosend] |
| 162 | } |
| 163 | } |
| 164 | unset lf |
| 165 | msendprivmsg_delayed 1000 $n $ml |
| 166 | } |
| 167 | } |
| 168 | |
| 169 | proc note_topic {showoff whoby topic} { |
| 170 | set msg "FYI, $whoby has changed the topic on $showoff" |
| 171 | if {[string length $topic] < 160} { |
| 172 | append msg " to $topic" |
| 173 | } else { |
| 174 | append msg " but it is too long to reproduce here !" |
| 175 | } |
| 176 | set showoff [irctolower $showoff] |
| 177 | set tell [chandb_get $showoff topictell] |
| 178 | if {[lsearch -exact $tell *] >= 0} { |
| 179 | set tryspies [chandb_list] |
| 180 | } else { |
| 181 | set tryspies $tell |
| 182 | } |
| 183 | foreach spy $tryspies { |
| 184 | set see [chandb_get $spy topicsee] |
| 185 | if {[lsearch -exact $see $showoff] >= 0 || \ |
| 186 | ([lsearch -exact $see *] >= 0 && \ |
| 187 | [lsearch -exact $tell $spy] >= 0)} { |
| 188 | sendprivmsg $spy $msg |
| 189 | } |
| 190 | } |
| 191 | } |
| 192 | |
| 193 | proc recordlastseen_p {p how here} { |
| 194 | prefix_nick |
| 195 | recordlastseen_n $n $how $here |
| 196 | } |
| 197 | |
| 198 | proc chanmode_arg {} { |
| 199 | upvar 2 args cm_args |
| 200 | set rv [lindex $cm_args 0] |
| 201 | set cm_args [lreplace cm_args 0 0] |
| 202 | return $rv |
| 203 | } |
| 204 | |
| 205 | proc chanmode_o1 {m g p chan} { |
| 206 | global nick chan_initialop |
| 207 | prefix_nick |
| 208 | set who [chanmode_arg] |
| 209 | recordlastseen_n $n "being nice to $who" 1 |
| 210 | if {"[irctolower $who]" == "[irctolower $nick]"} { |
| 211 | set nlower [irctolower $n] |
| 212 | upvar #0 nick_unique($nlower) u |
| 213 | if {[chandb_exists $chan]} { |
| 214 | sendprivmsg $n Thanks. |
| 215 | } elseif {![info exists u]} { |
| 216 | sendprivmsg $n {Op me while not on the channel, why don't you ?} |
| 217 | } else { |
| 218 | set chan_initialop([irctolower $chan]) $u |
| 219 | sendprivmsg $n \ |
| 220 | "Thanks. You can use `channel manager ...' to register this channel." |
| 221 | if {![nickdb_exists $n] || ![string length [nickdb_get $n username]]} { |
| 222 | sendprivmsg $n \ |
| 223 | "(But to do that you must register your nick securely first.)" |
| 224 | } |
| 225 | } |
| 226 | } |
| 227 | } |
| 228 | |
| 229 | proc chanmode_o0 {m g p chan} { |
| 230 | global nick chandeop |
| 231 | prefix_nick |
| 232 | set who [chanmode_arg] |
| 233 | recordlastseen_p $p "being mean to $who" 1 |
| 234 | if {"[irctolower $who]" == "[irctolower $nick]"} { |
| 235 | set chandeop($chan) [list [clock seconds] $p] |
| 236 | } |
| 237 | } |
| 238 | |
| 239 | proc msg_MODE {p c dest modelist args} { |
| 240 | if {![ischan $dest]} return |
| 241 | if {[regexp {^\-(.+)$} $modelist dummy modelist]} { |
| 242 | set give 0 |
| 243 | } elseif {[regexp {^\+(.+)$} $modelist dummy modelist]} { |
| 244 | set give 1 |
| 245 | } else { |
| 246 | error "invalid modelist" |
| 247 | } |
| 248 | foreach m [split $modelist] { |
| 249 | set procname chanmode_$m$give |
| 250 | if {[catch { info body $procname }]} { |
| 251 | recordlastseen_p $p "fiddling with $dest" 1 |
| 252 | } else { |
| 253 | $procname $m $give $p $dest |
| 254 | } |
| 255 | } |
| 256 | } |
| 257 | |
| 258 | proc leaving {lchan} { |
| 259 | foreach luser [array names nick_onchans] { |
| 260 | upvar #0 nick_onchans($luser) oc |
| 261 | set oc [grep tc {"$tc" != "$lchan"} $oc] |
| 262 | } |
| 263 | upvar #0 chan_nicks($lchan) nlist |
| 264 | unset nlist |
| 265 | upvar #0 chan_lastactivity($lchan) la |
| 266 | catch { unset la } |
| 267 | } |
| 268 | |
| 269 | proc doleave {lchan} { |
| 270 | sendout PART $lchan |
| 271 | leaving $lchan |
| 272 | } |
| 273 | |
| 274 | proc dojoin {lchan} { |
| 275 | global chan_nicks |
| 276 | sendout JOIN $lchan |
| 277 | set chan_nicks($lchan) {} |
| 278 | } |
| 279 | |
| 280 | proc check_justme {lchan} { |
| 281 | global nick |
| 282 | upvar #0 chan_nicks($lchan) nlist |
| 283 | if {[llength $nlist] != 1} return |
| 284 | if {"[lindex $nlist 0]" != "[irctolower $nick]"} return |
| 285 | if {[chandb_exists $lchan]} { |
| 286 | set mode [chandb_get $lchan mode] |
| 287 | if {"$mode" != "*"} { |
| 288 | sendout MODE $lchan $mode |
| 289 | } |
| 290 | set topic [chandb_get $lchan topicset] |
| 291 | if {[string length $topic]} { |
| 292 | sendout TOPIC $lchan $topic |
| 293 | } |
| 294 | } else { |
| 295 | doleave $lchan |
| 296 | } |
| 297 | } |
| 298 | |
| 299 | proc process_kickpart {chan user} { |
| 300 | global nick |
| 301 | check_nick $user |
| 302 | set luser [irctolower $user] |
| 303 | set lchan [irctolower $chan] |
| 304 | if {![ischan $chan]} { error "not a channel" } |
| 305 | if {"$luser" == "[irctolower $nick]"} { |
| 306 | leaving $lchan |
| 307 | } else { |
| 308 | upvar #0 nick_onchans($luser) oc |
| 309 | upvar #0 chan_nicks($lchan) nlist |
| 310 | set oc [grep tc {"$tc" != "$lchan"} $oc] |
| 311 | set nlist [grep tn {"$tn" != "$luser"} $nlist] |
| 312 | nick_case $user |
| 313 | if {![llength $oc]} { |
| 314 | nick_forget $luser |
| 315 | } else { |
| 316 | check_justme $lchan |
| 317 | } |
| 318 | } |
| 319 | } |
| 320 | |
| 321 | proc msg_TOPIC {p c dest topic} { |
| 322 | prefix_nick |
| 323 | if {![ischan $dest]} return |
| 324 | recordlastseen_n $n "changing the topic on $dest" 1 |
| 325 | note_topic [irctolower $dest] $n $topic |
| 326 | } |
| 327 | |
| 328 | proc msg_KICK {p c chans users comment} { |
| 329 | set chans [split $chans ,] |
| 330 | set users [split $users ,] |
| 331 | if {[llength $chans] > 1} { |
| 332 | foreach chan $chans user $users { process_kickpart $chan $user } |
| 333 | } else { |
| 334 | foreach user $users { process_kickpart [lindex $chans 0] $user } |
| 335 | } |
| 336 | } |
| 337 | |
| 338 | proc msg_KILL {p c user why} { |
| 339 | nick_forget $user |
| 340 | } |
| 341 | |
| 342 | set nick_counter 0 |
| 343 | set nick_arys {onchans username unique} |
| 344 | # nick_onchans($luser) -> [list ... $lchan ...] |
| 345 | # nick_username($luser) -> <securely known local username> |
| 346 | # nick_unique($luser) -> <counter> |
| 347 | # nick_case($luser) -> $user (valid even if no longer visible) |
| 348 | # nick_markid($luser) -> <after id for marktime> |
| 349 | |
| 350 | # chan_nicks($lchan) -> [list ... $luser ...] |
| 351 | # chan_lastactivity($lchan) -> [clock seconds] |
| 352 | |
| 353 | proc lnick_forget {luser} { |
| 354 | global nick_arys chan_nicks |
| 355 | lnick_marktime_cancel $luser |
| 356 | foreach ary $nick_arys { |
| 357 | upvar #0 nick_${ary}($luser) av |
| 358 | catch { unset av } |
| 359 | } |
| 360 | foreach lch [array names chan_nicks] { |
| 361 | upvar #0 chan_nicks($lch) nlist |
| 362 | set nlist [grep tn {"$tn" != "$luser"} $nlist] |
| 363 | check_justme $lch |
| 364 | } |
| 365 | } |
| 366 | |
| 367 | proc nick_forget {user} { |
| 368 | global nick_arys chan_nicks |
| 369 | lnick_forget [irctolower $user] |
| 370 | nick_case $user |
| 371 | } |
| 372 | |
| 373 | proc nick_case {user} { |
| 374 | global nick_case |
| 375 | set nick_case([irctolower $user]) $user |
| 376 | } |
| 377 | |
| 378 | proc msg_NICK {p c newnick} { |
| 379 | global nick_arys nick_case |
| 380 | prefix_nick |
| 381 | recordlastseen_n $n "changing nicks to $newnick" 0 |
| 382 | recordlastseen_n $newnick "changing nicks from $n" 1 |
| 383 | set luser [irctolower $n] |
| 384 | lnick_marktime_cancel $luser |
| 385 | set lusernew [irctolower $newnick] |
| 386 | foreach ary $nick_arys { |
| 387 | upvar #0 nick_${ary}($luser) old |
| 388 | upvar #0 nick_${ary}($lusernew) new |
| 389 | if {[info exists new]} { error "nick collision ?! $ary $n $newnick" } |
| 390 | if {[info exists old]} { set new $old; unset old } |
| 391 | } |
| 392 | upvar #0 nick_onchans($lusernew) oc |
| 393 | foreach ch $oc { |
| 394 | upvar #0 chan_nicks($ch) nlist |
| 395 | set nlist [grep tn {"$tn" != "$luser"} $nlist] |
| 396 | lappend nlist $lusernew |
| 397 | } |
| 398 | lnick_marktime_start $lusernew "Hi." 500 |
| 399 | nick_case $newnick |
| 400 | } |
| 401 | |
| 402 | proc nick_ishere {n} { |
| 403 | global nick_counter |
| 404 | upvar #0 nick_unique([irctolower $n]) u |
| 405 | if {![info exists u]} { set u [incr nick_counter].$n.[clock seconds] } |
| 406 | nick_case $n |
| 407 | } |
| 408 | |
| 409 | proc msg_JOIN {p c chan} { |
| 410 | prefix_nick |
| 411 | recordlastseen_n $n "joining $chan" 1 |
| 412 | set nl [irctolower $n] |
| 413 | set lchan [irctolower $chan] |
| 414 | upvar #0 nick_onchans($nl) oc |
| 415 | upvar #0 chan_nicks($lchan) nlist |
| 416 | if {![info exists oc]} { |
| 417 | global marktime_join_startdelay |
| 418 | lnick_marktime_start $nl "Welcome." $marktime_join_startdelay |
| 419 | } |
| 420 | lappend oc $lchan |
| 421 | lappend nlist $nl |
| 422 | nick_ishere $n |
| 423 | } |
| 424 | proc msg_PART {p c chan} { |
| 425 | prefix_nick |
| 426 | recordlastseen_n $n "leaving $chan" 1 |
| 427 | process_kickpart $chan $n |
| 428 | } |
| 429 | proc msg_QUIT {p c why} { |
| 430 | prefix_nick |
| 431 | recordlastseen_n $n "leaving ($why)" 0 |
| 432 | nick_forget $n |
| 433 | } |
| 434 | |
| 435 | proc msg_PRIVMSG {p c dest text} { |
| 436 | global errorCode |
| 437 | |
| 438 | prefix_nick |
| 439 | if {[ischan $dest]} { |
| 440 | recordlastseen_n $n "invoking me in $dest" 1 |
| 441 | set output $dest |
| 442 | } else { |
| 443 | recordlastseen_n $n "talking to me" 1 |
| 444 | set output $n |
| 445 | } |
| 446 | nick_case $n |
| 447 | |
| 448 | execute_usercommand $p $c $n $output $dest $text |
| 449 | } |
| 450 | |
| 451 | proc msg_INVITE {p c n chan} { |
| 452 | after 1000 [list dojoin [irctolower $chan]] |
| 453 | } |
| 454 | |
| 455 | proc grep {var predicate list} { |
| 456 | set o {} |
| 457 | upvar 1 $var v |
| 458 | foreach v $list { |
| 459 | if {[uplevel 1 [list expr $predicate]]} { lappend o $v } |
| 460 | } |
| 461 | return $o |
| 462 | } |
| 463 | |
| 464 | proc msg_353 {p c dest type chan nicklist} { |
| 465 | global names_chans nick_onchans |
| 466 | set lchan [irctolower $chan] |
| 467 | upvar #0 chan_nicks($lchan) nlist |
| 468 | lappend names_chans $lchan |
| 469 | if {![info exists nlist]} { |
| 470 | # We don't think we're on this channel, so ignore it ! |
| 471 | # Unfortunately, because we don't get a reply to PART, |
| 472 | # we have to remember ourselves whether we're on a channel, |
| 473 | # and ignore stuff if we're not, to avoid races. Feh. |
| 474 | return |
| 475 | } |
| 476 | set nlist_new {} |
| 477 | foreach user [split $nicklist { }] { |
| 478 | regsub {^[@+]} $user {} user |
| 479 | if {![string length $user]} continue |
| 480 | check_nick $user |
| 481 | set luser [irctolower $user] |
| 482 | upvar #0 nick_onchans($luser) oc |
| 483 | lappend oc $lchan |
| 484 | lappend nlist_new $luser |
| 485 | nick_ishere $user |
| 486 | } |
| 487 | set nlist $nlist_new |
| 488 | } |
| 489 | |
| 490 | proc msg_366 {p c args} { |
| 491 | global names_chans nick_onchans |
| 492 | set lchan [irctolower $c] |
| 493 | foreach luser [array names nick_onchans] { |
| 494 | upvar #0 nick_onchans($luser) oc |
| 495 | if {[llength names_chans] > 1} { |
| 496 | set oc [grep tc {[lsearch -exact $tc $names_chans] >= 0} $oc] |
| 497 | } |
| 498 | if {![llength $oc]} { lnick_forget $n } |
| 499 | } |
| 500 | unset names_chans |
| 501 | } |
| 502 | |
| 503 | proc check_username {target} { |
| 504 | if { |
| 505 | [string length $target] > 8 || |
| 506 | [regexp {[^-0-9a-z]} $target] || |
| 507 | ![regexp {^[a-z]} $target] |
| 508 | } { error "invalid username" } |
| 509 | } |
| 510 | |
| 511 | proc somedb__head {} { |
| 512 | uplevel 1 { |
| 513 | set idl [irctolower $id] |
| 514 | upvar #0 ${nickchan}db($idl) ndbe |
| 515 | binary scan $idl H* idh |
| 516 | set idfn $fprefix$idh |
| 517 | if {![info exists iddbe] && [file exists $idfn]} { |
| 518 | set f [open $idfn r] |
| 519 | try_except_finally { set newval [read $f] } {} { close $f } |
| 520 | if {[llength $newval] % 2} { error "invalid length" } |
| 521 | set iddbe $newval |
| 522 | } |
| 523 | } |
| 524 | } |
| 525 | |
| 526 | proc def_somedb {name arglist body} { |
| 527 | foreach {nickchan fprefix} {nick users/n chan chans/c} { |
| 528 | proc ${nickchan}db_$name $arglist \ |
| 529 | "set nickchan $nickchan; set fprefix $fprefix; $body" |
| 530 | } |
| 531 | } |
| 532 | |
| 533 | def_somedb list {} { |
| 534 | set list {} |
| 535 | foreach path [glob -nocomplain -path $fprefix *] { |
| 536 | binary scan $path "A[string length $fprefix]A*" afprefix thinghex |
| 537 | if {"$afprefix" != "$fprefix"} { error "wrong prefix $path $afprefix" } |
| 538 | lappend list [binary format H* $thinghex] |
| 539 | } |
| 540 | return $list |
| 541 | } |
| 542 | |
| 543 | proc def_somedb_id {name arglist body} { |
| 544 | def_somedb $name [concat id $arglist] "somedb__head; $body" |
| 545 | } |
| 546 | |
| 547 | def_somedb_id exists {} { |
| 548 | return [info exists iddbe] |
| 549 | } |
| 550 | |
| 551 | def_somedb_id delete {} { |
| 552 | catch { unset iddbe } |
| 553 | file delete $idfn |
| 554 | } |
| 555 | |
| 556 | set default_settings_nick {timeformat ks marktime off} |
| 557 | set default_settings_chan { |
| 558 | autojoin 1 |
| 559 | mode * |
| 560 | userinvite pub |
| 561 | topicset {} |
| 562 | topicsee {} |
| 563 | topictell {} |
| 564 | } |
| 565 | |
| 566 | def_somedb_id set {args} { |
| 567 | upvar #0 default_settings_$nickchan def |
| 568 | if {![info exists iddbe]} { set iddbe $def } |
| 569 | foreach {key value} [concat $iddbe $args] { set a($key) $value } |
| 570 | set newval {} |
| 571 | foreach {key value} [array get a] { lappend newval $key $value } |
| 572 | set f [open $idfn.new w] |
| 573 | try_except_finally { |
| 574 | puts $f $newval |
| 575 | close $f |
| 576 | file rename -force $idfn.new $idfn |
| 577 | } { |
| 578 | } { |
| 579 | catch { close $f } |
| 580 | } |
| 581 | set iddbe $newval |
| 582 | } |
| 583 | |
| 584 | def_somedb_id get {key} { |
| 585 | upvar #0 default_settings_$nickchan def |
| 586 | if {[info exists iddbe]} { |
| 587 | set l [concat $iddbe $def] |
| 588 | } else { |
| 589 | set l $def |
| 590 | } |
| 591 | foreach {tkey value} $l { |
| 592 | if {"$tkey" == "$key"} { return $value } |
| 593 | } |
| 594 | error "unset setting $key" |
| 595 | } |
| 596 | |
| 597 | proc opt {key} { |
| 598 | global calling_nick |
| 599 | if {[info exists calling_nick]} { set n $calling_nick } { set n {} } |
| 600 | return [nickdb_get $n $key] |
| 601 | } |
| 602 | |
| 603 | proc check_notonchan {} { |
| 604 | upvar 1 dest dest |
| 605 | if {[ischan $dest]} { usererror "That command must be sent privately." } |
| 606 | } |
| 607 | |
| 608 | proc nick_securitycheck {strict} { |
| 609 | upvar 1 n n |
| 610 | if {![nickdb_exists $n]} { |
| 611 | usererror "You are unknown to me, use `register'." |
| 612 | } |
| 613 | set wantu [nickdb_get $n username] |
| 614 | if {![string length $wantu]} { |
| 615 | if {$strict} { |
| 616 | usererror "That feature is only available to secure users, sorry." |
| 617 | } else { |
| 618 | return |
| 619 | } |
| 620 | } |
| 621 | set luser [irctolower $n] |
| 622 | upvar #0 nick_username($luser) nu |
| 623 | if {![info exists nu]} { |
| 624 | usererror "Nick $n is secure, you must identify yourself first." |
| 625 | } |
| 626 | if {"$wantu" != "$nu"} { |
| 627 | usererror "You are the wrong user -\ |
| 628 | the nick $n belongs to $wantu, not $nu." |
| 629 | } |
| 630 | } |
| 631 | |
| 632 | proc channel_ismanager {channel n} { |
| 633 | set mgrs [chandb_get $channel managers] |
| 634 | return [expr {[lsearch -exact [irctolower $mgrs] [irctolower $n]] >= 0}] |
| 635 | } |
| 636 | |
| 637 | proc channel_securitycheck {channel} { |
| 638 | upvar n n |
| 639 | if {![channel_ismanager $channel $n]} { |
| 640 | usererror "You are not a manager of $channel." |
| 641 | } |
| 642 | nick_securitycheck 1 |
| 643 | } |
| 644 | |
| 645 | proc def_chancmd {name body} { |
| 646 | proc channel/$name {} \ |
| 647 | " upvar 1 target chan; upvar 1 n n; upvar 1 text text; $body" |
| 648 | } |
| 649 | |
| 650 | proc ta_listop {findnow procvalue} { |
| 651 | # findnow and procvalue are code fragments which will be executed |
| 652 | # in the caller's level. findnow should set ta_listop_ev to |
| 653 | # the current list, and procvalue should treat ta_listop_ev as |
| 654 | # a proposed value in the list and check and possibly modify |
| 655 | # (canonicalise?) it. After ta_listop, ta_listop_ev will |
| 656 | # be the new value of the list. |
| 657 | upvar 1 ta_listop_ev exchg |
| 658 | upvar 1 text text |
| 659 | set opcode [ta_word] |
| 660 | switch -exact _$opcode { |
| 661 | _= { } |
| 662 | _+ - _- { |
| 663 | uplevel 1 $findnow |
| 664 | foreach item $exchg { set array($item) 1 } |
| 665 | } |
| 666 | default { |
| 667 | error "list change opcode must be one of + - =" |
| 668 | } |
| 669 | } |
| 670 | foreach exchg [split $text " "] { |
| 671 | if {![string length $exchg]} continue |
| 672 | uplevel 1 $procvalue |
| 673 | if {"$opcode" != "-"} { |
| 674 | set array($exchg) 1 |
| 675 | } else { |
| 676 | catch { unset array($exchg) } |
| 677 | } |
| 678 | } |
| 679 | set exchg [lsort [array names array]] |
| 680 | } |
| 681 | |
| 682 | def_chancmd manager { |
| 683 | ta_listop { |
| 684 | if {[chandb_exists $chan]} { |
| 685 | set ta_listop_ev [chandb_get $chan managers] |
| 686 | } else { |
| 687 | set ta_listop_ev [list [irctolower $n]] |
| 688 | } |
| 689 | } { |
| 690 | check_nick $ta_listop_ev |
| 691 | set ta_listop_ev [irctolower $ta_listop_ev] |
| 692 | } |
| 693 | if {[llength $ta_listop_ev]} { |
| 694 | chandb_set $chan managers $ta_listop_ev |
| 695 | ucmdr "Managers of $chan: $ta_listop_ev" {} |
| 696 | } else { |
| 697 | chandb_delete $chan |
| 698 | ucmdr {} {} "forgets about managing $chan." {} |
| 699 | } |
| 700 | } |
| 701 | |
| 702 | def_chancmd autojoin { |
| 703 | set yesno [ta_word] |
| 704 | switch -exact [string tolower $yesno] { |
| 705 | no { set nv 0 } |
| 706 | yes { set nv 1 } |
| 707 | default { error "channel autojoin must be `yes' or `no' } |
| 708 | } |
| 709 | chandb_set $chan autojoin $nv |
| 710 | ucmdr [expr {$nv ? "I will join $chan when I'm restarted " : \ |
| 711 | "I won't join $chan when I'm restarted "}] {} |
| 712 | } |
| 713 | |
| 714 | def_chancmd userinvite { |
| 715 | set nv [string tolower [ta_word]] |
| 716 | switch -exact $nv { |
| 717 | pub { set txt "!invite will work for $chan, but it won't work by /msg" } |
| 718 | here { set txt "!invite and /msg invite will work, but only for users who are already on $chan." } |
| 719 | all { set txt "Any user will be able to invite themselves or anyone else to $chan." } |
| 720 | none { set txt "I will not invite anyone to $chan." } |
| 721 | default { |
| 722 | error "channel userinvite must be `pub', `here', `all' or `none' |
| 723 | } |
| 724 | } |
| 725 | chandb_set $chan userinvite $nv |
| 726 | ucmdr $txt {} |
| 727 | } |
| 728 | |
| 729 | def_chancmd topic { |
| 730 | set what [ta_word] |
| 731 | switch -exact $what { |
| 732 | leave { |
| 733 | ta_nomore |
| 734 | chandb_set $chan topicset {} |
| 735 | ucmdr "I won't ever change the topic of $chan." {} |
| 736 | } |
| 737 | set { |
| 738 | set t [string trim $text] |
| 739 | if {![string length $t]} { |
| 740 | error "you must specific the topic to set" |
| 741 | } |
| 742 | chandb_set $chan topicset $t |
| 743 | ucmdr "Whenever I'm alone on $chan, I'll set the topic to $t." {} |
| 744 | } |
| 745 | see - tell { |
| 746 | ta_listop { |
| 747 | set ta_listop_ev [chandb_get $chan topic$what] |
| 748 | } { |
| 749 | if {"$ta_listop_ev" != "*"} { |
| 750 | if {![ischan $ta_listop_ev]} { |
| 751 | error "bad channel \`$ta_listop_ev' in topic $what" |
| 752 | } |
| 753 | set ta_listop_ev [irctolower $ta_listop_ev] |
| 754 | } |
| 755 | } |
| 756 | chandb_set $chan topic$what $ta_listop_ev |
| 757 | ucmdr "Topic $what list for $chan: $ta_listop_ev" {} |
| 758 | } |
| 759 | default { |
| 760 | usererror "Unknown channel topic subcommand - see help channel." |
| 761 | } |
| 762 | } |
| 763 | } |
| 764 | |
| 765 | def_chancmd mode { |
| 766 | set mode [ta_word] |
| 767 | if {"$mode" != "*" && ![regexp {^(([-+][imnpst]+)+)$} $mode mode]} { |
| 768 | error {channel mode must be * or match ([-+][imnpst]+)+} |
| 769 | } |
| 770 | chandb_set $chan mode $mode |
| 771 | if {"$mode" == "*"} { |
| 772 | ucmdr "I won't ever change the mode of $chan." {} |
| 773 | } else { |
| 774 | ucmdr "Whenever I'm alone on $chan, I'll set the mode to $mode." {} |
| 775 | } |
| 776 | } |
| 777 | |
| 778 | def_chancmd show { |
| 779 | if {[chandb_exists $chan]} { |
| 780 | set l "Settings for $chan: autojoin " |
| 781 | append l [lindex {no yes} [chandb_get $chan autojoin]] |
| 782 | append l ", mode " [chandb_get $chan mode] |
| 783 | append l ", userinvite " [chandb_get $chan userinvite] "." |
| 784 | append l "\nManagers: " |
| 785 | append l [join [chandb_get $chan managers] " "] |
| 786 | foreach {ts sep} {see "\n" tell " "} { |
| 787 | set t [chandb_get $chan topic$ts] |
| 788 | append l $sep |
| 789 | if {[llength $t]} { |
| 790 | append l "Topic $ts list: $t." |
| 791 | } else { |
| 792 | append l "Topic $ts list is empty." |
| 793 | } |
| 794 | } |
| 795 | append l "\n" |
| 796 | set t [chandb_get $chan topicset] |
| 797 | if {[string length $t]} { |
| 798 | append l "Topic to set: $t" |
| 799 | } else { |
| 800 | append l "I will not change the topic." |
| 801 | } |
| 802 | ucmdr {} $l |
| 803 | } else { |
| 804 | ucmdr {} "The channel $chan is not managed." |
| 805 | } |
| 806 | } |
| 807 | |
| 808 | proc channelmgr_monoop {} { |
| 809 | upvar 1 dest dest |
| 810 | upvar 1 text text |
| 811 | upvar 1 n n |
| 812 | upvar 1 p p |
| 813 | upvar 1 target target |
| 814 | global chan_nicks |
| 815 | |
| 816 | prefix_nick |
| 817 | |
| 818 | if {[ischan $dest]} { set target $dest } |
| 819 | if {[ta_anymore]} { set target [ta_word] } |
| 820 | ta_nomore |
| 821 | if {![info exists target]} { |
| 822 | usererror "You must specify, or invoke me on, the relevant channel." |
| 823 | } |
| 824 | if {![info exists chan_nicks([irctolower $target])]} { |
| 825 | usererror "I am not on $target." |
| 826 | } |
| 827 | if {![ischan $target]} { error "not a valid channel" } |
| 828 | |
| 829 | if {![chandb_exists $target]} { |
| 830 | usererror "$target is not a managed channel." |
| 831 | } |
| 832 | channel_securitycheck $target |
| 833 | } |
| 834 | |
| 835 | def_ucmd op { |
| 836 | channelmgr_monoop |
| 837 | sendout MODE $target +o $n |
| 838 | } |
| 839 | |
| 840 | def_ucmd leave { |
| 841 | channelmgr_monoop |
| 842 | doleave $target |
| 843 | } |
| 844 | |
| 845 | def_ucmd invite { |
| 846 | global chan_nicks errorCode errorInfo |
| 847 | prefix_nick |
| 848 | |
| 849 | if {[ischan $dest]} { |
| 850 | set target $dest |
| 851 | set onchan 1 |
| 852 | } else { |
| 853 | set target [ta_word] |
| 854 | set onchan 0 |
| 855 | } |
| 856 | set ltarget [irctolower $target] |
| 857 | if {![ischan $target]} { error "$target is not a channel" } |
| 858 | if {![info exists chan_nicks($ltarget)]} { |
| 859 | usererror "I am not on $target." |
| 860 | } |
| 861 | set ui [chandb_get $ltarget userinvite] |
| 862 | if {[catch { |
| 863 | if {"$ui" == "pub" && !$onchan} { |
| 864 | usererror "Invitations to $target must be made there with !invite." |
| 865 | } |
| 866 | if {"$ui" != "all"} { |
| 867 | if {[lsearch -exact $chan_nicks($ltarget) [irctolower $n]] < 0} { |
| 868 | usererror "Invitations to $target may only be made\ |
| 869 | by a user on the channel." |
| 870 | } |
| 871 | } |
| 872 | if {"$ui" == "none"} { |
| 873 | usererror "Sorry, I've not been authorised\ |
| 874 | to invite people to $target." |
| 875 | } |
| 876 | } emsg]} { |
| 877 | if {"$errorCode" == "BLIGHT USER" && [channel_ismanager $target $n]} { |
| 878 | if {[catch { |
| 879 | nick_securitycheck 1 |
| 880 | } emsg2]} { |
| 881 | if {"$errorCode" == "BLIGHT USER"} { |
| 882 | usererror "$emsg2 Therefore you can't use your\ |
| 883 | channel manager privilege. $emsg" |
| 884 | } else { |
| 885 | error $error $errorInfo $errorCode |
| 886 | } |
| 887 | } |
| 888 | } else { |
| 889 | error $emsg $errorInfo $errorCode |
| 890 | } |
| 891 | } |
| 892 | if {![ta_anymore]} { |
| 893 | usererror "You have to say who to invite." |
| 894 | } |
| 895 | set invitees {} |
| 896 | while {[ta_anymore]} { |
| 897 | set invitee [ta_word] |
| 898 | check_nick $invitee |
| 899 | lappend invitees $invitee |
| 900 | } |
| 901 | foreach invitee $invitees { |
| 902 | sendout INVITE $invitee $ltarget |
| 903 | } |
| 904 | set who [lindex $invitees 0] |
| 905 | switch -exact llength $invitees { |
| 906 | 0 { error "zero invitees" } |
| 907 | 1 { } |
| 908 | 2 { append who " and [lindex $invitees 1]" } |
| 909 | * { |
| 910 | set who [join [lreplace $invitees end end] ", "] |
| 911 | append who " and [lindex $invitees [llength $invitees]]" |
| 912 | } |
| 913 | } |
| 914 | ucmdr {} {} {} "invites $who to $target." |
| 915 | } |
| 916 | |
| 917 | def_ucmd channel { |
| 918 | if {[ischan $dest]} { set target $dest } |
| 919 | if {![ta_anymore]} { |
| 920 | set subcmd show |
| 921 | } else { |
| 922 | set subcmd [ta_word] |
| 923 | } |
| 924 | if {[ischan $subcmd]} { |
| 925 | set target $subcmd |
| 926 | if {![ta_anymore]} { |
| 927 | set subcmd show |
| 928 | } else { |
| 929 | set subcmd [ta_word] |
| 930 | } |
| 931 | } |
| 932 | if {![info exists target]} { error "privately, you must specify a channel" } |
| 933 | set procname channel/$subcmd |
| 934 | if {"$subcmd" != "show"} { |
| 935 | if {[catch { info body $procname }]} { |
| 936 | usererror "unknown channel setting $subcmd." |
| 937 | } |
| 938 | prefix_nick |
| 939 | if {[chandb_exists $target]} { |
| 940 | channel_securitycheck $target |
| 941 | } else { |
| 942 | nick_securitycheck 1 |
| 943 | upvar #0 chan_initialop([irctolower $target]) io |
| 944 | upvar #0 nick_unique([irctolower $n]) u |
| 945 | if {![info exists io]} { |
| 946 | usererror "$target is not a managed channel." |
| 947 | } |
| 948 | if {"$io" != "$u"} { |
| 949 | usererror "You are not the interim manager of $target." |
| 950 | } |
| 951 | if {"$subcmd" != "manager"} { |
| 952 | usererror "Please use `channel manager' first." |
| 953 | } |
| 954 | } |
| 955 | } |
| 956 | channel/$subcmd |
| 957 | } |
| 958 | |
| 959 | def_ucmd who { |
| 960 | if {[ta_anymore]} { |
| 961 | set target [ta_word]; ta_nomore |
| 962 | set myself 1 |
| 963 | } else { |
| 964 | prefix_nick |
| 965 | set target $n |
| 966 | set myself [expr {"$target" != "$n"}] |
| 967 | } |
| 968 | set ltarget [irctolower $target] |
| 969 | upvar #0 nick_case($ltarget) ctarget |
| 970 | set nshow $target |
| 971 | if {[info exists ctarget]} { |
| 972 | upvar #0 nick_onchans($ltarget) oc |
| 973 | upvar #0 nick_username($ltarget) nu |
| 974 | if {[info exists oc]} { set nshow $ctarget } |
| 975 | } |
| 976 | if {![nickdb_exists $ltarget]} { |
| 977 | set ol "$nshow is not a registered nick." |
| 978 | } elseif {[string length [set username [nickdb_get $target username]]]} { |
| 979 | set ol "The nick $nshow belongs to the user $username." |
| 980 | } else { |
| 981 | set ol "The nick $nshow is registered (but not to a username)." |
| 982 | } |
| 983 | if {![info exists ctarget] || ![info exists oc]} { |
| 984 | if {$myself} { |
| 985 | append ol "\nI can't see $nshow on anywhere." |
| 986 | } else { |
| 987 | append ol "\nYou aren't on any channels with me." |
| 988 | } |
| 989 | } elseif {![info exists nu]} { |
| 990 | append ol "\n$nshow has not identified themselves." |
| 991 | } elseif {![info exists username]} { |
| 992 | append ol "\n$nshow has identified themselves as the user $nu." |
| 993 | } elseif {"$nu" != "$username"} { |
| 994 | append ol "\nHowever, $nshow is being used by the user $nu." |
| 995 | } else { |
| 996 | append ol "\n$nshow has identified themselves to me." |
| 997 | } |
| 998 | ucmdr {} $ol |
| 999 | } |
| 1000 | |
| 1001 | def_ucmd register { |
| 1002 | prefix_nick |
| 1003 | check_notonchan |
| 1004 | set old [nickdb_exists $n] |
| 1005 | if {$old} { nick_securitycheck 0 } |
| 1006 | set luser [irctolower $n] |
| 1007 | switch -exact [string tolower [string trim $text]] { |
| 1008 | {} { |
| 1009 | upvar #0 nick_username($luser) nu |
| 1010 | if {![info exists nu]} { |
| 1011 | ucmdr {} \ |
| 1012 | "You must identify yourself before using `register'. See `help identify', or use `register insecure'." |
| 1013 | } |
| 1014 | nickdb_set $n username $nu |
| 1015 | ucmdr {} {} "makes a note of your username." {} |
| 1016 | } |
| 1017 | delete { |
| 1018 | nickdb_delete $n |
| 1019 | ucmdr {} {} "forgets your nickname." {} |
| 1020 | } |
| 1021 | insecure { |
| 1022 | nickdb_set $n username {} |
| 1023 | if {$old} { |
| 1024 | ucmdr {} "Security is now disabled for your nickname !" |
| 1025 | } else { |
| 1026 | ucmdr {} "This is fine, but bear in mind that people will be able to mess with your settings. Channel management features need a secure registration." "makes an insecure registration for your nick." |
| 1027 | } |
| 1028 | } |
| 1029 | } |
| 1030 | } |
| 1031 | |
| 1032 | proc timeformat_desc {tf} { |
| 1033 | switch -exact $tf { |
| 1034 | ks { return "Times will be displayed in seconds or kiloseconds." } |
| 1035 | hms { return "Times will be displayed in hours, minutes, etc." } |
| 1036 | default { error "invalid timeformat: $v" } |
| 1037 | } |
| 1038 | } |
| 1039 | |
| 1040 | proc def_setting {opt show_body set_body} { |
| 1041 | proc set_show/$opt {} " |
| 1042 | upvar 1 n n |
| 1043 | set opt $opt |
| 1044 | $show_body" |
| 1045 | if {![string length $set_body]} return |
| 1046 | proc set_set/$opt {} " |
| 1047 | upvar 1 n n |
| 1048 | upvar 1 text text |
| 1049 | set opt $opt |
| 1050 | $set_body" |
| 1051 | } |
| 1052 | |
| 1053 | def_setting timeformat { |
| 1054 | set tf [nickdb_get $n timeformat] |
| 1055 | return "$tf: [timeformat_desc $tf]" |
| 1056 | } { |
| 1057 | set tf [string tolower [ta_word]] |
| 1058 | ta_nomore |
| 1059 | set desc [timeformat_desc $tf] |
| 1060 | nickdb_set $n timeformat $tf |
| 1061 | ucmdr {} $desc |
| 1062 | } |
| 1063 | |
| 1064 | proc marktime_desc {mt} { |
| 1065 | if {"$mt" == "off"} { |
| 1066 | return "I will not send you periodic messages." |
| 1067 | } elseif {"$mt" == "once"} { |
| 1068 | return "I will send you one informational message when I see you." |
| 1069 | } else { |
| 1070 | return "I'll send you a message every [showintervalsecs $mt 0]." |
| 1071 | } |
| 1072 | } |
| 1073 | |
| 1074 | def_setting marktime { |
| 1075 | set mt [nickdb_get $n marktime] |
| 1076 | set p $mt |
| 1077 | if {[string match {[0-9]*} $mt]} { append p s } |
| 1078 | append p ": " |
| 1079 | append p [marktime_desc $mt] |
| 1080 | return $p |
| 1081 | } { |
| 1082 | global marktime_min |
| 1083 | set mt [string tolower [ta_word]] |
| 1084 | ta_nomore |
| 1085 | |
| 1086 | if {"$mt" == "off" || "$mt" == "once"} { |
| 1087 | } elseif {[regexp {^([0-9]+)([a-z]+)$} $mt dummy value unit]} { |
| 1088 | switch -exact $unit { |
| 1089 | s { set u 1 } |
| 1090 | ks { set u 1000 } |
| 1091 | m { set u 60 } |
| 1092 | h { set u 3600 } |
| 1093 | default { error "unknown unit of time $unit" } |
| 1094 | } |
| 1095 | if {$value > 86400*21/$u} { error "marktime interval too large" } |
| 1096 | set mt [expr {$value*$u}] |
| 1097 | if {$mt < $marktime_min} { error "marktime interval too small" } |
| 1098 | } else { |
| 1099 | error "invalid syntax for marktime" |
| 1100 | } |
| 1101 | nickdb_set $n marktime $mt |
| 1102 | lnick_marktime_start [irctolower $n] "So:" 500 |
| 1103 | ucmdr {} [marktime_desc $mt] |
| 1104 | } |
| 1105 | |
| 1106 | def_setting security { |
| 1107 | set s [nickdb_get $n username] |
| 1108 | if {[string length $s]} { |
| 1109 | return "Your nick, $n, is controlled by the user $s." |
| 1110 | } else { |
| 1111 | return "Your nick, $n, is not secure." |
| 1112 | } |
| 1113 | } {} |
| 1114 | |
| 1115 | def_ucmd set { |
| 1116 | prefix_nick |
| 1117 | check_notonchan |
| 1118 | if {![nickdb_exists $n]} { |
| 1119 | ucmdr {} "You are unknown to me and so have no settings. (Use `register'.)" |
| 1120 | } |
| 1121 | if {![ta_anymore]} { |
| 1122 | set ol {} |
| 1123 | foreach proc [lsort [info procs]] { |
| 1124 | if {![regexp {^set_show/(.*)$} $proc dummy opt]} continue |
| 1125 | lappend ol [format "%-10s %s" $opt [set_show/$opt]] |
| 1126 | } |
| 1127 | ucmdr {} [join $ol "\n"] |
| 1128 | } else { |
| 1129 | set opt [ta_word] |
| 1130 | if {[catch { info body set_show/$opt }]} { |
| 1131 | error "no setting $opt" |
| 1132 | } |
| 1133 | if {![ta_anymore]} { |
| 1134 | ucmdr {} "$opt [set_show/$opt]" |
| 1135 | } else { |
| 1136 | nick_securitycheck 0 |
| 1137 | if {[catch { info body set_set/$opt }]} { |
| 1138 | error "setting $opt cannot be set with `set'" |
| 1139 | } |
| 1140 | set_set/$opt |
| 1141 | } |
| 1142 | } |
| 1143 | } |
| 1144 | |
| 1145 | def_ucmd identpass { |
| 1146 | set username [ta_word] |
| 1147 | set passmd5 [md5sum "[ta_word]\n"] |
| 1148 | ta_nomore |
| 1149 | prefix_nick |
| 1150 | check_notonchan |
| 1151 | set luser [irctolower $n] |
| 1152 | upvar #0 nick_onchans($luser) onchans |
| 1153 | if {![info exists onchans] || ![llength $onchans]} { |
| 1154 | ucmdr "You must be on a channel with me to identify yourself." {} |
| 1155 | } |
| 1156 | check_username $username |
| 1157 | exec userv --timeout 3 $username << "$passmd5\n" > /dev/null \ |
| 1158 | irc-identpass $n |
| 1159 | upvar #0 nick_username($luser) rec_username |
| 1160 | set rec_username $username |
| 1161 | ucmdr "Pleased to see you, $username." {} |
| 1162 | } |
| 1163 | |
| 1164 | def_ucmd summon { |
| 1165 | set target [ta_word] |
| 1166 | ta_nomore |
| 1167 | check_username $target |
| 1168 | prefix_nick |
| 1169 | |
| 1170 | upvar #0 lastsummon($target) ls |
| 1171 | set now [clock seconds] |
| 1172 | if {[info exists ls]} { |
| 1173 | set interval [expr {$now - $ls}] |
| 1174 | if {$interval < 30} { |
| 1175 | ucmdr {} \ |
| 1176 | "Please be patient; $target was summoned only [showinterval $interval]." |
| 1177 | } |
| 1178 | } |
| 1179 | regsub {^[^!]*!} $p {} path |
| 1180 | if {[catch { |
| 1181 | exec userv --timeout 3 $target irc-summon $n $path \ |
| 1182 | [expr {[ischan $dest] ? "$dest" : ""}] \ |
| 1183 | < /dev/null |
| 1184 | } rv]} { |
| 1185 | regsub -all "\n" $rv { / } rv |
| 1186 | error $rv |
| 1187 | } |
| 1188 | if {[regexp {^problem (.*)} $rv dummy problem]} { |
| 1189 | ucmdr {} "The user `$target' $problem." |
| 1190 | } elseif {[regexp {^ok ([^ ]+) ([0-9]+)$} $rv dummy tty idlesince]} { |
| 1191 | set idletime [expr {$now - $idlesince}] |
| 1192 | set ls $now |
| 1193 | ucmdr {} {} {} "invites $target ($tty[expr { |
| 1194 | $idletime > 10 ? ", idle for [showintervalsecs $idletime 0]" : "" |
| 1195 | }]) to [expr { |
| 1196 | [ischan $dest] ? "join us here" : "talk to you" |
| 1197 | }]." |
| 1198 | } else { |
| 1199 | error "unexpected response from userv service: $rv" |
| 1200 | } |
| 1201 | } |
| 1202 | |
| 1203 | proc md5sum {value} { exec md5sum << $value } |
| 1204 | |
| 1205 | def_ucmd seen { |
| 1206 | global lastseen nick |
| 1207 | prefix_nick |
| 1208 | set ncase [ta_nick] |
| 1209 | set nlower [irctolower $ncase] |
| 1210 | ta_nomore |
| 1211 | set now [clock seconds] |
| 1212 | if {"$nlower" == "[irctolower $nick]"} { |
| 1213 | usererror "I am not self-aware." |
| 1214 | } elseif {![info exists lastseen($nlower)]} { |
| 1215 | set rstr "I've never seen $ncase." |
| 1216 | } else { |
| 1217 | manyset $lastseen($nlower) realnick time what |
| 1218 | set howlong [expr {$now - $time}] |
| 1219 | set string [showinterval $howlong] |
| 1220 | set rstr "I last saw $realnick $string, $what." |
| 1221 | } |
| 1222 | if {[ischan $dest]} { |
| 1223 | set where $dest |
| 1224 | } else { |
| 1225 | set where {} |
| 1226 | } |
| 1227 | upvar #0 lookedfor($nlower) lf |
| 1228 | if {[info exists lf]} { set oldvalue $lf } else { set oldvalue {} } |
| 1229 | set lf [list [list $now $n $where]] |
| 1230 | foreach v $oldvalue { |
| 1231 | if {"[irctolower [lindex $v 1]]" == "[irctolower $n]"} continue |
| 1232 | lappend lf $v |
| 1233 | } |
| 1234 | ucmdr {} $rstr |
| 1235 | } |
| 1236 | |
| 1237 | proc lnick_marktime_cancel {luser} { |
| 1238 | upvar #0 nick_markid($luser) mi |
| 1239 | if {![info exists mi]} return |
| 1240 | catch { after cancel $mi } |
| 1241 | catch { unset mi } |
| 1242 | } |
| 1243 | |
| 1244 | proc lnick_marktime_doafter {luser why ms} { |
| 1245 | lnick_marktime_cancel $luser |
| 1246 | upvar #0 nick_markid($luser) mi |
| 1247 | set mi [after $ms [list lnick_marktime_now $luser $why]] |
| 1248 | } |
| 1249 | |
| 1250 | proc lnick_marktime_reset {luser} { |
| 1251 | set mt [nickdb_get $luser marktime] |
| 1252 | if {"$mt" == "off" || "$mt" == "once"} return |
| 1253 | lnick_marktime_doafter $luser "Time passes." [expr {$mt*1000}] |
| 1254 | } |
| 1255 | |
| 1256 | proc lnick_marktime_start {luser why ms} { |
| 1257 | set mt [nickdb_get $luser marktime] |
| 1258 | if {"$mt" == "off"} { |
| 1259 | lnick_marktime_cancel $luser |
| 1260 | } else { |
| 1261 | lnick_marktime_doafter $luser $why $ms |
| 1262 | } |
| 1263 | } |
| 1264 | |
| 1265 | proc lnick_marktime_now {luser why} { |
| 1266 | upvar #0 nick_onchans($luser) oc |
| 1267 | global calling_nick |
| 1268 | set calling_nick $luser |
| 1269 | sendprivmsg $luser [lnick_pingstring $why $oc ""] |
| 1270 | lnick_marktime_reset $luser |
| 1271 | } |
| 1272 | |
| 1273 | proc lnick_pingstring {why oc apstring} { |
| 1274 | global nick_onchans |
| 1275 | catch { exec uptime } uptime |
| 1276 | set nnicks [llength [array names nick_onchans]] |
| 1277 | if {[regexp \ |
| 1278 | {^ *([0-9:apm]+) +up.*, +(\d+) users, +load average: +([0-9., ]+) *$} \ |
| 1279 | $uptime dummy time users load]} { |
| 1280 | regsub -all , $load {} load |
| 1281 | set uptime "$time $nnicks/$users $load" |
| 1282 | } else { |
| 1283 | append uptime ", $nnicks nicks" |
| 1284 | } |
| 1285 | if {[llength $oc]} { |
| 1286 | set best_la 0 |
| 1287 | set activity quiet |
| 1288 | foreach ch $oc { |
| 1289 | upvar #0 chan_lastactivity($ch) la |
| 1290 | if {![info exists la]} continue |
| 1291 | if {$la <= $best_la} continue |
| 1292 | set since [showintervalsecs [expr {[clock seconds]-$la}] 1] |
| 1293 | set activity "$ch $since" |
| 1294 | set best_la $la |
| 1295 | } |
| 1296 | } else { |
| 1297 | set activity unseen |
| 1298 | } |
| 1299 | set str $why |
| 1300 | append str " " $uptime " " $activity |
| 1301 | if {[string length $apstring]} { append str " " $apstring } |
| 1302 | return $str |
| 1303 | } |
| 1304 | |
| 1305 | def_ucmd ping { |
| 1306 | if {[ischan $dest]} { |
| 1307 | set oc [irctolower $dest] |
| 1308 | } else { |
| 1309 | global nick_onchans |
| 1310 | prefix_nick |
| 1311 | set ln [irctolower $n] |
| 1312 | if {[info exists nick_onchans($ln)]} { |
| 1313 | set oc $nick_onchans($ln) |
| 1314 | } else { |
| 1315 | set oc {} |
| 1316 | } |
| 1317 | if {[llength $oc]} { lnick_marktime_reset $ln } |
| 1318 | } |
| 1319 | ucmdr {} [lnick_pingstring "Pong!" $oc $text] |
| 1320 | } |
| 1321 | |
| 1322 | proc ensure_globalsecret {} { |
| 1323 | global globalsecret |
| 1324 | |
| 1325 | if {[info exists globalsecret]} return |
| 1326 | set gsfile [open /dev/urandom r] |
| 1327 | fconfigure $gsfile -translation binary |
| 1328 | set globalsecret [read $gsfile 32] |
| 1329 | binary scan $globalsecret H* globalsecret |
| 1330 | close $gsfile |
| 1331 | unset gsfile |
| 1332 | } |
| 1333 | |
| 1334 | proc connected {} { |
| 1335 | foreach chan [chandb_list] { |
| 1336 | if {[chandb_get $chan autojoin]} { dojoin $chan } |
| 1337 | } |
| 1338 | } |
| 1339 | |
| 1340 | ensure_globalsecret |
| 1341 | loadhelp |
| 1342 | ensure_connecting |