Files to link to the CFD

[become] / configure.in

dnl -*-fundamental-*-
dnl
dnl $Id: configure.in,v 1.3 1997/08/07 09:34:32 mdw Exp $
dnl
dnl Source for auto configuration for `become'
dnl
dnl (c) 1997 Mark Wooding
dnl

dnl----- Licensing notice ---------------------------------------------------
dnl 
dnl This file is part of `become'
dnl 
dnl `Become' is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl 
dnl `Become' is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl 
dnl You should have received a copy of the GNU General Public License
dnl along with `become'; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl----- Revision history ---------------------------------------------------
dnl
dnl $Log: configure.in,v $
dnl Revision 1.3  1997/08/07 09:34:32  mdw
dnl Added `ElectricFence' support, and support for the `deep' package structure.
dnl
dnl Revision 1.2  1997/08/04 10:24:21  mdw
dnl Sources placed under CVS control.
dnl
dnl Revision 1.1  1997/07/21  13:47:51  mdw
dnl Initial revision
dnl

AC_INIT(src/icrypt.c)
AC_CONFIG_HEADER(config.h)
PACKAGE=become VERSION=1.2-pre
AC_SUBST(PACKAGE)
AC_SUBST(VERSION)
AC_DEFINE(VERSION, "1.2-pre (24 July 1997)")

dnl --- Check for compilers and things ---

AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LEX
AC_CHECK_PROG(AR, ar, ar)
AC_PROG_RANLIB
AC_PROG_MAKE_SET
AC_PROG_YACC
AC_ARG_PROGRAM
if test "$ac_cv_prog_gcc" = "yes"; then
  CFLAGS="$CFLAGS -pedantic -Wall"
fi

dnl --- Libraries ---

MDW_CHECK_MANYLIBS(socket, socket,,
  AC_MSG_ERROR([Socket library not found]))

MDW_CHECK_MANYLIBS(gethostbyname, resolv nsl,,
  AC_MSG_ERROR([Resolver library not found]))

MDW_CHECK_MANYLIBS(yp_all, nsl, AC_DEFINE(HAVE_YP))

dnl --- Types ---

AC_TYPE_PID_T
AC_TYPE_UID_T
AC_CHECK_TYPE(ssize_t, int)

dnl --- Check on type sizes ---

AC_CHECK_SIZEOF(int, 2)

dnl --- Set the path separator ---

AC_DEFINE(PATHSEP, '/')

dnl --- Check for some useful functions ---

AC_CHECK_FUNCS(getrusage vtimes)

dnl --- Debugging stuff ---

AC_ARG_WITH(electric-fence,
[  --with-electric-fence	  link programs with Electric Fence],
  [if test "$withval" = "yes"; then
    AC_CHECK_LIB(efence, malloc)
  fi])

AC_ARG_ENABLE(debugging,
[  --enable-debugging	  spews vast swathes of useless information],
  [if test "$enableval" = "no"; then
    AC_DEFINE(NDEBUG, 1)
  fi],
  AC_DEFINE(NDEBUG, 1))

AC_ARG_ENABLE(tracing,
[  --enable-tracing	  enable output of tracing information],
  [if test "$enableval" = "yes"; then
    AC_DEFINE(TRACING)
  fi],
  AC_DEFINE(TRACING))

dnl --- Define where things get put ---

mdw_save_prefix="$prefix"
test "$prefix" = "NONE" && prefix="$ac_default_prefix"
AC_DEFINE_UNQUOTED(ETCDIR, "`eval echo ${sysconfdir}`")
prefix="$mdw_save_prefix"

dnl --- Done ---

AC_OUTPUT(Makefile src/Makefile manual/Makefile)

dnl----- That's all, folks --------------------------------------------------