blowfish-mktab.c: Remove the eye-candy progress meter.

[u/mdw/catacomb] / configure.in

dnl -*-m4-*-
dnl
dnl $Id$
dnl
dnl Autoconfiguration for Catacomb
dnl
dnl (c) 1999 Straylight/Edgeware
dnl

dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of Catacomb.
dnl
dnl Catacomb is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU Library General Public License as
dnl published by the Free Software Foundation; either version 2 of the
dnl License, or (at your option) any later version.
dnl
dnl Catacomb is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU Library General Public License for more details.
dnl
dnl You should have received a copy of the GNU Library General Public
dnl License along with Catacomb; if not, write to the Free
dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
dnl MA 02111-1307, USA.

dnl --- Boring boilerplate ---

mdw_AUTO_VERSION
AC_INIT(catacomb, AUTO_VERSION, mdw@distorted.org.uk)
mdw_SILENT_RULES
AC_CONFIG_SRCDIR(blkc.h)
AC_CONFIG_AUX_DIR(.)
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(foreign)

dnl --- Make sure I can compile and build libraries ---

AC_PROG_CC
AM_PROG_LIBTOOL
AX_CFLAGS_WARN_ALL
mdw_LIBTOOL_VERSION_INFO

AC_PROG_YACC

dnl --- Actually, I assume these exist anyway ---

AC_CHECK_HEADERS(unistd.h)
AC_HEADER_STDC

dnl --- Check for various important system types ---

AC_CHECK_TYPE(pid_t, int)
AC_CHECK_TYPE(size_t, unsigned)
AC_TYPE_UID_T
AC_CHECK_TYPE(time_t, long)
AC_CHECK_TYPE(ssize_t, int)

dnl --- The maths library, for Maurer's test ---

OLIBS=$LIBS
AC_SEARCH_LIBS(log, m)
AC_SEARCH_LIBS(sqrt, m)
AC_SUBST([CATACOMB_LIBS], [$LIBS]) LIBS=$OLIBS

dnl --- Functions used for noise-gathering ---

AC_CHECK_FUNCS(setgroups)

AC_CACHE_CHECK([whether the freewheel noise generator will work],
[catacomb_cv_freewheel],
[AC_TRY_LINK([
#include <setjmp.h>
#include <sys/time.h>
],
[struct itimerval itv = { { 0, 0 }, { 0, 5000 } };
jmp_buf j;
setitimer(ITIMER_REAL, &itv, 0);
sigsetjmp(j, 1);],
[catacomb_cv_freewheel=yes],
[catacomb_cv_freewheel=no])])
if test "$catacomb_cv_freewheel" = "yes"; then
  AC_DEFINE([USE_FREEWHEEL], [1],
	    [Define if you want to use the freewheel noise generator.])
fi

dnl --- Support for the passphrase pixie ---

OLIBS=$LIBS
AC_SEARCH_LIBS(socket, socket)
AC_SUBST([PIXIE_LIBS], [$LIBS]) LIBS=$OLIBS
AC_CHECK_FUNCS(mlock)

dnl --- Debugging things ---

AC_ARG_ENABLE([mpw],
	      [AS_HELP_STRING([--enable-mpw],
			      [force small-width mp digits])],
	      [case "$enableval" in
		 y*|t*|short)
		   AC_DEFINE([FORCE_MPW_SHORT], [1],
			     [Define to force small-width mp digits.])
		   ;;
		 cussid)
		   AC_DEFINE([FORCE_MPW_CUSSID], [1],
			     [Define to force strange-width mp digits.])
		   ;;
	       esac])

dnl --- Done ---

PKG_CHECK_MODULES(mLib, mLib >= 2.0.4)
CFLAGS="$CFLAGS $mLib_CFLAGS"
LIBS="$LIBS $mLib_LIBS"
AC_OUTPUT(Makefile)

dnl ----- That's all, folks -------------------------------------------------