+dnl Define language support for assembler.
+dnl
+dnl This is stolen from https://gitlab.crest.iu.edu/jsfiroz/hpx/commit/
+dnl 84be4345db6eec3797a57b8e53483cb43f4733bf
+
+AC_LANG_DEFINE([CPPAS], [cppas], [CPPAS], [CCAS], [C],
+ [ac_ext=S ac_cpp='$CPP $CPPFLAGS'
+ ac_compile='$CCAS -c $CCASFLAGS $CPPFLAGS dnl
+ conftest.$ac_ext >&AS_MESSAGE_LOG_FD'
+ ac_link='$CCAS -oconftest$ac_exeext $CCASFLAGS $CPPFLAGS $LDFLAGS dnl
+ conftest.$ac_ext $LIBS >&AS_MESSAGE_LOG_FD'])
+
+AC_DEFUN([AC_LANG_PREPROC(CPPAS)], [AC_REQUIRE([AC_PROG_CPP])])
+AC_DEFUN([AC_LANG_COMPILER(CPPAS)], [AC_REQUIRE([AM_PROG_AS])])
+AC_DEFUN([AC_LANG_CONFTEST(CPPAS)],
+ [cat confdefs.h - <<_ACEOF >conftest.$ac_ext
+/* end confdefs.h. */
+$1
+_ACEOF])
+
+dnl--------------------------------------------------------------------------
+dnl Host-specific configuration.
+
+dnl The table of CPU families and ABIs which we might support. Support is
+dnl not uniform: each dispatched function might or might not have an
+dnl implementation for any particular CPU/ABI combination.
+AC_DEFUN([catacomb_CPU_FAMILIES],
+ [$1([i[[3-6]]86,cygwin], [x86], [win])
+ $1([i[[3-6]]86,*], [x86], [sysv])
+ $1([x86_64,cygwin], [amd64], [win])
+ $1([x86_64,*], [amd64], [sysv])
+ $1([arm,* | armv*,*], [armel], [std])
+ $1([aarch64,*], [arm64], [std])])
+
+dnl A utility to clear the `seen' flags, used so as to process each CPU or
+dnl ABI once.
+m4_define([catacomb_CLEAR_FLAGS],
+[m4_ifdef([catacomb_seen_cpu/$2],
+ [m4_undefine([catacomb_seen_cpu/$2])])dnl
+m4_ifdef([catacomb_seen_abi/$3],
+ [m4_undefine([catacomb_seen_abi/$3])])])
+
+dnl Identify the current host.
+case $host_cpu,$host_os in
+ m4_define([catacomb_CPU_CASE],
+ [$1) CPUFAM=$2 ABI=$3 ;;
+])
+ catacomb_CPU_FAMILIES([catacomb_CPU_CASE])
+ *) CPUFAM=nil ABI=nil ;;
+esac
+
+dnl Now check the assembler. We have target-specific requirements here, so
+dnl we couldn't do this any earlier.
+AC_CACHE_CHECK(
+ [whether the assembler is likely to work], [mdw_cv_gnuish_as],
+ [AC_LANG_PUSH([CPPAS])
+ AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ .text
+ .L\$_test = 23
+.macro mymac
+ .L\$_test = .L\$_test + 1
+.endm
+ .globl foo
+ .extern bar
+ mymac]])],
+ [mdw_cv_gnuish_as=yes], [mdw_cv_gnuish_as=no])
+ case $CPUFAM in
+ x86 | amd64)
+ AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ .text
+ .arch pentium4
+ .intel_syntax noprefix
+ .globl foo
+foo:
+ adcd var, 0
+ ret
+ .data
+var: .long 1
+ ]])],
+ [:], [mdw_cv_gnuish_as=no])
+ ;;
+ esac
+ AC_LANG_POP([CPPAS])])
+AM_CONDITIONAL([GNUISH_AS], [test $mdw_cv_gnuish_as = yes])
+if test $mdw_cv_gnuish_as = no; then CPUFAM=nil ABI=nil; fi
+
+dnl A hairy macro used to set the `CPUFAM_...' and `ABI_...' variables. We
+dnl basically need to do the same thing for the family and ABI, so it's worth
+dnl some effort to hide the ugliness.
+m4_define([catacomb_DEFINE_CPU_OR_ABI],
+[case $$1 in
+ m4_define([_def],
+ [m4_ifdef([catacomb_seen_$3/$$2], [],
+ [$$2)
+ AC_DEFINE([$4]m4_translit([$$2], [a-z], [A-Z]), [1], [$5])
+ ;;m4_define([catacomb_seen_$3/$$2], [t])])])
+ catacomb_CPU_FAMILIES([_def])
+ nil) ;;
+ *) AC_MSG_ERROR([BUG: unexpected $1 \`$1']) ;;
+esac])
+
+dnl Now that's out the way, we can explain what we're doing.
+AC_MSG_CHECKING([CPU family and ABI])
+
+dnl Figure out the target CPU family and ABI.
+catacomb_CPU_FAMILIES([catacomb_CLEAR_FLAGS])
+catacomb_DEFINE_CPU_OR_ABI([CPUFAM], [2], [cpu],
+ [CPUFAM_], [Define if target CPU is \`$][2\'.])
+catacomb_DEFINE_CPU_OR_ABI([ABI], [3], [abi],
+ [ABI_], [Define if target ABI is \`$][3\'.])
+
+dnl Establish Automake conditions for things.
+catacomb_CPU_FAMILIES([catacomb_CLEAR_FLAGS])
+m4_define([catacomb_COND_CPU],
+[m4_define([_CPU], m4_translit([$2], [a-z], [A-Z]))
+m4_define([_ABI], m4_translit([$3], [a-z], [A-Z]))
+AM_CONDITIONAL([CPUABI_]_CPU[_]_ABI, [test x$CPUFAM/$ABI = x$2/$3])
+m4_ifdef([catacomb_seen_cpu/$2], [],
+[AM_CONDITIONAL([CPUFAM_]_CPU, [test x$CPUFAM = x$2])dnl
+m4_define([catacomb_seen_cpu/$2], [t])])
+m4_ifdef([catacomb_seen_abi/$3], [],
+[AM_CONDITIONAL([ABI_]_ABI, [test x$ABI = x$3])dnl
+m4_define([catacomb_seen_abi/$3], [t])])])
+catacomb_CPU_FAMILIES([catacomb_COND_CPU])
+AM_CONDITIONAL([KNOWN_CPUFAM], [test x$CPUFAM != xnil])
+
+dnl Report on what we found.
+case $CPUFAM in
+ nil) AC_MSG_RESULT([not supported]) ;;
+ *) AC_MSG_RESULT([$CPUFAM/$ABI]) ;;
+esac
+
+dnl--------------------------------------------------------------------------
+dnl CPU-specific assembler features.
+
+AC_LANG([CPPAS])
+
+case $CPUFAM in
+ armel)
+ AC_CACHE_CHECK(
+ [whether the assembler understands ARMv8 crypto extensions],
+ [mdw_cv_as_armv8_crypto],
+ [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ .arch armv8-a
+ .fpu crypto-neon-fp-armv8
+
+ .text
+ .globl foo
+foo:
+ vldmia r0, {d0-d3}
+ aese.8 q0, q1
+ aesmc.8 q0, q0
+ vstmia r0, {d0, d1}
+ bx r14]])],
+ [mdw_cv_as_armv8_crypto=yes],
+ [mdw_cv_as_armv8_crypto=no])])
+ ;;
+esac
+
+: ${mdw_cv_as_armv8_crypto=no}
+AM_CONDITIONAL([HAVE_AS_ARMV8_CRYPTO], [test $mdw_cv_as_armv8_crypto = yes])
+if test $mdw_cv_as_armv8_crypto = yes; then
+ AC_DEFINE([HAVE_AS_ARMV8_CRYPTO], [1],
+ [Define to 1 if your ARM assembler supports the ARMv8 crypto instructions.])
+fi
+
+dnl--------------------------------------------------------------------------