git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-m4-*-
   2 ##
   3 ## $Id$
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 AUTOMAKE_OPTIONS = foreign
  30
  31 SUBDIRS = tests
  32
  33 archincludedir = $(libdir)/catacomb/include
  34
  35 ## --- List handling macros ---
  36 ##
  37 ## List handling is nice, usually.  Unfortunately, I based this design on
  38 ## TeX list macros rather than anything sensible...
  39
  40 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
  41 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
  42 define(`join',
  43 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
  44 define(`addsuffix', `adorn(`', `$1', `$2')')
  45 define(`lit', `adorn(`', `$1', `')')
  46 define(`nl', `
  47 ')
  48
  49 define(`allwithsuffix',
  50 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
  51 addsuffix(join(`$1', `-', `$2'), `$3')')
  52
  53 ## --- Autogenerated source files ---
  54
  55 define(`ciphers', `dnl
  56 _(des) _(desx) _(des3) _(mars) dnl
  57 _(idea) _(safer) _(safersk) dnl
  58 _(blowfish) _(twofish) dnl
  59 _(tea) _(xtea) dnl
  60 _(rc2) _(rc5) dnl
  61 _(skipjack) dnl
  62 _(cast128) _(cast256) dnl
  63 _(square) _(rijndael) _(rijndael192) _(rijndael256) dnl
  64 _(serpent) _(noekeon)')
  65 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
  66
  67 define(`hashes', `dnl
  68 _(md5) _(md4) _(md2) _(tiger) _(has160) dnl
  69 _(sha) _(sha224) _(sha256) _(sha384) _(sha512) dnl
  70 _(whirlpool) _(whirlpool256) dnl
  71 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
  72 define(`hash_modes', `_(mgf) _(hmac)')
  73
  74 MODES = \
  75         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
  76         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
  77         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
  78         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
  79
  80 $(MODES): modes-stamp
  81 modes-stamp: genmodes
  82         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
  83         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
  84         echo datestamp >modes-stamp
  85
  86 define(`gen_tables', `dnl
  87 _(des) _(blowfish) _(twofish) dnl
  88 _(square) _(rijndael) _(whirlpool) dnl
  89 _(safer) _(mars) _(tiger) dnl
  90 _(gfshare) _(gfx-sqr)')
  91
  92 autoheaders: \
  93   addsuffix(`gen_tables', `-tab.h') \
  94   primetab.h wheel.h mptypes.h mplimits.h
  95 define(`emit', `
  96 _item`'-tab.h: _item`'-mktab$(EXEEXT)
  97         ./_item`'-mktab >_item`'-tab.h.new
  98         mv _item`'-tab.h.new _item`'-tab.h')dnl
  99 gen_tables
 100
 101 primetab.h: primetab.c
 102 primetab.c: genprimes$(EXEEXT)
 103         ./genprimes -h primetab.h -c primetab.c \
 104                 -s CATACOMB_PRIMETAB_H -n 256 \
 105                 -t "unsigned short" -i primetab
 106
 107 wheel.h: wheel.c
 108 wheel.c: genwheel$(EXEEXT)
 109         ./genwheel -h wheel.h -c wheel.c \
 110                 -s CATACOMB_WHEEL_H -n 5
 111                 -t "unsigned char" -i wheel
 112
 113 archinclude_HEADERS = mptypes.h mplimits.h
 114 mptypes.h: mptypes$(EXEEXT)
 115         ./mptypes >mptypes.h.new
 116         mv mptypes.h.new mptypes.h
 117
 118 mplimits.h: genlimits$(EXEEXT)
 119         ./genlimits h >mplimits.h.new
 120         mv mplimits.h.new mplimits.h
 121 mplimits.c: genlimits$(EXEEXT)
 122         ./genlimits c >mplimits.c.new
 123         mv mplimits.c.new mplimits.c
 124
 125 ectab.c: ectab.in ec-gentab.awk mpdump$(EXEEXT)
 126         $(srcdir)/ec-gentab.awk <$(srcdir)/ectab.in >ectab.c.new
 127         mv ectab.c.new ectab.c
 128
 129 ptab.c: ptab.in p-gentab.awk mpdump$(EXEEXT)
 130         $(srcdir)/p-gentab.awk <$(srcdir)/ptab.in >ptab.c.new
 131         mv ptab.c.new ptab.c
 132
 133 bintab.c: bintab.in bin-gentab.awk mpdump$(EXEEXT)
 134         $(srcdir)/bin-gentab.awk <$(srcdir)/bintab.in >bintab.c.new
 135         mv bintab.c.new bintab.c
 136
 137 gciphertab.c: gengctab
 138         $(srcdir)/gengctab gccipher gcipher >gciphertab.c.new \
 139                 "lit(join(`ciphers', `-', `cipher_modes')) \
 140                 lit(join(`hashes', `-', `_(mgf)')) \
 141                 rc4 seal"
 142         mv gciphertab.c.new gciphertab.c
 143
 144 gmactab.c: gengctab
 145         $(srcdir)/gengctab gcmac gmac >gmactab.c.new \
 146                 "lit(join(`hashes', `-', `_(hmac)'))"
 147         mv gmactab.c.new gmactab.c
 148
 149 ghashtab.c: gengctab
 150         $(srcdir)/gengctab gchash ghash >ghashtab.c.new \
 151                 "lit(`hashes') \
 152                 crc32=gcrc32"
 153         mv ghashtab.c.new ghashtab.c
 154
 155 BUILT_SOURCES = \
 156         getdate.c modes-stamp gciphertab.c gmactab.c ghashtab.c \
 157         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 158         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 159         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 160         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 161
 162 ## --- Building the main library ---
 163
 164 lib_LTLIBRARIES = libcatacomb.la
 165
 166 libcatacomb_la_LDFLAGS = -version-info 3:0:1
 167 ## Middle number is the patchlevel.  Final number is the minor version.  The
 168 ## difference between the first and last numbers is major version.
 169
 170 pkginclude_HEADERS = \
 171         arena.h paranoia.h buf.h qdparse.h keysz.h \
 172         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 173         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 174         key.h key-error.h key-data.h passphrase.h pixie.h lmem.h \
 175         mpx.h bitops.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 176         exp.h mpbarrett.h mpmont.h mpreduce.h mp-exp.h \
 177         mpcrt.h mprand.h mpmul.h \
 178         gfx.h gf.h gfreduce.h gfn.h gf-exp.h \
 179         primetab.h wheel.h pfilt.h rabin.h \
 180         pgen.h primeiter.h prim.h strongprime.h limlee.h keycheck.h \
 181         bbs.h rsa.h dh.h dsarand.h dsa.h gdsa.h gkcdsa.h \
 182         tlsprf.h sslprf.h \
 183         gfshare.h share.h \
 184         rho.h \
 185         field.h field-guts.h field-exp.h \
 186         ec.h ec-guts.h ec-exp.h ec-test.h ectab.h ec-keys.h ec-raw.h \
 187         ptab.h bintab.h group.h group-guts.h \
 188         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 189         allwithsuffix(`hashes', `hash_modes', `.h') \
 190         addsuffix(`cipher_modes', `-def.h') \
 191         addsuffix(`hash_modes', `-def.h') crc32.h
 192
 193 define(`MP_BASE',
 194         `mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \
 195         mp-misc.c mp-mem.c mp-const.c mp-arith.c mp-io.c \
 196         mptext.c mptext-string.c')
 197
 198 define(`MP_SOURCES',
 199         `qdparse.c \
 200         mp-test.c mplimits.c \
 201         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c mp-exp.c mp-modexp.c \
 202         mpint.c mptext-file.c mptext-dstr.c \
 203         mptext-len.c \
 204         exp.c mpcrt.c mpmul.c mprand.c \
 205         mpbarrett.c mpbarrett-exp.c mpbarrett-mexp.c mpbarrett-exp.h \
 206         mpmont.c mpmont-exp.c mpmont-mexp.c mpmont-exp.h \
 207         mpreduce.c mpreduce-exp.h \
 208         group-stdops.c group-exp.c group-exp.h g-prime.c g-bin.c \
 209           group-parse.c \
 210         group-string.c group-file.c group-dstr.c \
 211         rho.c buf.c ptab.c bintab.c \
 212         GF_SOURCES PGEN_SOURCES EC_SOURCES')
 213
 214 define(`GF_SOURCES',
 215         `gfx.c gfx-kmul.c gfx-sqr.c gf-arith.c gf-exp.c gf-gcd.c \
 216         gfreduce.c gfreduce-exp.h gfn.c')
 217
 218 define(`EC_SOURCES',
 219         `field.c field-parse.c field-exp.c \
 220         f-prime.c f-niceprime.c f-binpoly.c \
 221         ec.c ec-exp.c ec-prime.c ec-bin.c ec-test.c ec-info.c ectab.c \
 222         ec-fetch.c ec-raw.c g-ec.c')
 223
 224 define(`PGEN_SOURCES',
 225         `pfilt.c primeiter.c rabin.c \
 226         pgen.c pgen-stdev.c pgen-gcd.c pgen-simul.c \
 227           prim.c strongprime.c limlee.c \
 228         keycheck.c keycheck-mp.c keycheck-report.c \
 229         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 230         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 231         oaep.c pkcs1.c pss.c \
 232         dh-gen.c dh-limlee.c dh-kcdsa.c dh-check.c dh-fetch.c dh-param.c \
 233         dsarand.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-check.c \
 234         gdsa.c gkcdsa.c \
 235         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 236         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 237         key-error.c key-fetch.c \
 238         primetab.c wheel.c share.c')
 239
 240 libcatacomb_la_SOURCES = \
 241         grand.c keysz.c keysz-conv.c \
 242         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 243         arena.c \
 244         passphrase.c pixie-common.c lmem.c \
 245         tlsprf.c sslprf.c \
 246         gfshare.c \
 247         MP_BASE MP_SOURCES karatsuba.h \
 248         gciphertab.c ghashtab.c gmactab.c \
 249         des-base.c des-base.h \
 250         desx-tab.h \
 251         rc2-tab.h \
 252         skipjack-tab.h \
 253         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 254         rijndael-base.c rijndael-base.h \
 255         md2-tab.h \
 256         serpent-sbox.h skipjack-tab.h tiger-base.h \
 257         daftstory.h \
 258         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 259         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 260         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') crc32.c
 261
 262 des-base.lo: des-tab.h
 263 blowfish.lo: blowfish-tab.h
 264 twofish.lo: twofish-tab.h
 265 square.lo: square-tab.h
 266 rijndael-base.lo: rijndael-tab.h
 267 whirlpool.lo: whirlpool-tab.h
 268 safer.lo: safer-tab.h
 269 mars.lo: mars-tab.h
 270 tiger.lo: tiger-tab.h
 271 gfshare.lo: gfshare-tab.h
 272 gfx-sqr.lo: gfx-sqr-tab.h
 273
 274 ## --- Utility programs ---
 275
 276 bin_PROGRAMS = \
 277         dsig key pixie cookie rspit factorial hashsum mkphrase \
 278         catcrypt catsign
 279 noinst_LIBRARIES = libcatcrypt.a
 280 bin_SCRIPTS = catacomb-config xpixie
 281 noinst_PROGRAMS = \
 282         genprimes genwheel mptypes genlimits serpent-check bittest mpdump \
 283         perftest \
 284         addsuffix(`gen_tables', `-mktab')
 285 LDADD = libcatcrypt.a libcatacomb.la
 286
 287 define(`LIBCAT_SRC', `cc.h getdate.h dnl
 288         cc-sig.c cc-subcmd.c cc-enc.c cc-kem.c cc-list.c')
 289 libcatcrypt_a_SOURCES = LIBCAT_SRC getdate.y
 290
 291 patsubst(MP_BASE MP_SOURCES, `\.c\>', `.lo') dsig.o keyutil.o rspit.o \
 292         patsubst(LIBCAT_SRC, `\.c\>', `.o'): \
 293         mptypes.h primetab.h wheel.h
 294 patsubst(MP_SOURCES, `\.c\>', `.lo'): mplimits.h
 295
 296 dsig_SOURCES = dsig.c
 297 cookie_SOURCES = cookie.c
 298 catcrypt_SOURCES = catcrypt.c
 299 catsign_SOURCES = catsign.c
 300 key_SOURCES = keyutil.c
 301 hashsum_SOURCES = hashsum.c
 302 rspit_SOURCES = rspit.c
 303 factorial_SOURCES = factorial.c
 304 perftest_SOURCES = perftest.c
 305 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c passphrase.c
 306 pixie_LDADD =
 307 pixie_CFLAGS = $(AM_CFLAGS)
 308 mkphrase_SOURCES = mkphrase.c
 309 bittest_SOURCES = bittest.c
 310 bittest_LDADD =
 311
 312 define(`emit', `
 313 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_SOURCES = _item`'-mktab.c
 314 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_LDADD =')dnl
 315 gen_tables
 316
 317 serpent_check_SOURCES = serpent-check.c
 318 serpent_check_LDADD =
 319
 320 genprimes_SOURCES = genprimes.c
 321 genprimes_LDADD =
 322
 323 genwheel_SOURCES = genwheel.c
 324 genwheel_LDADD =
 325
 326 mptypes_SOURCES = mptypes.c
 327 mptypes_LDADD =
 328
 329 genlimits_SOURCES = genlimits.c MP_BASE mptypes.h
 330 genlimits_LDADD =
 331 genlimits_CFLAGS = $(AM_CFLAGS)
 332
 333 mpdump_SOURCES = mpdump.c MP_BASE
 334 mpdump_LDADD =
 335 mpdump_CFLAGS = $(AM_CFLAGS)
 336
 337 ## --- Install the pixie setuid-root if we can ---
 338 ##
 339 ## Bodge around a bug in Automake: it doesn't call `install-exec-hook' from
 340 ## `install' if there are subdirectories.
 341
 342 changequote(<, >)
 343 # install: install-exec-hook
 344 install-exec-hook:
 345         @pixie="$(DESTDIR)$(bindir)/`echo pixie|sed $(transform)`"; \
 346         if chown root $$pixie && chmod 4755 $$pixie; then \
 347           echo "chown root $$pixie"; \
 348           echo "chmod 4755 $$pixie"; \
 349         else \
 350           echo "***"; \
 351           echo "*** You should probably install $$pixie setuid-root."; \
 352           echo "***"; \
 353         fi
 354 changequote(`, ')
 355
 356 ## --- Documentation ---
 357
 358 man_MANS = \
 359         key.1 dsig.1 cookie.1 catcrypt.1 catsign.1 hashsum.1 mkphrase.1 \
 360         keyring.5 pixie.1
 361
 362 ## --- Prime group keyring ---
 363
 364 pkgdata_DATA = pgroups.kr
 365
 366 $(srcdir)/pgroups.kr: ptab.in mkpgroups
 367         cd $(srcdir) && rm -f pgroups.kr && ./mkpgroups <ptab.in
 368
 369 ## --- Other handy definitions ---
 370
 371 EXTRA_DIST = \
 372         Makefile.m4 genmodes gengctab $(man_MANS) xpixie \
 373         group-test.c rsa-test.c \
 374         ectab.in ec-gentab.awk \
 375         ptab.in p-gentab.awk mkpgroups pgroups.kr \
 376         bintab.in bin-gentab.awk \
 377         README.cipher README.hash README.random README.mp \
 378         debian/rules debian/copyright debian/control debian/changelog \
 379         debian/catacomb-bin.postinst debian/catacomb-bin.config \
 380         debian/catacomb-bin.prerm debian/catacomb-bin.templates
 381
 382 dist-hook:
 383         @for i in getdate.c gciphertab.c ghashtab.c gmactab.c; do \
 384           ln $$i $(distdir) || ln $(srcdir)/$$i $(distdir) || true; \
 385         done
 386         @echo datestamp >$(distdir)/modes-stamp || true
 387         @for i in calc tests; do \
 388           mkdir $(distdir)/$$i; \
 389           ln $(srcdir)/$$i/*[!~] $(distdir)/$$i; \
 390         done || true
 391 #       kr=$$HOME/.catacomb/dsig-keyring; \
 392 #       if [ -r $$kr ]; then \
 393 #         cd $(distdir); \
 394 #         ../key -k $$kr extract -f -secret KEYRING; \
 395 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 396 #       fi
 397
 398 ## --- Testing ---
 399
 400 define(`testprogs', `')
 401
 402 define(`CTESTRIG',
 403 `define(`testprogs', testprogs \
 404         $1.t$(EXEEXT))dnl
 405 $1.to: $1.c
 406         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 407 $1.t$(EXEEXT): $1.to libcatacomb.la
 408         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(LIBS) -o $1.t$(EXEEXT)')
 409
 410 CTESTRIG(rc4)
 411 CTESTRIG(seal)
 412 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 413 adorn(`nl`'CTESTRIG(', `hashes', `)')
 414 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 415 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 416 CTESTRIG(lcrand)
 417 CTESTRIG(tlsprf)
 418 CTESTRIG(sslprf)
 419 CTESTRIG(mpx)
 420 CTESTRIG(mpx-kmul)
 421 CTESTRIG(mpx-ksqr)
 422 CTESTRIG(mp-arith)
 423 CTESTRIG(mp-modsqrt)
 424 CTESTRIG(mp-gcd)
 425 CTESTRIG(mp-jacobi)
 426 CTESTRIG(mp-sqrt)
 427 CTESTRIG(mp-modexp)
 428 CTESTRIG(mptext)
 429 CTESTRIG(mpint)
 430 CTESTRIG(mpbarrett)
 431 CTESTRIG(mpbarrett-exp)
 432 CTESTRIG(mpbarrett-mexp)
 433 CTESTRIG(mpmont)
 434 CTESTRIG(mpmont-exp)
 435 CTESTRIG(mpmont-mexp)
 436 CTESTRIG(mpreduce)
 437 CTESTRIG(mpcrt)
 438 CTESTRIG(mpmul)
 439 CTESTRIG(rsa-test)
 440 CTESTRIG(gfx)
 441 CTESTRIG(gfx-sqr)
 442 CTESTRIG(gfx-kmul)
 443 CTESTRIG(gf-arith)
 444 CTESTRIG(gf-gcd)
 445 CTESTRIG(gfreduce)
 446 CTESTRIG(gfn)
 447 CTESTRIG(ec-prime)
 448 CTESTRIG(ec-bin)
 449 CTESTRIG(ec-test)
 450 CTESTRIG(ec-info)
 451 CTESTRIG(dh-param)
 452 CTESTRIG(group-test)
 453 CTESTRIG(gdsa)
 454 CTESTRIG(gkcdsa)
 455 CTESTRIG(pgen)
 456 CTESTRIG(primeiter)
 457 CTESTRIG(dsa-gen)
 458 CTESTRIG(dsa-sign)
 459 CTESTRIG(dsa-verify)
 460 CTESTRIG(bbs-rand)
 461 CTESTRIG(bbs-jump)
 462 CTESTRIG(gfshare)
 463 CTESTRIG(share)
 464 CTESTRIG(rho)
 465
 466 TESTS = serpent-check bittest testprogs
 467
 468 CLEANFILES = \
 469         *.t$(EXEEXT) *.to *.kr.old \
 470         mptypes.h primetab.c primetab.h wheel.c wheel.h \
 471         ectab.c ptab.c bintab.c \
 472         addsuffix(`gen_tables', `-tab.h')
 473
 474 ## --- Makefile building (haha!) ---
 475
 476 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 477         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am.new
 478         mv $(srcdir)/Makefile.am.new $(srcdir)/Makefile.am
 479
 480 DISTCLEANFILES = libtool
 481
 482 MAINTAINERCLEANFILES = \
 483         $(srcdir)/Makefile.am \
 484         $(srcdir)/getdate.c getdate.c \
 485         $(srcdir)/pgroups.kr \
 486         $(MODES) modes-stamp $(srcdir)/modes-stamp
 487
 488 ##----- That's all, folks ---------------------------------------------------