| 1 | ## -*-makefile-*- |
| 2 | ## |
| 3 | ## $Id: Makefile.m4,v 1.11 1999/11/20 22:24:53 mdw Exp $ |
| 4 | ## |
| 5 | ## Makefile for Catacomb |
| 6 | ## |
| 7 | ## (c) 1999 Straylight/Edgeware |
| 8 | ## |
| 9 | |
| 10 | ##----- Licensing notice ---------------------------------------------------- |
| 11 | ## |
| 12 | ## This file is part of Catacomb. |
| 13 | ## |
| 14 | ## Catacomb is free software; you can redistribute it and/or modify |
| 15 | ## it under the terms of the GNU Library General Public License as |
| 16 | ## published by the Free Software Foundation; either version 2 of the |
| 17 | ## License, or (at your option) any later version. |
| 18 | ## |
| 19 | ## Catacomb is distributed in the hope that it will be useful, |
| 20 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ## GNU Library General Public License for more details. |
| 23 | ## |
| 24 | ## You should have received a copy of the GNU Library General Public |
| 25 | ## License along with Catacomb; if not, write to the Free |
| 26 | ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, |
| 27 | ## MA 02111-1307, USA. |
| 28 | |
| 29 | ##----- Revision history ---------------------------------------------------- |
| 30 | ## |
| 31 | ## $Log: Makefile.m4,v $ |
| 32 | ## Revision 1.11 1999/11/20 22:24:53 mdw |
| 33 | ## Add Diffie-Hellman support. |
| 34 | ## |
| 35 | ## Revision 1.11 1999/11/20 22:24:53 mdw |
| 36 | ## Add Diffie-Hellman support. |
| 37 | ## |
| 38 | ## Revision 1.10 1999/11/19 19:28:24 mdw |
| 39 | ## Add DSA files and tests. |
| 40 | ## |
| 41 | ## Revision 1.9 1999/11/17 18:05:35 mdw |
| 42 | ## Many new files and test cases for multiprecision arithmetic. |
| 43 | ## |
| 44 | ## Revision 1.8 1999/11/13 01:56:07 mdw |
| 45 | ## Include multiprecision maths stuff. |
| 46 | ## |
| 47 | ## Revision 1.7 1999/11/11 19:01:02 mdw |
| 48 | ## Use `libtool' to generate a shared library. |
| 49 | ## |
| 50 | ## Revision 1.6 1999/11/11 17:47:34 mdw |
| 51 | ## Updates for new configuration system, and `mptypes' generator. |
| 52 | ## |
| 53 | ## Revision 1.5 1999/11/11 00:59:17 mdw |
| 54 | ## Minor reformatting. |
| 55 | ## |
| 56 | ## Revision 1.4 1999/10/24 10:20:36 mdw |
| 57 | ## Modify for standalone distribution. The library's getting far too large |
| 58 | ## to be sensibly embedded in other programs. |
| 59 | ## |
| 60 | ## Revision 1.3 1999/10/24 10:04:26 mdw |
| 61 | ## Install headers in the right directory. |
| 62 | ## |
| 63 | ## Revision 1.2 1999/10/23 12:55:35 mdw |
| 64 | ## The `CVS' directory can't be hardlinked. Don't worry about this |
| 65 | ## overmuch. |
| 66 | ## |
| 67 | ## Revision 1.1 1999/09/03 08:41:11 mdw |
| 68 | ## Initial import. |
| 69 | ## |
| 70 | |
| 71 | AUTOMAKE_OPTIONS = foreign |
| 72 | |
| 73 | archincludedir = $(libdir)/catacomb/include |
| 74 | |
| 75 | ## --- List handling macros --- |
| 76 | ## |
| 77 | ## List handling is nice, usually. Unfortunately, I based this design on |
| 78 | ## TeX list macros rather than anything sensible... |
| 79 | |
| 80 | define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'') |
| 81 | define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')') |
| 82 | define(`join', |
| 83 | `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')') |
| 84 | define(`addsuffix', `adorn(`', `$1', `$2')') |
| 85 | define(`lit', `adorn(`', `$1', `')') |
| 86 | define(`nl', ` |
| 87 | ') |
| 88 | |
| 89 | define(`allwithsuffix', |
| 90 | `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl |
| 91 | addsuffix(join(`$1', `-', `$2'), `$3')') |
| 92 | |
| 93 | ## --- Autogenerated source files --- |
| 94 | |
| 95 | define(`ciphers', `_(des) _(des3) _(blowfish) _(idea) _(rc5)') |
| 96 | define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb)') |
| 97 | |
| 98 | define(`hashes', `_(md5) _(md4) _(rmd160) _(sha)') |
| 99 | define(`hash_modes', `_(hmac)') |
| 100 | |
| 101 | MODES = \ |
| 102 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 103 | adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 104 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \ |
| 105 | adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h') |
| 106 | |
| 107 | $(MODES): $(srcdir)/genmodes |
| 108 | cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')" |
| 109 | cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')" |
| 110 | |
| 111 | des_sp.h: des-mktab |
| 112 | ./des-mktab >des_sp.h |
| 113 | |
| 114 | ptab.c ptab.h: genprimes |
| 115 | ./genprimes -h ptab.h -c ptab.c -m 256 -t "unsigned char" -i ptab |
| 116 | |
| 117 | archinclude_HEADERS = mptypes.h |
| 118 | |
| 119 | mptypes.h: mptypes |
| 120 | ./mptypes >mptypes.h |
| 121 | |
| 122 | BUILT_SOURCES = \ |
| 123 | getdate.c \ |
| 124 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 125 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \ |
| 126 | addsuffix(join(`hashes', `-', `hash_modes'), `.c') \ |
| 127 | addsuffix(join(`hashes', `-', `hash_modes'), `.h') |
| 128 | |
| 129 | ## --- Building the main library --- |
| 130 | libcatacomb_la_LDFLAGS = -version-info 0:3:0 |
| 131 | lib_LTLIBRARIES = libcatacomb.la |
| 132 | |
| 133 | libcatacomb_la_LDFLAGS = -version-info 0:4:0 |
| 134 | ## Middle number is the patchlevel. Final number is the minor version. The |
| 135 | ## difference between the first and last numbers is major version. |
| 136 | |
| 137 | define(`emit', `$1.h ') |
| 138 | pkginclude_HEADERS = \ |
| 139 | paranoia.h \ |
| 140 | blkc.h hash.h \ |
| 141 | rc4.h \ |
| 142 | rand.h noise.h \ |
| 143 | key.h \ |
| 144 | mpx.h mpw.h mpscan.h mparena.h mp.h mptext.h mpmont.h \ |
| 145 | ptab.h pgen.h rabin.h \ |
| 146 | dsa.h dh.h \ |
| 147 | allwithsuffix(`ciphers', `cipher_modes', `.h') \ |
| 148 | allwithsuffix(`hashes', `hash_modes', `.h') |
| 149 | |
| 150 | define(`emit', `$1.c ') |
| 151 | libcatacomb_la_SOURCES = \ |
| 152 | des-base.c des-base.h des_sp.h bf_ikey.h daftstory.h \ |
| 153 | rc4.c \ |
| 154 | rand.c noise.c \ |
| 155 | key.c \ |
| 156 | mpx.c mpscan.c mparena.c \ |
| 157 | mp-misc.c mp-mem.c mp-const.c mp-io.c mp-arith.c mp-test.c \ |
| 158 | mp-gcd.c \ |
| 159 | mptext.c mptext-file.c mptext-string.c mptext-dstr.c \ |
| 160 | mpmont.c mpmont-mexp.c \ |
| 161 | ptab.c pgen.c rabin.c \ |
| 162 | dsa-sign.c dsa-verify.c dsa-gen.c \ |
| 163 | dh-prime.c \ |
| 164 | addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \ |
| 165 | addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') |
| 166 | |
| 167 | des-base.lo: des_sp.h |
| 168 | mpx.lo: mptypes.h |
| 169 | |
| 170 | ## --- Utility programs --- |
| 171 | |
| 172 | bin_PROGRAMS = key |
| 173 | bin_SCRIPTS = catacomb-config |
| 174 | noinst_PROGRAMS = des-mktab genprimes mptypes |
| 175 | LDADD = libcatacomb.la |
| 176 | |
| 177 | key_SOURCES = keyutil.c getdate.y getdate.h |
| 178 | |
| 179 | des_mktab_SOURCES = des-mktab.c |
| 180 | des_mktab_LDADD = |
| 181 | |
| 182 | genprimes_SOURCES = genprimes.c |
| 183 | genprimes_LDADD = |
| 184 | |
| 185 | mptypes_SOURCES = mptypes.c |
| 186 | mptypes_LDADD = |
| 187 | |
| 188 | ## --- Documentation --- |
| 189 | |
| 190 | man_MANS = key.1 keyring.5 |
| 191 | |
| 192 | ## --- Other handy definitions --- |
| 193 | |
| 194 | EXTRA_DIST = Makefile.m4 genmodes $(man_MANS) |
| 195 | |
| 196 | dist-hook: |
| 197 | @ln getdate.c $(distdir) || ln $(srcdir)/getdate.c $(distdir) || true |
| 198 | @mkdir $(distdir)/tests |
| 199 | @ln $(srcdir)/tests/* $(distdir)/tests || true |
| 200 | @rm -f $(distdir)/tests/*~ |
| 201 | |
| 202 | ## --- Testing --- |
| 203 | |
| 204 | define(`testprogs', `') |
| 205 | |
| 206 | define(`CTESTRIG', |
| 207 | `define(`testprogs', testprogs \ |
| 208 | $1.t)dnl |
| 209 | $1.t: $1.c libcatacomb.la |
| 210 | $(COMPILE) -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c .libs/libcatacomb.a $(LIBS) -o $1.t') |
| 211 | |
| 212 | CTESTRIG(rc4) |
| 213 | adorn(`nl`'CTESTRIG(', `ciphers', `)') |
| 214 | CTESTRIG(mpx-test) |
| 215 | adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)') |
| 216 | adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)') |
| 217 | CTESTRIG(mpx) |
| 218 | CTESTRIG(mptext) |
| 219 | CTESTRIG(mp-arith) |
| 220 | CTESTRIG(mp-gcd) |
| 221 | CTESTRIG(mpmont) |
| 222 | CTESTRIG(mpmont-mexp) |
| 223 | CTESTRIG(pgen) |
| 224 | CTESTRIG(dsa-gen) |
| 225 | CTESTRIG(dsa-sign) |
| 226 | CTESTRIG(dsa-verify) |
| 227 | |
| 228 | TESTS = testprogs |
| 229 | |
| 230 | CLEANFILES = *.t mptypes.h des_sp.h ptab.c ptab.h |
| 231 | |
| 232 | ## --- Makefile building (haha!) --- |
| 233 | |
| 234 | $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4 |
| 235 | m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am |
| 236 | |
| 237 | MAINTAINERCLEANFILES = \ |
| 238 | $(srcdir)/Makefile.am \ |
| 239 | $(srcdir)/getdate.c getdate.c \ |
| 240 | $(MODES) |
| 241 | |
| 242 | ##----- That's all, folks --------------------------------------------------- |