+dnl Consider enabling support for assembler-level debugging toys.
+AC_ARG_ENABLE([asm-debug],
+ AS_HELP_STRING([--enable-asm-debug],
+ [enable assembler debugging features]),
+ [mdw_asm_debug=$enableval], [mdw_asm_debug=no])
+case $CPUFAM in nil) mdw_asm_debug=no ;; esac
+case $mdw_asm_debug in
+ no) ;;
+ *) AC_DEFINE([ENABLE_ASM_DEBUG], [1],
+ [Define to enable assembler-level debugging.]) ;;
+esac
+AM_CONDITIONAL([ASM_DEBUG], [test x$mdw_asm_debug != xno])
+
+dnl Check for leading underscores on C symbols.
+LT_SYS_SYMBOL_USCORE
+case $sys_symbol_underscore in
+ yes) AC_DEFINE([SYM_USCORE], [1],
+ [Define if C symbols are prefixed with an underscore.]) ;;
+esac
+
+dnl--------------------------------------------------------------------------
+dnl CPU-specific assembler features.
+
+AC_LANG([CPPAS])
+
+case $CPUFAM in
+ armel)
+ AC_CACHE_CHECK(
+ [whether the assembler understands ARMv8 crypto extensions],
+ [mdw_cv_as_armv8_crypto],
+ [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ .arch armv8-a
+ .fpu crypto-neon-fp-armv8
+
+ .text
+ .globl foo
+foo:
+ vldmia r0, {d0-d3}
+ aese.8 q0, q1
+ aesmc.8 q0, q0
+ vstmia r0, {d0, d1}
+ bx r14]])],
+ [mdw_cv_as_armv8_crypto=yes],
+ [mdw_cv_as_armv8_crypto=no])])
+ ;;
+esac
+
+: ${mdw_cv_as_armv8_crypto=no}
+AM_CONDITIONAL([HAVE_AS_ARMV8_CRYPTO], [test $mdw_cv_as_armv8_crypto = yes])
+if test $mdw_cv_as_armv8_crypto = yes; then
+ AC_DEFINE([HAVE_AS_ARMV8_CRYPTO], [1],
+ [Define to 1 if your ARM assembler supports the ARMv8 crypto instructions.])
+fi
+