dnl -*-autoconf-*-
dnl
dnl Configuration script for `autoys'
dnl
dnl (c) 2016 Mark Wooding
dnl

dnl----- Licensing notice ---------------------------------------------------
dnl
dnl This file is part of the `autoys' audio tools collection.
dnl
dnl `autoys' is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation; either version 2 of the License, or
dnl (at your option) any later version.
dnl
dnl `autoys' is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with `autoys'; if not, write to the Free Software Foundation,
dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

dnl--------------------------------------------------------------------------
dnl Initialization.

mdw_AUTO_VERSION
AC_INIT([autoys], AUTO_VERSION, [mdw@distorted.org.uk])
AC_CONFIG_SRCDIR([gremlin/gremlin.in])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([foreign])
mdw_SILENT_RULES

dnl--------------------------------------------------------------------------
dnl C programming environment.

AC_PROG_CC
AX_FLAGS_WARN_ALL

dnl--------------------------------------------------------------------------
dnl Various scripting languages.

## Python
AM_PATH_PYTHON([2.5], [have_python=yes], [have_python=no])
AM_CONDITIONAL([HAVE_PYTHON], [test $have_python = yes])

## Bash.
case "$BASH" in /bin/sh) unset BASH ;; esac
AC_ARG_VAR([BASH], [Path to the Bourne Again Shell.])
AC_PATH_PROG([BASH], [bash], [false])
AC_MSG_CHECKING([bash version])
bashver=$("$BASH" -c 'echo $BASH_VERSION')
if "$BASH" 2>/dev/null -c '[[[ ${BASH_VERSINFO[0]} -ge 3 ]]]'; then
  have_bash=yes
  AC_MSG_RESULT([$bashver])
else
  have_bash=no
  AC_MSG_RESULT([too old ($bashver)])
fi
AM_CONDITIONAL([HAVE_BASH], [test $have_bash = yes])

dnl--------------------------------------------------------------------------
dnl Output.

AC_CONFIG_FILES(
  [Makefile]
  [coverart/Makefile]
  [gremlin/Makefile])
AC_OUTPUT

dnl----- That's all, folks --------------------------------------------------