git.distorted.org.uk Git - u/mdw/catacomb/blob - Makefile.m4

   1 ## -*-m4-*-
   2 ##
   3 ## $Id$
   4 ##
   5 ## Makefile for Catacomb
   6 ##
   7 ## (c) 1999 Straylight/Edgeware
   8 ##
   9
  10 ##----- Licensing notice ----------------------------------------------------
  11 ##
  12 ## This file is part of Catacomb.
  13 ##
  14 ## Catacomb is free software; you can redistribute it and/or modify
  15 ## it under the terms of the GNU Library General Public License as
  16 ## published by the Free Software Foundation; either version 2 of the
  17 ## License, or (at your option) any later version.
  18 ##
  19 ## Catacomb is distributed in the hope that it will be useful,
  20 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ## GNU Library General Public License for more details.
  23 ##
  24 ## You should have received a copy of the GNU Library General Public
  25 ## License along with Catacomb; if not, write to the Free
  26 ## Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  27 ## MA 02111-1307, USA.
  28
  29 AUTOMAKE_OPTIONS = foreign
  30
  31 SUBDIRS = tests
  32
  33 archincludedir = $(libdir)/catacomb/include
  34
  35 ## --- List handling macros ---
  36 ##
  37 ## List handling is nice, usually.  Unfortunately, I based this design on
  38 ## TeX list macros rather than anything sensible...
  39
  40 define(`_', `define(`_item', $1)define(`_item_2', $2)emit`'')
  41 define(`adorn', `pushdef(`emit', `$1`'_item`'$3')$2`'popdef(`emit')')
  42 define(`join',
  43 `pushdef(`emit', `adorn(``_(''_item`$2', `$3', ``)'')`'')$1`'popdef(`emit')')
  44 define(`addsuffix', `adorn(`', `$1', `$2')')
  45 define(`lit', `adorn(`', `$1', `')')
  46 define(`nl', `
  47 ')
  48
  49 define(`allwithsuffix',
  50 `addsuffix(`$1', `$3') addsuffix(`$2', `$3') dnl
  51 addsuffix(join(`$1', `-', `$2'), `$3')')
  52
  53 ## --- Autogenerated source files ---
  54
  55 define(`ciphers', `dnl
  56 _(des) _(desx) _(des3) _(mars) dnl
  57 _(idea) _(safer) _(safersk) dnl
  58 _(blowfish) _(twofish) dnl
  59 _(tea) _(xtea) dnl
  60 _(rc2) _(rc5) dnl
  61 _(skipjack) dnl
  62 _(cast128) _(cast256) dnl
  63 _(square) _(rijndael) _(rijndael192) _(rijndael256) dnl
  64 _(serpent) _(noekeon)')
  65 define(`cipher_modes', `_(ecb) _(cbc) _(cfb) _(ofb) _(counter)')
  66
  67 define(`hashes', `dnl
  68 _(md5) _(md4) _(md2) _(tiger) _(has160) dnl
  69 _(sha) _(sha224) _(sha256) _(sha384) _(sha512) dnl
  70 _(whirlpool) _(whirlpool256) dnl
  71 _(rmd128) _(rmd160) _(rmd256) _(rmd320)')
  72 define(`hash_modes', `_(mgf) _(hmac)')
  73
  74 MODES = \
  75         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.c') \
  76         adorn(`$(srcdir)/', join(`ciphers', `-', `cipher_modes'), `.h') \
  77         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.c') \
  78         adorn(`$(srcdir)/', join(`hashes', `-', `hash_modes'), `.h')
  79
  80 $(MODES): modes-stamp
  81 modes-stamp: genmodes
  82         cd $(srcdir); ./genmodes "lit(`ciphers')" "lit(`cipher_modes')"
  83         cd $(srcdir); ./genmodes "lit(`hashes')" "lit(`hash_modes')"
  84         echo datestamp >modes-stamp
  85
  86 define(`gen_tables', `dnl
  87 _(des) _(blowfish) _(twofish) dnl
  88 _(square) _(rijndael) _(whirlpool) dnl
  89 _(safer) _(mars) _(tiger) dnl
  90 _(gfshare) _(gfx-sqr)')
  91
  92 autoheaders: \
  93   addsuffix(`gen_tables', `-tab.h') \
  94   primetab.h wheel.h mptypes.h mplimits.h
  95 define(`emit', `
  96 _item`'-tab.h: _item`'-mktab$(EXEEXT)
  97         ./_item`'-mktab >_item`'-tab.h.new
  98         mv _item`'-tab.h.new _item`'-tab.h')dnl
  99 gen_tables
 100
 101 primetab.h: primetab.c
 102 primetab.c: genprimes$(EXEEXT)
 103         ./genprimes -h primetab.h -c primetab.c \
 104                 -s CATACOMB_PRIMETAB_H -n 256 \
 105                 -t "unsigned short" -i primetab
 106
 107 wheel.h: wheel.c
 108 wheel.c: genwheel$(EXEEXT)
 109         ./genwheel -h wheel.h -c wheel.c \
 110                 -s CATACOMB_WHEEL_H -n 5 \
 111                 -t "unsigned char" -i wheel
 112
 113 archinclude_HEADERS = mptypes.h mplimits.h
 114 mptypes.h: mptypes$(EXEEXT)
 115         ./mptypes >mptypes.h.new
 116         mv mptypes.h.new mptypes.h
 117
 118 mplimits.h: genlimits$(EXEEXT)
 119         ./genlimits h >mplimits.h.new
 120         mv mplimits.h.new mplimits.h
 121 mplimits.c: genlimits$(EXEEXT)
 122         ./genlimits c >mplimits.c.new
 123         mv mplimits.c.new mplimits.c
 124
 125 ectab.c: ectab.in ec-gentab.awk mpdump$(EXEEXT)
 126         $(srcdir)/ec-gentab.awk <$(srcdir)/ectab.in >ectab.c.new
 127         mv ectab.c.new ectab.c
 128
 129 ptab.c: ptab.in p-gentab.awk mpdump$(EXEEXT)
 130         $(srcdir)/p-gentab.awk <$(srcdir)/ptab.in >ptab.c.new
 131         mv ptab.c.new ptab.c
 132
 133 bintab.c: bintab.in bin-gentab.awk mpdump$(EXEEXT)
 134         $(srcdir)/bin-gentab.awk <$(srcdir)/bintab.in >bintab.c.new
 135         mv bintab.c.new bintab.c
 136
 137 gciphertab.c: gengctab
 138         $(srcdir)/gengctab gccipher gcipher >gciphertab.c.new \
 139                 "lit(join(`ciphers', `-', `cipher_modes')) \
 140                 lit(join(`hashes', `-', `_(mgf)')) \
 141                 rc4 seal"
 142         mv gciphertab.c.new gciphertab.c
 143
 144 gmactab.c: gengctab
 145         $(srcdir)/gengctab gcmac gmac >gmactab.c.new \
 146                 "lit(join(`hashes', `-', `_(hmac)'))"
 147         mv gmactab.c.new gmactab.c
 148
 149 ghashtab.c: gengctab
 150         $(srcdir)/gengctab gchash ghash >ghashtab.c.new \
 151                 "lit(`hashes') \
 152                 crc32=gcrc32"
 153         mv ghashtab.c.new ghashtab.c
 154
 155 BUILT_SOURCES = \
 156         getdate.c modes-stamp gciphertab.c gmactab.c ghashtab.c \
 157         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 158         addsuffix(join(`ciphers', `-', `cipher_modes'), `.h') \
 159         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 160         addsuffix(join(`hashes', `-', `hash_modes'), `.h')
 161
 162 ## --- Building the main library ---
 163
 164 lib_LTLIBRARIES = libcatacomb.la
 165
 166 libcatacomb_la_LIBADD = $(CATACOMB_LIBS)
 167 libcatacomb_la_LDFLAGS = -version-info 3:1:1
 168 ## Middle number is the patchlevel.  Final number is the minor version.  The
 169 ## difference between the first and last numbers is major version.
 170
 171 pkginclude_HEADERS = \
 172         arena.h paranoia.h buf.h qdparse.h keysz.h \
 173         blkc.h hash.h gcipher.h ghash.h gmac.h grand.h ghash-def.h \
 174         lcrand.h fibrand.h rc4.h seal.h rand.h noise.h fipstest.h maurer.h \
 175         key.h key-error.h key-data.h passphrase.h pixie.h lmem.h \
 176         mpx.h bitops.h mpw.h mpscan.h mparena.h mp.h mptext.h mpint.h \
 177         exp.h mpbarrett.h mpmont.h mpreduce.h mp-exp.h \
 178         mpcrt.h mprand.h mpmul.h \
 179         gfx.h gf.h gfreduce.h gfn.h gf-exp.h \
 180         primetab.h wheel.h pfilt.h rabin.h \
 181         pgen.h primeiter.h prim.h strongprime.h limlee.h keycheck.h \
 182         bbs.h rsa.h dh.h dsarand.h dsa.h gdsa.h gkcdsa.h \
 183         tlsprf.h sslprf.h \
 184         gfshare.h share.h \
 185         rho.h \
 186         field.h field-guts.h field-exp.h \
 187         ec.h ec-guts.h ec-exp.h ec-test.h ectab.h ec-keys.h ec-raw.h \
 188         ptab.h bintab.h group.h group-guts.h \
 189         allwithsuffix(`ciphers', `cipher_modes', `.h') \
 190         allwithsuffix(`hashes', `hash_modes', `.h') \
 191         addsuffix(`cipher_modes', `-def.h') \
 192         addsuffix(`hash_modes', `-def.h') crc32.h
 193
 194 define(`MP_BASE',
 195         `mpx.c mpx-kmul.c mpx-ksqr.c mpscan.c mparena.c \
 196         mp-misc.c mp-mem.c mp-const.c mp-arith.c mp-io.c \
 197         mptext.c mptext-string.c')
 198
 199 define(`MP_SOURCES',
 200         `qdparse.c \
 201         mp-test.c mplimits.c \
 202         mp-sqrt.c mp-gcd.c mp-jacobi.c mp-modsqrt.c mp-exp.c mp-modexp.c \
 203         mpint.c mptext-file.c mptext-dstr.c \
 204         mptext-len.c \
 205         exp.c mpcrt.c mpmul.c mprand.c \
 206         mpbarrett.c mpbarrett-exp.c mpbarrett-mexp.c mpbarrett-exp.h \
 207         mpmont.c mpmont-exp.c mpmont-mexp.c mpmont-exp.h \
 208         mpreduce.c mpreduce-exp.h \
 209         group-stdops.c group-exp.c group-exp.h g-prime.c g-bin.c \
 210           group-parse.c \
 211         group-string.c group-file.c group-dstr.c \
 212         rho.c buf.c ptab.c bintab.c \
 213         GF_SOURCES PGEN_SOURCES EC_SOURCES')
 214
 215 define(`GF_SOURCES',
 216         `gfx.c gfx-kmul.c gfx-sqr.c gf-arith.c gf-exp.c gf-gcd.c \
 217         gfreduce.c gfreduce-exp.h gfn.c')
 218
 219 define(`EC_SOURCES',
 220         `field.c field-parse.c field-exp.c \
 221         f-prime.c f-niceprime.c f-binpoly.c \
 222         ec.c ec-exp.c ec-prime.c ec-bin.c ec-test.c ec-info.c ectab.c \
 223         ec-fetch.c ec-raw.c g-ec.c')
 224
 225 define(`PGEN_SOURCES',
 226         `pfilt.c primeiter.c rabin.c \
 227         pgen.c pgen-stdev.c pgen-gcd.c pgen-simul.c \
 228           prim.c strongprime.c limlee.c \
 229         keycheck.c keycheck-mp.c keycheck-report.c \
 230         bbs-rand.c bbs-gen.c bbs-jump.c bbs-fetch.c \
 231         rsa-priv.c rsa-pub.c rsa-gen.c rsa-recover.c rsa-fetch.c \
 232         oaep.c pkcs1.c pss.c \
 233         dh-gen.c dh-limlee.c dh-kcdsa.c dh-check.c dh-fetch.c dh-param.c \
 234         dsarand.c dsa-misc.c dsa-sign.c dsa-verify.c dsa-gen.c dsa-check.c \
 235         gdsa.c gkcdsa.c \
 236         key-data.c key-flags.c key-text.c key-binary.c key-pass.c \
 237         key-pack.c key-misc.c key-file.c key-attr.c key-io.c key-moan.c \
 238         key-error.c key-fetch.c \
 239         primetab.c wheel.c share.c')
 240
 241 libcatacomb_la_SOURCES = \
 242         grand.c keysz.c keysz-conv.c \
 243         lcrand.c fibrand.c rc4.c seal.c rand.c noise.c fipstest.c maurer.c \
 244         arena.c \
 245         passphrase.c pixie-common.c lmem.c \
 246         tlsprf.c sslprf.c \
 247         gfshare.c \
 248         MP_BASE MP_SOURCES karatsuba.h \
 249         gciphertab.c ghashtab.c gmactab.c \
 250         des-base.c des-base.h \
 251         desx-tab.h \
 252         rc2-tab.h \
 253         skipjack-tab.h \
 254         cast-s.c cast-sk.c cast-base.h cast-tab.h \
 255         rijndael-base.c rijndael-base.h \
 256         md2-tab.h \
 257         serpent-sbox.h skipjack-tab.h tiger-base.h \
 258         daftstory.h \
 259         addsuffix(join(`ciphers', `-', `cipher_modes'), `.c') \
 260         addsuffix(join(`hashes', `-', `hash_modes'), `.c') \
 261         addsuffix(`ciphers', `.c') addsuffix(`hashes', `.c') crc32.c
 262
 263 des-base.lo: des-tab.h
 264 blowfish.lo: blowfish-tab.h
 265 twofish.lo: twofish-tab.h
 266 square.lo: square-tab.h
 267 rijndael-base.lo: rijndael-tab.h
 268 whirlpool.lo: whirlpool-tab.h
 269 safer.lo: safer-tab.h
 270 mars.lo: mars-tab.h
 271 tiger.lo: tiger-tab.h
 272 gfshare.lo: gfshare-tab.h
 273 gfx-sqr.lo: gfx-sqr-tab.h
 274
 275 ## --- Utility programs ---
 276
 277 bin_PROGRAMS = \
 278         dsig key pixie cookie rspit factorial hashsum mkphrase \
 279         catcrypt catsign
 280 noinst_LIBRARIES = libcatcrypt.a
 281 pkgconfigdir = $(libdir)/pkgconfig
 282 pkgconfig_DATA = catacomb.pc
 283 noinst_PROGRAMS = \
 284         genprimes genwheel mptypes genlimits serpent-check bittest mpdump \
 285         perftest \
 286         addsuffix(`gen_tables', `-mktab')
 287 LDADD = libcatcrypt.a libcatacomb.la
 288
 289 define(`LIBCAT_SRC', `cc.h getdate.h dnl
 290         cc-sig.c cc-subcmd.c cc-enc.c cc-kem.c cc-hash.c \
 291         cc-list.c cc-progress.c')
 292 libcatcrypt_a_SOURCES = LIBCAT_SRC getdate.y
 293
 294 patsubst(MP_BASE MP_SOURCES, `\.c\>', `.lo') dsig.o keyutil.o rspit.o \
 295         patsubst(LIBCAT_SRC, `\.c\>', `.o'): \
 296         mptypes.h primetab.h wheel.h
 297 patsubst(MP_SOURCES, `\.c\>', `.lo'): mplimits.h
 298
 299 dsig_SOURCES = dsig.c
 300 cookie_SOURCES = cookie.c
 301 catcrypt_SOURCES = catcrypt.c
 302 catsign_SOURCES = catsign.c
 303 key_SOURCES = keyutil.c
 304 hashsum_SOURCES = hashsum.c
 305 rspit_SOURCES = rspit.c
 306 factorial_SOURCES = factorial.c
 307 perftest_SOURCES = perftest.c
 308 perftest_LDADD = $(CATACOMB_LIBS) $(LDADD)
 309 pixie_SOURCES = pixie.c pixie-common.c lmem.c arena.c passphrase.c
 310 pixie_LDADD = $(PIXIE_LIBS)
 311 pixie_CFLAGS = $(AM_CFLAGS)
 312 mkphrase_SOURCES = mkphrase.c
 313 mkphrase_LDADD = $(CATACOMB_LIBS) $(LDADD)
 314 bittest_SOURCES = bittest.c
 315 bittest_LDADD =
 316
 317 define(`emit', `
 318 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_SOURCES = _item`'-mktab.c
 319 patsubst(_item, `[^a-zA-Z0-9]', `_')_mktab_LDADD =')dnl
 320 gen_tables
 321
 322 serpent_check_SOURCES = serpent-check.c
 323 serpent_check_LDADD =
 324
 325 genprimes_SOURCES = genprimes.c
 326 genprimes_LDADD =
 327
 328 genwheel_SOURCES = genwheel.c
 329 genwheel_LDADD =
 330
 331 mptypes_SOURCES = mptypes.c
 332 mptypes_LDADD =
 333
 334 genlimits_SOURCES = genlimits.c MP_BASE mptypes.h
 335 genlimits_LDADD =
 336 genlimits_CFLAGS = $(AM_CFLAGS)
 337
 338 mpdump_SOURCES = mpdump.c MP_BASE
 339 mpdump_LDADD =
 340 mpdump_CFLAGS = $(AM_CFLAGS)
 341
 342 ## --- Install the pixie setuid-root if we can ---
 343 ##
 344 ## Bodge around a bug in Automake: it doesn't call `install-exec-hook' from
 345 ## `install' if there are subdirectories.
 346
 347 changequote(<, >)
 348 # install: install-exec-hook
 349 install-exec-hook:
 350         @pixie="$(DESTDIR)$(bindir)/`echo pixie|sed $(transform)`"; \
 351         if chown root $$pixie && chmod 4755 $$pixie; then \
 352           echo "chown root $$pixie"; \
 353           echo "chmod 4755 $$pixie"; \
 354         else \
 355           echo "***"; \
 356           echo "*** You should probably install $$pixie setuid-root."; \
 357           echo "***"; \
 358         fi
 359 changequote(`, ')
 360
 361 ## --- Documentation ---
 362
 363 man_MANS = \
 364         key.1 dsig.1 cookie.1 catcrypt.1 catsign.1 hashsum.1 mkphrase.1 \
 365         keyring.5 pixie.1
 366
 367 ## --- Prime group keyring ---
 368
 369 #pkgdata_DATA = pgroups.kr
 370
 371 $(srcdir)/pgroups.kr: ptab.in mkpgroups
 372         cd $(srcdir) && rm -f pgroups.kr && ./mkpgroups <ptab.in
 373
 374 ## --- Other handy definitions ---
 375
 376 EXTRA_DIST = \
 377         Makefile.m4 genmodes gengctab $(man_MANS) xpixie \
 378         group-test.c rsa-test.c \
 379         ectab.in ec-gentab.awk \
 380         ptab.in p-gentab.awk mkpgroups \
 381         bintab.in bin-gentab.awk \
 382         README.cipher README.hash README.random README.mp \
 383         debian/rules debian/copyright debian/control debian/changelog \
 384         debian/catacomb-bin.postinst debian/catacomb-bin.config \
 385         debian/catacomb-bin.prerm debian/catacomb-bin.templates
 386
 387 dist-hook:
 388         @for i in getdate.c gciphertab.c ghashtab.c gmactab.c; do \
 389           ln $$i $(distdir) || ln $(srcdir)/$$i $(distdir) || true; \
 390         done
 391         @echo datestamp >$(distdir)/modes-stamp || true
 392         @for i in calc tests; do \
 393           mkdir $(distdir)/$$i; \
 394           ln $(srcdir)/$$i/*[!~] $(distdir)/$$i; \
 395         done || true
 396 #       kr=$$HOME/.catacomb/dsig-keyring; \
 397 #       if [ -r $$kr ]; then \
 398 #         cd $(distdir); \
 399 #         ../key -k $$kr extract -f -secret KEYRING; \
 400 #         find . -type f -print0 | ../dsig -k $$kr sign -0 -oMANIFEST; \
 401 #       fi
 402
 403 ## --- Testing ---
 404
 405 define(`testprogs', `')
 406
 407 define(`CTESTRIG',
 408 `define(`testprogs', testprogs \
 409         $1.t$(EXEEXT))dnl
 410 $1.to: $1.c
 411         $(COMPILE) -c -DTEST_RIG -DSRCDIR=\"$(srcdir)\" $(srcdir)/$1.c -o $1.to
 412 $1.t$(EXEEXT): $1.to libcatacomb.la
 413         $(CC) $(CFLAGS) $(LDFLAGS) $1.to .libs/libcatacomb.a $(CATACOMB_LIBS) $(LIBS) -o $1.t$(EXEEXT)')
 414
 415 CTESTRIG(rc4)
 416 CTESTRIG(seal)
 417 adorn(`nl`'CTESTRIG(', `ciphers', `)')
 418 adorn(`nl`'CTESTRIG(', `hashes', `)')
 419 adorn(`nl`'CTESTRIG(', join(`ciphers', `-', `cipher_modes'), `)')
 420 adorn(`nl`'CTESTRIG(', join(`hashes', `-', `hash_modes'), `)')
 421 CTESTRIG(lcrand)
 422 CTESTRIG(tlsprf)
 423 CTESTRIG(sslprf)
 424 CTESTRIG(mpx)
 425 CTESTRIG(mpx-kmul)
 426 CTESTRIG(mpx-ksqr)
 427 CTESTRIG(mp-arith)
 428 CTESTRIG(mp-modsqrt)
 429 CTESTRIG(mp-gcd)
 430 CTESTRIG(mp-jacobi)
 431 CTESTRIG(mp-sqrt)
 432 CTESTRIG(mp-modexp)
 433 CTESTRIG(mptext)
 434 CTESTRIG(mpint)
 435 CTESTRIG(mpbarrett)
 436 CTESTRIG(mpbarrett-exp)
 437 CTESTRIG(mpbarrett-mexp)
 438 CTESTRIG(mpmont)
 439 CTESTRIG(mpmont-exp)
 440 CTESTRIG(mpmont-mexp)
 441 CTESTRIG(mpreduce)
 442 CTESTRIG(mpcrt)
 443 CTESTRIG(mpmul)
 444 CTESTRIG(rsa-test)
 445 CTESTRIG(gfx)
 446 CTESTRIG(gfx-sqr)
 447 CTESTRIG(gfx-kmul)
 448 CTESTRIG(gf-arith)
 449 CTESTRIG(gf-gcd)
 450 CTESTRIG(gfreduce)
 451 CTESTRIG(gfn)
 452 CTESTRIG(ec-prime)
 453 CTESTRIG(ec-bin)
 454 CTESTRIG(ec-test)
 455 CTESTRIG(ec-info)
 456 CTESTRIG(dh-param)
 457 CTESTRIG(group-test)
 458 CTESTRIG(gdsa)
 459 CTESTRIG(gkcdsa)
 460 CTESTRIG(pgen)
 461 CTESTRIG(primeiter)
 462 CTESTRIG(dsa-gen)
 463 CTESTRIG(dsa-sign)
 464 CTESTRIG(dsa-verify)
 465 CTESTRIG(bbs-rand)
 466 CTESTRIG(bbs-jump)
 467 CTESTRIG(gfshare)
 468 CTESTRIG(share)
 469 CTESTRIG(rho)
 470
 471 TESTS = serpent-check bittest testprogs
 472
 473 CLEANFILES = \
 474         *.t$(EXEEXT) *.to *.kr.old \
 475         mptypes.h primetab.c primetab.h wheel.c wheel.h \
 476         ectab.c ptab.c bintab.c \
 477         addsuffix(`gen_tables', `-tab.h')
 478
 479 ## --- Makefile building (haha!) ---
 480
 481 $(srcdir)/Makefile.am: $(srcdir)/Makefile.m4
 482         m4 $(srcdir)/Makefile.m4 >$(srcdir)/Makefile.am.new
 483         mv $(srcdir)/Makefile.am.new $(srcdir)/Makefile.am
 484
 485 DISTCLEANFILES = libtool
 486
 487 MAINTAINERCLEANFILES = \
 488         $(srcdir)/Makefile.am \
 489         $(srcdir)/getdate.c getdate.c \
 490         $(srcdir)/pgroups.kr \
 491         $(MODES) modes-stamp $(srcdir)/modes-stamp
 492
 493 ##----- That's all, folks ---------------------------------------------------