m4_divert(-1) ### -*-m4-*-
### SSH client configuration for root.
###
### This file is maintained on ibanez: edit it there and run `update-slaves'.

### Diversion map.
###
###   10	Host nicknames.
###   20	Special-purpose services.
###   90	Default settings.

###--------------------------------------------------------------------------
### M4 machinery.

m4_changequote([, ])
m4_define([_nl], [
])

m4_define([_FOREACH], [m4_dnl
m4_ifelse([$#], [1], [_foreach_func($1)],
	[_foreach_func($1)[]_FOREACH(m4_shift($@))])])
m4_define([FOREACH], [m4_dnl
m4_pushdef([_foreach_func], [$1])m4_dnl
_FOREACH($2)[]m4_dnl
m4_popdef([_foreach_func])])

## Configuration variables.
m4_define([DOMAIN], [distorted.org.uk])
m4_define([BACKUP], [ibanez.distorted.org.uk])

## Define a host entry.
m4_define([_SETHOST], [m4_define([_host], [$1])])
m4_define([_DEFHOST], [m4_dnl
m4_pushdef([_host])m4_dnl
_SETHOST($1)m4_dnl
m4_pushdef([_fqdn], m4_ifelse([$5], [], [_host[]$3.DOMAIN], [$5]))m4_dnl
Host[]m4_dnl
FOREACH([ $][1[]$3 $][1[]$3.DOMAIN], [$1])m4_dnl
FOREACH([ $][1[]$4], [$2])
	HostName _fqdn
m4_popdef([_fqdn])m4_dnl
m4_popdef([_sethost])m4_dnl
m4_popdef([_host])])
m4_define([DEFHOST], [m4_dnl
_DEFHOST([$1], [$2], [], [], [$4])m4_dnl
m4_ifelse([$3], [], [],
[FOREACH([_DEFHOST([$1], [$2], [.]$][1, [SHORT_]$][1, [$4])], [$3])])])])

## Local configuration.
m4_define([HOST], m4_esyscmd([printf %s $(hostname -s)]))

###--------------------------------------------------------------------------
### Do-not-edit banners.

m4_divert(0)m4_dnl
### -*-conf-*-  GENERATED FROM config.m4: DO NOT EDIT!
###
### SSH client configuration for root.

m4_divert(100)m4_dnl
### GENERATED FROM config.m4: NO NOT EDIT!
m4_divert(-1)

###--------------------------------------------------------------------------
### Include any local overrides.

m4_sinclude([/root/.ssh/config.local.m4])m4_divert(-1)

###--------------------------------------------------------------------------
### Subnet nicknames.

m4_define([SHORT_dmz],		[d])
m4_define([SHORT_unsafe],	[u])
m4_define([SHORT_safe],		[s])
m4_define([SHORT_untrusted],	[x])

m4_define([SHORT_jump],		[j])
m4_define([SHORT_colo],		[c])

m4_divert(10)m4_dnl
###--------------------------------------------------------------------------
### Host-specific settings (mostly nicknames).

## Internal hosts.
DEFHOST([ibanez],		[i],	[dmz, unsafe])
DEFHOST([radius],		[r],	[dmz, unsafe, safe, untrusted])
DEFHOST([roadstar],		[rg],	[dmz, unsafe])
DEFHOST([jem],			[j],	[dmz, unsafe])
DEFHOST([artist],		[a],	[dmz, unsafe, untrusted])
DEFHOST([fender],		[f],	[jump, colo])
DEFHOST([precision],		[p],	[jump, colo])
DEFHOST([telecaster, tele],	[t],	[jump, colo])
DEFHOST([stratocaster, strat],	[s],	[jump, colo])
DEFHOST([jazz],			[z],	[jump, colo])
DEFHOST([jaguar],		[jag],	[jump])
DEFHOST([vampire],		[v],	[dmz, unsafe, safe, untrusted])
DEFHOST([orange],		[o])
DEFHOST([gibson],		[g])
DEFHOST([crybaby],		[cb])
DEFHOST([terror])
DEFHOST([groove],		[gr])
DEFHOST([haze],			[h])
DEFHOST([marauder],		[m])
DEFHOST([invader, inv])
DEFHOST([evolution, evo])
DEFHOST([grigsby, tp0])
DEFHOST([carling, tp1])
DEFHOST([tritan, tp2])

## Satellite hosts.
m4_define([DOMAIN], [binswood.org.uk])m4_dnl
DEFHOST([mango])
DEFHOST([binswrt],		[bw])

## Linode Lish gateways.
m4_define([DOMAIN], [linode.com])m4_dnl
m4_define([LISH], [DEFHOST([lish-$1])
	User distorted])m4_dnl
LISH([tokyo])
LISH([fremont])
LISH([newark])
LISH([dallas])
LISH([atlanta])
LISH([london])
LISH([singapore])

###--------------------------------------------------------------------------
### Specific services.

Host backup-server
	HostName BACKUP
	User bkp-HOST

m4_divert(90)m4_dnl
###--------------------------------------------------------------------------
### Default settings.

Host *
	User root
	Cipher blowfish
	Ciphers aes128-ctr,blowfish-cbc,3des-cbc
	Macs hmac-ripemd160,hmac-sha1,umac-64@openssh.com
	KeepAlive no
	ForwardAgent no
	ForwardX11 no
	Compression no
	ControlMaster auto
	ControlPath ~/.ssh/sock-%l/control-%r@%h:%p
	##ControlPersist 5m
	AddressFamily inet
	ServerAliveInterval 300
	CheckHostIP no
	HashKnownHosts no

###------ That's all, folks --------------------------------------------------