| 1 | dnl -*-fundamental-*- |
| 2 | dnl |
| 3 | dnl $Id: configure.in,v 1.3 1997/08/07 09:34:32 mdw Exp $ |
| 4 | dnl |
| 5 | dnl Source for auto configuration for `become' |
| 6 | dnl |
| 7 | dnl (c) 1997 Mark Wooding |
| 8 | dnl |
| 9 | |
| 10 | dnl----- Licensing notice --------------------------------------------------- |
| 11 | dnl |
| 12 | dnl This file is part of `become' |
| 13 | dnl |
| 14 | dnl `Become' is free software; you can redistribute it and/or modify |
| 15 | dnl it under the terms of the GNU General Public License as published by |
| 16 | dnl the Free Software Foundation; either version 2 of the License, or |
| 17 | dnl (at your option) any later version. |
| 18 | dnl |
| 19 | dnl `Become' is distributed in the hope that it will be useful, |
| 20 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | dnl GNU General Public License for more details. |
| 23 | dnl |
| 24 | dnl You should have received a copy of the GNU General Public License |
| 25 | dnl along with `become'; if not, write to the Free Software Foundation, |
| 26 | dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 27 | |
| 28 | dnl----- Revision history --------------------------------------------------- |
| 29 | dnl |
| 30 | dnl $Log: configure.in,v $ |
| 31 | dnl Revision 1.3 1997/08/07 09:34:32 mdw |
| 32 | dnl Added `ElectricFence' support, and support for the `deep' package structure. |
| 33 | dnl |
| 34 | dnl Revision 1.2 1997/08/04 10:24:21 mdw |
| 35 | dnl Sources placed under CVS control. |
| 36 | dnl |
| 37 | dnl Revision 1.1 1997/07/21 13:47:51 mdw |
| 38 | dnl Initial revision |
| 39 | dnl |
| 40 | |
| 41 | AC_INIT(src/icrypt.c) |
| 42 | AC_CONFIG_HEADER(config.h) |
| 43 | PACKAGE=become VERSION=1.2-pre |
| 44 | AC_SUBST(PACKAGE) |
| 45 | AC_SUBST(VERSION) |
| 46 | AC_DEFINE(VERSION, "1.2-pre (24 July 1997)") |
| 47 | |
| 48 | dnl --- Check for compilers and things --- |
| 49 | |
| 50 | AC_PROG_CC |
| 51 | AC_PROG_INSTALL |
| 52 | AC_PROG_LEX |
| 53 | AC_CHECK_PROG(AR, ar, ar) |
| 54 | AC_PROG_RANLIB |
| 55 | AC_PROG_MAKE_SET |
| 56 | AC_PROG_YACC |
| 57 | AC_ARG_PROGRAM |
| 58 | if test "$ac_cv_prog_gcc" = "yes"; then |
| 59 | CFLAGS="$CFLAGS -pedantic -Wall" |
| 60 | fi |
| 61 | |
| 62 | dnl --- Libraries --- |
| 63 | |
| 64 | MDW_CHECK_MANYLIBS(socket, socket,, |
| 65 | AC_MSG_ERROR([Socket library not found])) |
| 66 | |
| 67 | MDW_CHECK_MANYLIBS(gethostbyname, resolv nsl,, |
| 68 | AC_MSG_ERROR([Resolver library not found])) |
| 69 | |
| 70 | MDW_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP)) |
| 71 | |
| 72 | dnl --- Types --- |
| 73 | |
| 74 | AC_TYPE_PID_T |
| 75 | AC_TYPE_UID_T |
| 76 | AC_CHECK_TYPE(ssize_t, int) |
| 77 | |
| 78 | dnl --- Check on type sizes --- |
| 79 | |
| 80 | AC_CHECK_SIZEOF(int, 2) |
| 81 | |
| 82 | dnl --- Set the path separator --- |
| 83 | |
| 84 | AC_DEFINE(PATHSEP, '/') |
| 85 | |
| 86 | dnl --- Check for some useful functions --- |
| 87 | |
| 88 | AC_CHECK_FUNCS(getrusage vtimes) |
| 89 | |
| 90 | dnl --- Debugging stuff --- |
| 91 | |
| 92 | AC_ARG_WITH(electric-fence, |
| 93 | [ --with-electric-fence link programs with Electric Fence], |
| 94 | [if test "$withval" = "yes"; then |
| 95 | AC_CHECK_LIB(efence, malloc) |
| 96 | fi]) |
| 97 | |
| 98 | AC_ARG_ENABLE(debugging, |
| 99 | [ --enable-debugging spews vast swathes of useless information], |
| 100 | [if test "$enableval" = "no"; then |
| 101 | AC_DEFINE(NDEBUG, 1) |
| 102 | fi], |
| 103 | AC_DEFINE(NDEBUG, 1)) |
| 104 | |
| 105 | AC_ARG_ENABLE(tracing, |
| 106 | [ --enable-tracing enable output of tracing information], |
| 107 | [if test "$enableval" = "yes"; then |
| 108 | AC_DEFINE(TRACING) |
| 109 | fi], |
| 110 | AC_DEFINE(TRACING)) |
| 111 | |
| 112 | dnl --- Define where things get put --- |
| 113 | |
| 114 | mdw_save_prefix="$prefix" |
| 115 | test "$prefix" = "NONE" && prefix="$ac_default_prefix" |
| 116 | AC_DEFINE_UNQUOTED(ETCDIR, "`eval echo ${sysconfdir}`") |
| 117 | prefix="$mdw_save_prefix" |
| 118 | |
| 119 | dnl --- Done --- |
| 120 | |
| 121 | AC_OUTPUT(Makefile src/Makefile manual/Makefile) |
| 122 | |
| 123 | dnl----- That's all, folks -------------------------------------------------- |