X-Git-Url: https://git.distorted.org.uk/~mdw/catacomb/blobdiff_plain/f12328720976ccd09afe73420ff07e6c72478b4c..e492db887af6561dd33aa18e3887efaeb219fd16:/base/asm-common.h

diff --git a/base/asm-common.h b/base/asm-common.h
index f4c4f6e3..d81e4098 100644
--- a/base/asm-common.h
+++ b/base/asm-common.h
@@ -1031,6 +1031,125 @@ name:
 #endif
 
 ///--------------------------------------------------------------------------
+/// AArch64-specific hacking.
+
+#if CPUFAM_ARM64
+
+// Set the function hooks.
+#define FUNC_PREHOOK(_) .balign 4
+#define FUNC_POSTHOOK(_) .cfi_startproc; .L$_prologue_p = -1
+#define ENDFUNC_HOOK(_) .cfi_endproc
+
+// Call external subroutine at ADDR, possibly via PLT.
+.macro	callext addr
+	bl	\addr
+.endm
+
+// Load address of external symbol ADDR into REG.
+.macro	leaext	reg, addr
+#if WANT_PIC
+	adrp	\reg, :got:\addr
+	ldr	\reg, [\reg, #:got_lo12:\addr]
+#else
+	adrp	\reg, \addr
+	add	\reg, \reg, #:lo12:\addr
+#endif
+.endm
+
+// Stack management and unwinding.
+.macro	setfp	fp, offset = 0
+  // If you're just going through the motions with a fixed-size stack frame,
+  // then you want to say `add x29, sp, #OFFSET' directly, which will avoid
+  // pointlessly restoring sp later.
+  .if \offset == 0
+	mov	\fp, sp
+	  .cfi_def_cfa_register \fp
+  .else
+	add	\fp, sp, #\offset
+	  .cfi_def_cfa_register \fp
+	  .cfi_adjust_cfa_offset -\offset
+  .endif
+	.macro dropfp; _dropfp	\fp, \offset; .endm
+	.L$_frameptr_p = -1
+.endm
+
+.macro	_dropfp	fp, offset = 0
+  .if \offset == 0
+	mov	sp, \fp
+	  .cfi_def_cfa_register sp
+  .else
+	sub	sp, \fp, #\offset
+	  .cfi_def_cfa_register sp
+	  .cfi_adjust_cfa_offset +\offset
+  .endif
+	.purgem	dropfp
+	.L$_frameptr_p = 0
+.endm
+
+.macro	stalloc	n
+	sub	sp, sp, #\n
+	  .cfi_adjust_cfa_offset +\n
+.endm
+
+.macro	stfree	n
+	add	sp, sp, #\n
+	  .cfi_adjust_cfa_offset -\n
+.endm
+
+.macro	pushreg	x, y=
+  .ifeqs "\y", ""
+	str	\x, [sp, #-16]!
+	  .cfi_adjust_cfa_offset +16
+	  .cfi_rel_offset \x, 0
+  .else
+	stp	\x, \y, [sp, #-16]!
+	  .cfi_adjust_cfa_offset +16
+	  .cfi_rel_offset \x, 0
+	  .cfi_rel_offset \y, 8
+  .endif
+.endm
+
+.macro	popreg	x, y=
+  .ifeqs "\y", ""
+	ldr	\x, [sp], #16
+	  .cfi_restore \x
+	  .cfi_adjust_cfa_offset -16
+  .else
+	ldp	\x, \y, [sp], #16
+	  .cfi_restore \x
+	  .cfi_restore \y
+	  .cfi_adjust_cfa_offset -16
+  .endif
+.endm
+
+.macro	savereg	x, y, z=
+  .ifeqs "\z", ""
+	str	\x, [sp, #\y]
+	  .cfi_rel_offset \x, \y
+  .else
+	stp	\x, \y, [sp, #\z]
+	  .cfi_rel_offset \x, \z
+	  .cfi_rel_offset \y, \z + 8
+  .endif
+.endm
+
+.macro	rstrreg	x, y, z=
+  .ifeqs "\z", ""
+	ldr	\x, [sp, #\y]
+	  .cfi_restore \x
+  .else
+	ldp	\x, \y, [sp, #\z]
+	  .cfi_restore \x
+	  .cfi_restore \y
+  .endif
+.endm
+
+.macro	endprologue
+.endm
+
+#endif
+
+///--------------------------------------------------------------------------
 /// Final stuff.
 
 // Default values for the various hooks.